Add support for macOS

flake.nix

@@ -2,6 +2,10 @@
   description = "soxin: opiniated configs for everyone";
 
   inputs = {
+    darwin = {
+      url = "github:lnl7/nix-darwin/master";
+      inputs.nixpkgs.follows = "nixpkgs";
+    };
     deploy-rs.url = "github:serokell/deploy-rs";
     flake-utils-plus.url = "github:gytis-ivaskevicius/flake-utils-plus/v1.3.1";
     nixpkgs-unstable.url = "github:NixOS/nixpkgs/nixos-unstable";

lib/mk-flake.nix

@@ -1,4 +1,5 @@
-{ deploy-rs
+{ darwin
+, deploy-rs
 , home-manager
 , flake-utils-plus
 , nixpkgs
@@ -34,6 +35,9 @@
   # NixOS specific modules.
 , extraNixosModules ? [ ]
 
+  # nix-darwin specific modules.
+, extraNixDarwinModules ? [ ]
+
   # The global extra arguments are included in both NixOS and home-manager.
 , globalSpecialArgs ? { }
 
@@ -43,6 +47,9 @@
   # NixOS specific extra arguments.
 , nixosSpecialArgs ? { }
 
+  # nix-darwin specific extra arguments.
+, nixDarwinSpecialArgs ? { }
+
   # Evaluates to `packages.<system>.<pname> = <unstable-channel-reference>.<pname>`.
 , packagesBuilder ? (_: { })
 
@@ -98,9 +105,11 @@ let
     "extraGlobalModules"
     "extraHomeManagerModules"
     "extraNixosModules"
+    "extraNixDarwinModules"
     "globalSpecialArgs"
     "hmSpecialArgs"
     "nixosSpecialArgs"
+    "nixDarwinSpecialArgs"
     "packagesBuilder"
     "devShellBuilder"
     "sharedOverlays"
@@ -109,33 +118,113 @@ let
   # generate each host by injecting special arguments and the given host
   # without certain soxin-only attributes.
   hosts' =
-    mapAttrs
-      (hostname: host: (recursiveUpdate
-        {
-          specialArgs = {
-            inherit soxin soxincfg home-manager;
-
-            # the mode allows us to tell at what level we are within the modules.
-            mode = "NixOS";
-          }
-          # include the global special arguments.
-          // globalSpecialArgs
-          # include the NixOS special arguments.
-          // nixosSpecialArgs;
-        }
-
-        # pass along the hosts minus the deploy key that's specific to soxin.
-        (removeAttrs host [ "deploy" ])
-      ))
-      hosts;
+    let
+      darwinHosts =
+        let
+          darwinOnlyHosts = filterAttrs (n: host: host.mode == "nix-darwin") hosts;
+
+          # Build host with darwinSystem.
+          builder = args: darwin.lib.darwinSystem args;
+
+          # Setup the output
+          output = "darwinConfigurations";
+        in
+        mapAttrs
+          (_: host:
+            # setup the default attributes, users can override it by passing them through their host definition.
+            { inherit builder output; }
+            //
+            (recursiveUpdate
+              # pass along the hosts minus few keys that are implementation detail to soxin.
+              (removeAttrs host [ "deploy" "mode" "modules" ])
+
+              {
+                modules = [ ]
+                # include modules for the host
+                ++ (host.modules or [ ])
+                # include the NixOS modules
+                ++ extraNixDarwinModules
+                # include home-manager modules
+                ++ (singleton home-manager.darwinModules.home-manager)
+                ;
+                specialArgs =
+                  {
+                    inherit
+                      home-manager
+                      soxin
+                      soxincfg
+                      ;
+
+                    inherit (host)
+                      mode
+                      ;
+                  }
+                  # include the specialArgs that were passed in.
+                  // (host.specialArgs or { })
+                  # include the global special arguments.
+                  // globalSpecialArgs
+                  # include the NixDarwin special arguments.
+                  // nixDarwinSpecialArgs
+                ;
+              }
+            ))
+          darwinOnlyHosts;
+
+      nixosHosts =
+        let
+          nixosOnlyHosts = filterAttrs (n: host: host.mode == "NixOS") hosts;
+        in
+        mapAttrs
+          (_: host: (recursiveUpdate
+            # pass along the hosts minus few keys that are implementation detail to soxin.
+            (removeAttrs host [ "deploy" "mode" ])
+
+            {
+              modules = [ ]
+                # include modules for the host
+                ++ (host.modules or [ ])
+                # include the NixOS modules
+                ++ extraNixosModules
+                # include sops
+                ++ (optionals withSops (singleton sops-nix.nixosModules.sops))
+                # include home-manager modules
+                ++ (singleton home-manager.nixosModules.home-manager)
+              ;
+
+              specialArgs =
+                {
+                  inherit
+                    home-manager
+                    soxin
+                    soxincfg
+                    ;
+
+                  inherit (host)
+                    mode
+                    ;
+                }
+                # include the specialArgs that were passed in.
+                // (host.specialArgs or { })
+                # include the global special arguments.
+                // globalSpecialArgs
+                # include the NixOS special arguments.
+                // nixosSpecialArgs
+              ;
+            }
+          ))
+          nixosOnlyHosts;
+
+      # TODO: add support for home-manager modes
+    in
+    darwinHosts // nixosHosts;
 
   # Generate the deployment nodes.
   deploy.nodes =
     let
       # filter out hosts without a deploy attribute.
       deploy-hosts = filterAttrs (n: v: (v.deploy or { }) != { }) hosts;
     in
-    mapAttrs (hostname: host: host.deploy) deploy-hosts;
+    mapAttrs (_: host: host.deploy) deploy-hosts;
 
   soxinSystemFlake = {
     # inherit the required fields as-is
@@ -235,22 +324,17 @@ let
         modules =
           # include the modules that are passed in
           (hostDefaults.modules or [ ])
-            # include sops
-            ++ (optionals withSops (singleton sops-nix.nixosModules.sops))
             # include the global modules
             ++ extraGlobalModules
-            # include the NixOS modules
-            ++ extraNixosModules
             # include Soxin modules
             ++ (singleton soxin.nixosModule)
-            # include home-manager modules
-            ++ (singleton home-manager.nixosModules.home-manager)
             # configure fup to expose NIX_PATH and Nix registry from inputs.
             ++ (singleton { nix = { inherit generateNixPathFromInputs generateRegistryFromInputs linkInputs; }; })
             # configure home-manager
             ++ (singleton {
-            # tell home-manager to use the global (as in NixOS system-level) pkgs and
-            # install all  user packages through the users.users.<name>.packages.
+            # tell home-manager to use the global (as in NixOS/Nix-Darwin
+            # system-level) pkgs and install all user packages through the
+            # users.users.<name>.packages.
             home-manager.useGlobalPkgs = true;
             home-manager.useUserPackages = true;
 
@@ -263,15 +347,17 @@ let
             # include the global special arguments.
             // globalSpecialArgs
             # include the home-manager special arguments.
-            // hmSpecialArgs;
+            // hmSpecialArgs
+            ;
 
             home-manager.sharedModules =
               # include the global modules
               extraGlobalModules
                 # include the home-manager modules
                 ++ extraHomeManagerModules
                 # include Soxin module
-                ++ (singleton soxin.nixosModule);
+                ++ (singleton soxin.nixosModule)
+            ;
           });
       };
   }
@@ -291,7 +377,7 @@ flake-utils-plus.lib.mkFlake (recursiveUpdate soxinSystemFlake otherArguments)
   # TODO: Let flake-utils-plus.lib.mkFlake handle the home-managers by using the host's builder function
   // {
   homeConfigurations = (mapAttrs
-    (hostname: host: soxin.lib.homeManagerConfiguration (host // {
+    (_: host: soxin.lib.homeManagerConfiguration (host // {
       inherit inputs;
       hmModules =
         # include the global modules

modules/programs/keybase/default.nix

@@ -1,8 +1,19 @@
 { mode, config, pkgs, lib, ... }:
 
-with lib;
 let
   cfg = config.soxin.programs.keybase;
+
+  inherit (lib)
+    mkEnableOption
+    mkIf
+    mkMerge
+    optionalAttrs
+    recursiveUpdate
+    ;
+
+  inherit (pkgs.hostPlatform)
+    isLinux
+    ;
 in
 {
   options = {
@@ -11,14 +22,14 @@ in
       enableFs =
         recursiveUpdate
           (mkEnableOption "Keybase filesystem")
-          { default = true; };
+          { default = isLinux; };
     };
   };
 
   config = mkIf cfg.enable (mkMerge [
-    {
+    (optionalAttrs (mode == "NixOS" || mode == "home-manager") {
       services.keybase.enable = true;
       services.kbfs.enable = cfg.enableFs;
-    }
+    })
   ]);
 }

modules/programs/starship/default.nix

@@ -1,8 +1,19 @@
 { mode, config, pkgs, lib, ... }:
 
-with lib;
 let
   cfg = config.soxin.programs.starship;
+
+  inherit (lib)
+    mkEnableOption
+    mkAfter
+    mkIf
+    mkMerge
+    optionalAttrs
+    ;
+
+  inherit (pkgs.hostPlatform)
+    isDarwin
+    ;
 in
 {
   options = {
@@ -21,10 +32,27 @@ in
     })
 
     (optionalAttrs (mode == "home-manager") {
-      programs.starship = {
-        enable = true;
-        enableZshIntegration = config.soxin.programs.zsh.enable;
-      };
+      programs.starship = mkMerge [
+        {
+          enable = true;
+          enableZshIntegration = config.soxin.programs.zsh.enable;
+        }
+
+        (mkIf (isDarwin && pkgs.system == "aarch64-darwin") {
+          package = pkgs.writeShellScriptBin "starship" ''
+            set -euo pipefail
+
+            readonly real_path=/opt/homebrew/bin/starship
+
+            if [[ ! -x $real_path ]]; then
+              >&2 echo "Installing starship, please wait."
+              brew install starship
+            fi
+
+            exec $real_path "$@"
+          '';
+        })
+      ];
     })
   ]);
 }

modules/programs/tmux/default.nix

@@ -86,7 +86,7 @@ in
 
         secureSocket = mkOption {
           type = types.bool;
-          default = true;
+          default = pkgs.stdenv.isLinux;
           description = ''
             Store tmux socket under <filename>/run</filename>, which is more
             secure than <filename>/tmp</filename>, but as a downside it doesn't
@@ -99,7 +99,9 @@ in
 
   config = mkIf cfg.enable (mkMerge [
     # add all plugins installed by themes
-    { soxin.programs.tmux.plugins = cfg.theme.plugins; }
+    (optionalAttrs (mode == "NixOS" || mode == "home-manager") {
+      soxin.programs.tmux.plugins = cfg.theme.plugins;
+    })
 
     (optionalAttrs (mode == "NixOS") (mkMerge [
       { programs.tmux = { inherit (cfg) enable extraConfig secureSocket; }; }