Write CLI

Author: zyrolasting

.gitignore

@@ -4,3 +4,4 @@
 .DS_Store
 compiled/
 /doc/
+*.svg

cli.rkt

@@ -0,0 +1,84 @@
+#lang racket/base
+
+(provide DEFAULT-OUTPUT-DIRNAME)
+
+(require racket/cmdline
+         racket/file
+         racket/path
+         racket/string
+         file/convertible
+         "main.rkt")
+
+; The manual also uses this constant.
+(define DEFAULT-OUTPUT-DIRNAME "mind-maps-out")
+
+(module+ main
+  (define force? #f)
+  (define << printf)
+  (define dest-dir (build-path (current-directory) DEFAULT-OUTPUT-DIRNAME))
+
+  (command-line
+   #:program "mind-map"
+   #:once-each
+   [("--dest")
+    user-dest-dir
+    "Set the output directory"
+    (set! dest-dir (read-user-path user-dest-dir))]
+   [("-f" "--force")
+    "Overwrite output files, if they exist."
+    (set! force? #t)]
+   [("-q" "--quiet")
+    "Suppress messages on STDOUT"
+    (set! << void)]
+   #:args mind-map-paths
+
+   ; Validate user arguments.
+   (when (null? mind-map-paths)
+     (eprintf "No mind-maps specified.~n")
+     (exit 1))
+
+   (define unreadable
+     (for/fold ([dne null])
+               ([mm (in-list mind-map-paths)])
+       (if (and (file-exists? mm)
+                (member 'read (file-or-directory-permissions mm)))
+           dne
+           (cons mm dne))))
+
+   (unless (null? unreadable)
+     (eprintf "These files are not readable:~n~a~n"
+              (string-join (reverse (map (λ (p) (format "  ~a" p)) unreadable)) "\n"))
+     (exit 1))
+
+   ; Read input files
+   (define parse-trees
+     (for/list ([mm (in-list mind-map-paths)])
+       (cond [(has-lang? mm)
+              (<< "Loading Racket module ~a~n" mm)
+              (dynamic-require mm 'thoughts)]
+             [else
+              (<< "Loading text file ~a~n" mm)
+              (call-with-input-file mm
+                (λ (in) (read-thoughts in)))])))
+
+   ; Write output files
+   (make-directory* dest-dir)
+   (for ([thoughts (in-list parse-trees)]
+         [mm (in-list mind-map-paths)])
+     (define output-path (build-path dest-dir (path-replace-extension (file-name-from-path mm) #".svg")))
+     (if (or force? (not (file-exists? output-path)))
+         (call-with-output-file output-path #:exists 'truncate/replace
+           (λ (o) (write-bytes (convert (thoughts->pict thoughts) 'svg-bytes) o)
+              (<< "Wrote ~a~n" output-path)))
+         (<< "Skipped ~a~n" output-path)))))
+
+(define (has-lang? path)
+  (call-with-input-file path
+    (λ (in) (regexp-match? #px"^\\s*#lang\\s+mind-map\\s+" in))))
+
+(define (read-user-path user-path)
+  (define p (string->path user-path))
+  (cond [(file-exists? p)
+         (eprintf "Expected ~a to be a directory, but it's a file.~n" p)
+         (exit 1)]
+        [else p]))

info.rkt

@@ -6,3 +6,5 @@
 (define pkg-desc "Write and render mind maps in Racket")
 (define version "0.0")
 (define pkg-authors '(sage))
+(define raco-commands
+  '(("mind-map" (submod mind-map/cli main) "Build mind maps" #f)))

main.rkt

@@ -77,10 +77,3 @@
           (require mind-map)
           (provide thoughts)
           (define thoughts 'parse-tree)))))
-
-(module+ main
-  (require racket/cmdline)
-  (command-line
-    #:program "mind-map"
-    #:args mind-maps
-    (displayln mind-maps)))

scribblings/mind-map.scrbl

@@ -3,7 +3,8 @@
                     racket/base
                     racket/contract
                     racket/sequence]
-                    racket/runtime-path]
+                    racket/runtime-path
+                    mind-map/cli]
 
 @title{Creating Mind Maps in Racket}
 @author{Sage Gerard}
@@ -164,6 +165,34 @@ The indentation error can be fixed by replacing the tab with a space,
 or by replacing one space with a tab in all indented lines.
 }
 
+@section{@tt{raco mind-map}}
+
+The @tt{mind-map} collection includes a @tt{raco} command of the same
+name. The command will parse text files given as command line
+arguments and save the rendered mind maps to SVG files.  Currently,
+any failure results in exit code 1.
+
+@verbatim|{$ raco mind-map path/to/mind-map.rkt path/to/notes.txt}|
+
+As implied in the above command line, the input files do not have to be
+Racket modules. If the file starts with @litchar{#lang mind-map}, then
+it will be loaded as a Racket module.  Otherwise it will be read as a
+plain text file using @racket[read-thoughts].
+
+By default, the command will render the SVG documents in a
+@tt[@DEFAULT-OUTPUT-DIRNAME] directory, relative to the command's working
+directory. You can override this directory with @litchar{--dest}.
+
+@verbatim|{$ raco mind-map --dest other-dir ...}|
+
+The command will not overwrite any files unless forced.  Set @litchar{-f}
+or @litchar{--force} to overwrite any conflicting files.
+
+By default, the command will print its activity on STDOUT. Use
+@litchar{--quiet} or @litchar{-q} to suppress STDOUT messages.
+
+Run @tt{raco mind-map -h} to review these options.
+
 
 @section{Project Information}