mail-client/evolution: bump to 3.38.3

Includes upstream fix for webkit-gtk built without -NDEBUG.
Require USE=spell on webkit-gtk if enabled on evolution, to ensure
visual highlighting of spelling errors works.

Bug: https://bugs.gentoo.org/761238
Closes: https://bugs.gentoo.org/751217
Package-Manager: Portage-3.0.12, Repoman-3.0.2
Signed-off-by: Mart Raudsepp <[email protected]>

mail-client/evolution/Manifest

@@ -1,2 +1,3 @@
 DIST evolution-3.36.5.tar.xz 12137312 BLAKE2B dcd7785fabeda0b8daeadcf5858ac6ae9d11fa21ef4ff3f7b880f0b0c22ff2e8ba6dd25ef983ddf7d6c7c0d060613fea8f0f01a67b0641159cff908d0b2c8c9d SHA512 4f3a7e891f6e0bb8f3d44f838ecf0f373ad1133f465af3a0ab68e9ec9220e67025dc4e657c73bb8c212d958669e5285050234fb43b6bf0596bcd662de1ef9fd0
 DIST evolution-3.38.2.tar.xz 12159172 BLAKE2B 9690428c05f985a73c2ae4d02a1d6fcc71aa02a6d10b8dec938ed65c48bde0e0c873bd0e65040ec90c0136346d76989a0758f59e29eb8526b6953fecaf11177e SHA512 30d40e9e8934afa2a8b602bccf740a055423892cc435b54e2cb116d0a8f24a369975f90a253da0c3554fd315a378c014a26c5b85af5b588c2afd9e8ad4698f3e
+DIST evolution-3.38.3.tar.xz 12159492 BLAKE2B 95fab6e01ae357437c834bc3651a5d599523004e9ca33ab07c552b99dd4119f0ec4cadea11a2e51ecfe61b2329454a866a211f99d35d912690288651f51134c8 SHA512 aaf30f95485939b3715803a46b484fd72d1a2e3d02a2cc0aabea1ee56a20babcea47804badb52219cecb2806c1ebf711ffb14f36918619fb62bf16a031623508

mail-client/evolution/evolution-3.38.3.ebuild

