Update KotlinCoroutineFilter for Kotlin 1.6

[Godin]

For the following Example.kt

fun example() {
  exec {
    // suspending lambda without suspension points,
    // i.e. without invocations of suspending functions/lambdas
  }
}

fun exec(suspendingLambda: suspend () -> Unit) {}

execution of

kotlin/bin/kotlinc Example.kt -d classes
javap -v -p classes/ExampleKt\$example\$1.class

using Kotlin compiler version 1.5.32 (latest as of today in 1.5 series) produces

  public final java.lang.Object invokeSuspend(java.lang.Object);
    descriptor: (Ljava/lang/Object;)Ljava/lang/Object;
    flags: ACC_PUBLIC, ACC_FINAL
    Code:
      stack=3, locals=3, args_size=2
         0: invokestatic  #36                 // Method kotlin/coroutines/intrinsics/IntrinsicsKt.getCOROUTINE_SUSPENDED:()Ljava/lang/Object;
         3: astore_2
         4: aload_0
         5: getfield      #40                 // Field label:I
         8: tableswitch   { // 0 to 0
                       0: 28
                 default: 36
            }
        28: aload_1
        29: invokestatic  #46                 // Method kotlin/ResultKt.throwOnFailure:(Ljava/lang/Object;)V
        32: getstatic     #52                 // Field kotlin/Unit.INSTANCE:Lkotlin/Unit;
        35: areturn
        36: new           #54                 // class java/lang/IllegalStateException
        39: dup
        40: ldc           #56                 // String call to 'resume' before 'invoke' with coroutine
        42: invokespecial #59                 // Method java/lang/IllegalStateException."<init>":(Ljava/lang/String;)V
        45: athrow

whereas using Kotlin compiler version 1.6.0 produces

  public final java.lang.Object invokeSuspend(java.lang.Object);
    descriptor: (Ljava/lang/Object;)Ljava/lang/Object;
    flags: ACC_PUBLIC, ACC_FINAL
    Code:
      stack=3, locals=2, args_size=2
         0: invokestatic  #36                 // Method kotlin/coroutines/intrinsics/IntrinsicsKt.getCOROUTINE_SUSPENDED:()Ljava/lang/Object;
         3: pop
         4: aload_0
         5: getfield      #40                 // Field label:I
         8: tableswitch   { // 0 to 0
                       0: 28
                 default: 36
            }
        28: aload_1
        29: invokestatic  #46                 // Method kotlin/ResultKt.throwOnFailure:(Ljava/lang/Object;)V
        32: getstatic     #52                 // Field kotlin/Unit.INSTANCE:Lkotlin/Unit;
        35: areturn
        36: new           #54                 // class java/lang/IllegalStateException
        39: dup
        40: ldc           #56                 // String call to 'resume' before 'invoke' with coroutine
        42: invokespecial #59                 // Method java/lang/IllegalStateException."<init>":(Ljava/lang/String;)V
        45: athrow

Currently the first one is filtered by KotlinCoroutineFilter, but not the second.

And the diff between them

-      stack=3, locals=3, args_size=2
+      stack=3, locals=2, args_size=2
          0: invokestatic  #36                 // Method kotlin/coroutines/intrinsics/IntrinsicsKt.getCOROUTINE_SUSPENDED:()Ljava/lang/Object;
-         3: astore_2
+         3: pop
          4: aload_0

This relates to the following change in Kotlin compiler - JetBrains/kotlin@f4a1e27

---

Closes #1258