@@ -0,0 +1,152 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit cmake gnome2 flag-o-matic readme.gentoo-r1
+
+DESCRIPTION="Integrated mail, addressbook and calendaring functionality"
+HOMEPAGE="https://wiki.gnome.org/Apps/Evolution"
+
+# Note: explicitly "|| ( LGPL-2 LGPL-3 )", not "LGPL-2+".
+LICENSE="|| ( LGPL-2 LGPL-3 ) CC-BY-SA-3.0 FDL-1.3+ OPENLDAP"
+SLOT="2.0"
+
+IUSE="archive +bogofilter geolocation gtk-doc highlight ldap spamassassin spell ssl +weather ytnef"
+
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86"
+
+# glade-3 support is for maintainers only per configure.ac
+# pst is not mature enough and changes API/ABI frequently
+# dconf explicitely needed for backup plugin
+# gnome-desktop support is optional with --enable-gnome-desktop
+# automagic libunity dep
+# >=gspell-1.8 to ensure it uses enchant:2 like webkit-gtk
+DEPEND="
+	>=app-crypt/gcr-3.4:=[gtk]
+	>=app-text/enchant-2.2.0:2
+	>=dev-libs/glib-2.46:2[dbus]
+	>=dev-libs/libxml2-2.7.3:2
+	>=gnome-base/gnome-desktop-2.91.3:3=
+	>=gnome-base/gsettings-desktop-schemas-2.91.92
+	>=gnome-extra/evolution-data-server-${PV}:=[gtk,weather?]
+	>=media-libs/libcanberra-0.25[gtk3]
+	>=net-libs/libsoup-2.42:2.4
+	>=net-libs/webkit-gtk-2.28.0:4[spell?]
+	>=x11-libs/cairo-1.9.15:=[glib]
+	>=x11-libs/gdk-pixbuf-2.24:2
+	>=x11-libs/gtk+-3.22:3
+	>=x11-libs/libnotify-0.7:=
+	>=x11-misc/shared-mime-info-0.22
+
+	>=app-text/iso-codes-0.49
+	dev-libs/atk
+	gnome-base/dconf
+	x11-libs/libSM
+	x11-libs/libICE
+
+	archive? ( >=app-arch/gnome-autoar-0.1.1[gtk] )
+	bogofilter? ( mail-filter/bogofilter )
+	geolocation? (
+		>=media-libs/libchamplain-0.12:0.12[gtk]
+		>=media-libs/clutter-1.0.0:1.0
+		>=media-libs/clutter-gtk-0.90:1.0
+		>=sci-geosciences/geocode-glib-3.10.0
+		x11-libs/mx:1.0 )
+	ldap? ( >=net-nds/openldap-2:= )
+	spamassassin? ( mail-filter/spamassassin )
+	spell? ( >=app-text/gspell-1.8:= )
+	ssl? (
+		>=dev-libs/nspr-4.6.1:=
+		>=dev-libs/nss-3.11:= )
+	weather? ( >=dev-libs/libgweather-3.10:2= )
+	ytnef? ( net-mail/ytnef )
+"
+RDEPEND="${DEPEND}
+	highlight? ( app-text/highlight )
+"
+BDEPEND="
+	app-text/docbook-xml-dtd:4.1.2
+	dev-util/gdbus-codegen
+	dev-util/glib-utils
+	dev-util/itstool
+	gtk-doc? ( dev-util/gtk-doc
+		app-text/docbook-xml-dtd:4.3 )
+	>=dev-util/intltool-0.40.0
+	>=sys-devel/gettext-0.18.3
+	virtual/pkgconfig
+"
+
+DISABLE_AUTOFORMATTING="yes"
+DOC_CONTENTS="To change the default browser if you are not using GNOME, edit
+~/.local/share/applications/mimeapps.list so it includes the
+following content:
+
+[Default Applications]
+x-scheme-handler/http=firefox.desktop
+x-scheme-handler/https=firefox.desktop
+
+(replace firefox.desktop with the name of the appropriate .desktop
+file from /usr/share/applications if you use a different browser)."
+
+# global scope PATCHES or DOCS array mustn't be used due to double default_src_prepare
+# call; if needed, set them after cmake_src_prepare call, if that works
+
+src_prepare() {
+	cmake_src_prepare
+	gnome2_src_prepare
+}
+
+src_configure() {
+	# Use NSS/NSPR only if 'ssl' is enabled.
+	local mycmakeargs=(
+		-DSYSCONF_INSTALL_DIR="${EPREFIX}"/etc
+		-DENABLE_SCHEMAS_COMPILE=OFF
+		-DENABLE_GTK_DOC=$(usex gtk-doc)
+		-DWITH_OPENLDAP=$(usex ldap)
+		-DENABLE_SMIME=$(usex ssl)
+		-DENABLE_GNOME_DESKTOP=ON
+		-DWITH_ENCHANT_VERSION=2
+		-DENABLE_CANBERRA=ON
+		-DENABLE_AUTOAR=$(usex archive)
+		-DWITH_HELP=ON
+		-DENABLE_YTNEF=OFF
+		-DWITH_BOGOFILTER=$(usex bogofilter)
+		-DWITH_SPAMASSASSIN=$(usex spamassassin)
+		-DENABLE_GSPELL=$(usex spell)
+		-DENABLE_TEXT_HIGHLIGHT=$(usex highlight)
+		-DENABLE_WEATHER=$(usex weather)
+		-DENABLE_CONTACT_MAPS=$(usex geolocation)
+		-DENABLE_YTNEF=$(usex ytnef)
+		-DENABLE_PST_IMPORT=OFF
+		-DWITH_GLADE_CATALOG=OFF
+	)
+
+	cmake_src_configure
+}
+
+src_compile() {
+	cmake_src_compile
+}
+
+src_test() {
+	cmake_src_test
+}
+
+src_install() {
+	cmake_src_install
+
+	# Problems with prelink:
+	# https://bugzilla.gnome.org/show_bug.cgi?id=731680
+	# https://bugzilla.gnome.org/show_bug.cgi?id=732148
+	# https://bugzilla.redhat.com/show_bug.cgi?id=1114538
+	echo PRELINK_PATH_MASK=/usr/bin/evolution > ${T}/99${PN}
+	doenvd "${T}"/99${PN}
+
+	readme.gentoo_create_doc
+}
+
+pkg_postinst() {
+	gnome2_pkg_postinst
+	readme.gentoo_print_elog
+}