-
Notifications
You must be signed in to change notification settings - Fork 1
/
Copy pathflux.f90
533 lines (438 loc) · 18.9 KB
/
flux.f90
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
!##########################################################
! SUBROUTINE flux
! Goal: compute the global flux defined by the finite volume method
!##########################################################
SUBROUTINE flux(Hvec,Source_sf, Q)
USE module_shallow
USE OMP_LIB
IMPLICIT NONE
! Subroutine parameters
REAL(kr), DIMENSION(1:nbvar*nbrElem), INTENT(IN) :: Q
REAL(kr), DIMENSION(1:nbvar*nbrElem), INTENT(OUT) :: Hvec
REAL(kr), DIMENSION(1:nbvar*nbrElem), INTENT(OUT) :: Source_sf
! Local parameters
REAL(kr), DIMENSION(1:nbvar) :: temp
REAL(kr), DIMENSION(1:nbvar) :: qL, qR, Fav, Fup, qAv, sourceloc_f, sourceloc_s
REAL(kr), DIMENSION(1:nbvar,1:2) :: FL, FR
REAL(kr), DIMENSION(1:nbvar*nbrElem) :: gradX, gradY
REAL(kr), DIMENSION(1:2) :: n
REAL(kr) :: ds, SL, SR, h, u, v, c, Froude, dij, Hi, Hj, Xij, Yij, tmpmax, tmp, tmp2, globmax
INTEGER(ki) :: i, j, idL, idR, error,chunck, IDj, IDk
LOGICAL :: iswall
Hvec = zero
Source_sf = zero
iswall = .FALSE.
IF (muscl .NE. 0) THEN
CALL getGradients(Q,gradX,gradY)
CALL applyTVD_Gradients(gradX,gradY)
shock_indicator = zero
globmax = zero
DO i=1,nbrInt
idL = edges_ind(i,1)
idR = edges_ind(i,2)
n(1:2) = edges(i,1:2) ! x,y components of the external normal to the edge
ds = SQRT(n(1)*n(1) + n(2)*n(2)) ! length of the edge
n = n/ds ! normalize the normal
IDk = (idL-1)*nbvar + 1
tmp = gradX(IDk)*n(1) + gradY(IDk)*n(2)
IDk = (idR-1)*nbvar + 1
tmp2 = gradX(IDk)*n(1) + gradY(IDk)*n(2)
tmpmax = MAX(tmp,tmp2)
IF (ABS(tmpmax).LT.1.E-12) tmpmax = 1.E-12
shock_indicator(idL) = ABS(tmpmax)
shock_indicator(idR) = ABS(tmpmax)
globmax = MAX(globmax,ABS(tmpmax))
ENDDO
shock_indicator = shock_indicator / globmax
ENDIF
! Loop on the internal edges
!$OMP PARALLEL &
!$OMP& default (shared) &
!$OMP& private (temp,Fup,idL,idR,SL,SR,qL,qR,j,n,ds,FL,FR,Fav,qAv,dij,Hi,Hj,sourceloc_s,sourceloc_f) &
!$OMP& reduction(+: Hvec,Source_sf)
! chunck = nbrInt / omp_get_num_threads()
!$OMP DO
! schedule(static,chunck)
DO i=1,nbrInt
temp = zero
Fup = zero
idL = edges_ind(i,1) ! ID of 2D element, normal pointing outwards
idR = edges_ind(i,2) ! ID of 2D element, normal pointing inwards
SL = geom_data(idL,1)! area of element idL
SR = geom_data(idR,1)! area of element idR
Xij = geom_data(idR,3) - geom_data(idL,3)
Yij = geom_data(idR,4) - geom_data(idL,4)
qL = Q(idL*nbvar-2:idL*nbvar) ! solution h, hu, hv inside element idL
qR = Q(idR*nbvar-2:idR*nbvar) ! solution h, hu, hv inside element idR
! Reconstruct the solution at the edge to reach a 2nd order precision
IF (muscl .NE. 0) THEN
DO j=1,nbvar
qL(j) = qL(j) + 0.5d00 * ( gradX((idL-1)*nbvar+j)*Xij + gradY((idL-1)*nbvar+j)*Yij )
qR(j) = qR(j) - 0.5d00 * ( gradX((idR-1)*nbvar+j)*Xij + gradY((idR-1)*nbvar+j)*Yij )
ENDDO
ENDIF
IF (ABS(qL(1))<eps) qL(1)=eps
IF (ABS(qR(1))<eps) qR(1)=eps
qL(2:3) = qL(2:3)/qL(1)
qR(2:3) = qR(2:3)/qR(1)
n(1:2) = edges(i,1:2) ! x,y components of the external normal to the edge
ds = SQRT(n(1)*n(1) + n(2)*n(2)) ! length of the edge
n = n/ds ! normalize the normal
CALL getFlux(qL,FL) ! Get the local flux for the cell left of the edge
CALL getFlux(qR,FR) ! Get the local flux for the cell right of the edge
! Average the flux
Fav = ((SL*FL(:,1) + SR*FR(:,1))*n(1) + (SL*FL(:,2) + SR*FR(:,2))*n(2))/(SL+SR)
qAv = (SL*qL + SR*qR)/(SL+SR) ! Average the solution
! Get the distance from center of element to center of edge
dij = SQRT( ( geom_data(idL,3) - edges(i,3) )**2 + ( geom_data(idL,4) - edges(i,4) )**2 )
Hi = depth(idL) ! geometric depth, cell left to the edge
Hj = depth(idR) ! geometric depth, cell right to the edge
! Get the upwind + source terms
CALL getUpwind_and_Source(qL,qR,qAv,n,Fup,sourceloc_f,sourceloc_s,Hi,Hj,dij,iswall,ds,SL)
! Add the contribution to the element idL
temp = (Fav + Fup)*ds/SL
! write(*,'(3i3,2f20.15)') i,omp_get_thread_num(),idL*nbvar,Hvec(idL*nbvar),temp(3)
Hvec (idL*nbvar-2:idL*nbvar) = Hvec (idL*nbvar-2:idL*nbvar) + temp
Source_sf(idL*nbvar-2:idL*nbvar) = Source_sf(idL*nbvar-2:idL*nbvar) + (sourceloc_f+sourceloc_s) * edges(i,5) / SL
! Add the contribution to the other element idR, Fav -> -Fav
n = -n
! Get the distance from center of element to center of edge
dij = SQRT( ( geom_data(idR,3) - edges(i,3) )**2 + ( geom_data(idR,4) - edges(i,4) )**2 )
! Get the upwind + source terms
CALL getUpwind_and_Source(qR,qL,qAv,n,Fup,sourceloc_f,sourceloc_s,Hj,Hi,dij,iswall,ds,SR)
! Add the contribution to the element idR
temp = (- Fav + Fup)*ds/SR
Hvec (idR*nbvar-2:idR*nbvar) = Hvec (idR*nbvar-2:idR*nbvar) + temp
Source_sf(idR*nbvar-2:idR*nbvar) = Source_sf(idR*nbvar-2:idR*nbvar) + (sourceloc_f+sourceloc_s) * edges(i,6) / SR
END DO
!$OMP END DO
!$OMP END PARALLEL
! Loop on the border edges to take into account the boundary conditions
!$OMP PARALLEL &
!$OMP& default (shared) &
!$OMP& private (temp,Fup,idL,idR,SL,SR,qL,qR,n,ds,iswall,h,u,v,c,Froude,FL,FR,Fav,qAv,dij,Hi,Hj,sourceloc_s,sourceloc_f) &
!$OMP& reduction(+: Hvec,Source_sf)
! chunck = nbrFront / omp_get_num_threads()
!$OMP DO
!schedule(static,chunck)
DO i=1,nbrFront
temp = zero
Fup = zero
idL = fnormal_ind(i,1) ! ID of 2D element
SL = geom_data(idL,1) ! area of element idL
qL = Q(idL*nbvar-2:idL*nbvar) ! solution h, hu, hv inside element idL
IF (ABS(qL(1))<eps) qL(1)=eps
qL(2:3) = qL(2:3)/qL(1)
n(1:2) = fnormal(i,1:2) ! x,y components of the external normal to the edge
ds = SQRT(n(1)**2 + n(2)**2) ! length of the edge
n = n/ds ! normalize the normal
iswall = .FALSE.
! Select the type of boundary condition to impose
! Fill the array qR for the ghost cell
SELECT CASE (fnormal_ind(i,3))
CASE (0) ! inlet
h = BoundCond(fnormal_ind(i,4),1) ! imposed h
u = BoundCond(fnormal_ind(i,4),2) ! imposed u
v = BoundCond(fnormal_ind(i,4),3) ! imposed v
c = SQRT(ggrav*h) ! wave speed
Froude = SQRT(u*u+v*v)/c
IF(Froude.GE.1.0D00) THEN ! supercritical flow
qR(1) = 2.d00*h - qL(1)
qR(2) = 2.d00*u - qL(2)
qR(3) = 2.d00*v - qL(3)
ELSE ! subcritical flow
qR(1) = qL(1)
! Force to keep the prescribed unit discharge q = u qL(1)
u = u * h / qL(1)
v = v * h / qL(1)
qR(2) = 2.d00*u - qL(2)
qR(3) = 2.d00*v - qL(3)
ENDIF
CASE (1) ! outlet
h = BoundCond(fnormal_ind(i,4),1) ! imposed h
u = BoundCond(fnormal_ind(i,4),2) ! imposed u
v = BoundCond(fnormal_ind(i,4),3) ! imposed v
c = SQRT(ggrav*h) ! wave speed
Froude = SQRT(u*u+v*v)/c
IF(Froude.GE.1.0D00) THEN ! supercritical flow
qR = qL
ELSE ! subcritical
qR(1) = 2*h - qL(1)
qR(2:3) = qL(2:3)
ENDIF
CASE (2) ! wall, cancel the wall-normal velocity component
qR(1) = qL(1)
qR(2) = qL(2) - 2.d00*(qL(2)*n(1)+qL(3)*n(2))*n(1)
qR(3) = qL(3) - 2.d00*(qL(2)*n(1)+qL(3)*n(2))*n(2)
iswall = .TRUE.
CASE (3) ! symmetry
qR = qL
qR(2:3) = -qR(2:3)
CASE (4) ! periodicity
qR = qL
CASE DEFAULT
WRITE(*,*) "Error : unrecognized boundary condition ",fnormal_ind(i,3)
END SELECT
IF (muscl .NE. 0) THEN
! Retrieve qu and qv to reconstruct the solution with MUSCL
qL(2:3) = qL(2:3)*qL(1)
! Reconstruct the solution at the edge to reach a 2nd order precision
DO j=1,nbvar
qL(j) = qL(j) + 0.5d00 * ( gradX((idL-1)*nbvar+j)*Xij + gradY((idL-1)*nbvar+j)*Yij )
ENDDO
qL(2:3) = qL(2:3)/qL(1)
ENDIF
CALL getFlux(qL,FL) ! Get the local flux for the cell left of the edge
CALL getFlux(qR,FR) ! Get the local flux for the ghost cell
! Average the flux and the solution
Fav = 0.5d00*(FL(:,1)+FR(:,1))*n(1) + 0.5d00*(FL(:,2)+FR(:,2))*n(2)
qAv = 0.5d00*(qL+qR)
! Get the distance from center of element to center of edge
dij = SQRT( ( geom_data(idL,3) - fnormal(i,3) )**2 + ( geom_data(idL,4) - fnormal(i,4) )**2 )
Hi = depth(idL)
Hj = depth(idL)
! Get the upwind term. The source term is not relevant for border edges
CALL getUpwind_and_Source(qL,qR,qAv,n,Fup,sourceloc_f,sourceloc_s,Hi,Hj,dij,iswall,ds,SL)
! Add the contribution to the element idL
temp = (Fav + Fup)*ds/SL
Hvec(idL*nbvar-2:idL*nbvar) = Hvec(idL*nbvar-2:idL*nbvar) + temp
Source_sf(idL*nbvar-2:idL*nbvar) = Source_sf(idL*nbvar-2:idL*nbvar) + sourceloc_f * fnormal(i,5) / SL
END DO
!$OMP END DO
!$OMP END PARALLEL
END SUBROUTINE flux
!##########################################################
! SUBROUTINE getFlux
! Goal: compute the local flux defined by the finite volume method
! (h u) (h v)
! Fx = (h u^2 + 0.5 g h^2) Fy = (h u v)
! (h u v) (h v^2 + 0.5 g h^2)
!##########################################################
SUBROUTINE getFlux(q,F)
USE module_shallow
IMPLICIT NONE
! Subroutine parameters
REAL(kr), DIMENSION(nbvar), INTENT(IN) :: q
REAL(kr), DIMENSION(1:nbvar,1:2), INTENT(OUT) :: F
! Flux for the X-gradient
F(1,1) = q(1)*q(2)
F(2,1) = q(1)*q(2)*q(2) + 0.5d00*ggrav*q(1)*q(1)
F(3,1) = q(1)*q(2)*q(3)
! Flux for the Y-gradient
F(1,2) = q(1)*q(3)
F(2,2) = q(1)*q(2)*q(3)
F(3,2) = q(1)*q(3)*q(3) + 0.5d00*ggrav*q(1)*q(1)
END SUBROUTINE getFlux
!##########################################################
! SUBROUTINE getUpwind_and_Source
! Goal: compute the upwind correction flux defined by the finite volume method
! for both the flux and source terms
!##########################################################
SUBROUTINE getUpwind_and_Source(qL,qR,qAvg,n,Fout,source_f,source_s,Hi,Hj,dij,iswall,ds,omega)
USE module_shallow, only : kr,ki,ggrav,manning_b,manning_w,nbvar,zero
USE booklib
IMPLICIT NONE
! Subroutine parameters
REAL(kr), DIMENSION(2), INTENT(IN) :: n
REAL(kr), DIMENSION(1:nbvar), INTENT(IN) :: qL, qR, qAvg
REAL(kr), DIMENSION(1:nbvar), INTENT(OUT) :: Fout,source_f,source_s
REAL(kr), INTENT(IN) :: Hi, Hj, dij, ds,omega
LOGICAL, INTENT(IN) :: iswall
! Local parameters
REAL(kr), DIMENSION(1:nbvar,1:nbvar) :: Qmat,sourceMat
REAL(kr), DIMENSION(1:nbvar) :: qLloc, qRloc,tmp
REAL(kr) :: tempval, locdist
source_f = zero
source_s = zero
qLloc = QL
qRloc = QR
! Set again hu,hv as the variables
qLloc(2:3) = qLloc(2:3) * qLloc(1)
qRloc(2:3) = qRloc(2:3) * qRloc(1)
! Get the matrices abs(Q) = X abs(lambda) X-1
! and sourceMat = X ( I - abs(lambda) lambda-1 ) X-1
CALL upwind_term(qAvg,Qmat,sourceMat,n)
! Get the upwind correction term for the flux
tmp = MATMUL( Qmat , qRloc - qLloc )
Fout = - 0.5d00 * tmp
! Get the upwind corrected source term (bed slope)
tmp = zero
tempval = - 0.5d00 * ggrav * ( QL(1)+QR(1) ) * ( Hj - Hi ) / dij
tmp(2) = tempval*n(1)
tmp(3) = tempval*n(2)
source_s = MATMUL( sourceMat , tmp )
! Friction slope x: -g h n^2 u(u^2 + v^2)^(1/2) / h^(4/3)
! y: -g h n^2 v(u^2 + v^2)^(1/2) / h^(4/3)
tempval = - ggrav * QL(1) * sqrt(ql(2)**2 + qR(2)**2)
locdist = (manning_b)**(1.5D00) / QL(1)
IF (iswall) THEN
locdist = locdist + (manning_w)**(1.5D0) * ds / omega
ENDIF
source_f(2) = tempval * QL(2) * ( locdist**(4.D00 / 3.D00) )
source_f(3) = tempval * QL(3) * ( locdist**(4.D00 / 3.D00) )
! source_f(2) = - ggrav * QL(1) * manning_b*manning_b * QL(2) * sqrt(ql(2)**2 + qR(2)**2) / (QL(1)**(4.d00/3.d00))
! source_f(3) = - ggrav * QL(1) * manning_b*manning_b * QL(3) * sqrt(ql(2)**2 + qR(2)**2) / (QL(1)**(4.d00/3.d00))
! IF (iswall) THEN
! source_f(2) = source_f(2) - ggrav * QL(1) * manning_w*manning_w * QL(2) * sqrt(ql(2)**2 + qR(2)**2) / ((omega/ds)**(4.d00/3.d00))
! source_f(3) = source_f(3) - ggrav * QL(1) * manning_w*manning_w * QL(3) * sqrt(ql(2)**2 + qR(2)**2) / ((omega/ds)**(4.d00/3.d00))
! ENDIF
END SUBROUTINE getUpwind_and_Source
!##########################################################
! SUBROUTINE upwind_term
! Goal: get the matrices abs(Q) = X abs(lambda) X-1
! sourceMat = X ( I - abs(lambda) lambda-1 ) X-1
!##########################################################
SUBROUTINE upwind_term(q,Qmat,sourceMat,n)
USE module_shallow
USE booklib
IMPLICIT NONE
! Subroutine parameters
REAL(kr), DIMENSION(2), INTENT(IN) :: n
REAL(kr), DIMENSION(1:nbvar), INTENT(IN) :: q
REAL(kr), DIMENSION(1:nbvar,1:nbvar), INTENT(OUT) :: Qmat
REAL(kr), DIMENSION(1:nbvar,1:nbvar), INTENT(OUT) :: sourceMat
! Local parameters
REAL(kr) :: one = 1.0d00
REAL(kr), DIMENSION(1:nbvar,1:nbvar) :: X, Xm1, abslambda,invlambda,identity, temp, temp2
REAL(kr) :: h, u, v, c,lambda1, lambda2, lambda3
h = q(1)
u = q(2)
v = q(3)
c = SQRT(ggrav*h) ! wave speed
lambda1 = u*n(1)+v*n(2) ! first eigenvalue
lambda2 = lambda1 + c ! second eigenvalue
lambda3 = lambda1 - c ! third eigenvalue
! Fill in the matrix that contains the absolute eigenvalues on the diagonal
abslambda = zero
abslambda(1,1) = ABS(lambda1)
abslambda(2,2) = ABS(lambda2)
abslambda(3,3) = ABS(lambda3)
! Fill in the matrix that contains the inverse of the eigenvalues on the diagonal
invlambda = zero
IF (ABS(lambda1).EQ.zero) lambda1=eps
IF (ABS(lambda2).EQ.zero) lambda2=eps
IF (ABS(lambda3).EQ.zero) lambda3=eps
invlambda(1,1) = one/lambda1
invlambda(2,2) = one/lambda2
invlambda(3,3) = one/lambda3
! Identity matrix
identity = zero
identity(1,1) = one
identity(2,2) = one
identity(3,3) = one
! Row eigenvector matrix
X(1,1:3) = (/ zero, one, one /)
X(2,1:3) = (/-c*n(2), u+c*n(1), u-c*n(1)/)
X(3,1:3) = (/ c*n(1), v+c*n(2), v-c*n(2)/)
! Column eigenvector matrix
Xm1(1,1:3) = (/ 2*n(2)*u-2*n(1)*v, -2*n(2), 2*n(1) /)
Xm1(2,1:3) = (/ c-n(1)*u-n(2)*v, n(1), n(2) /)
Xm1(3,1:3) = (/ c+n(1)*u+n(2)*v, -n(1), -n(2) /)
Xm1 = Xm1 * 0.5d00 / c
! Compute abs(Q) = X abs(lambda) X-1
temp = MATMUL(abslambda,Xm1)
Qmat = MATMUL(X,temp)
! Compute sourceMat = X ( I - abs(lambda) lambda-1 ) X-1
temp = MATMUL(abslambda,invlambda)
temp = identity - temp
temp2 = MATMUL(temp,Xm1)
sourceMat = MATMUL(X,temp2)
END SUBROUTINE upwind_term
SUBROUTINE getGradients(q,gradX,gradY)
USE module_shallow
USE OMP_LIB
IMPLICIT NONE
! Subroutine parameters
REAL(kr), DIMENSION(1:nbvar*nbrElem), INTENT(IN) :: q
REAL(kr), DIMENSION(1:nbvar*nbrElem), INTENT(OUT) :: gradX, gradY
! Local parameters
INTEGER(ki) :: i,j,k,IDj
REAL(kr) :: Ixx,Iyy,Ixy,D
REAL(kr), DIMENSION(nbvar) :: Jx,Jy
gradX = zero
gradY = zero
!$OMP PARALLEL &
!$OMP& default (shared) &
!$OMP& private (Ixx,Iyy,Ixy,Jx,Jy,D,j,k,IDj)
!$OMP DO
DO i=1,nbrElem
Ixx = zero
Iyy = zero
Ixy = zero
Jx = zero
Jy = zero
DO j=1,nbr_nodes_per_elem(i)
IDj = geom_data_ind(i,j)
IF (IDj.EQ.0) CYCLE
Ixx = Ixx + (geom_data(IDj,3)-geom_data(i,3))*(geom_data(IDj,3)-geom_data(i,3))
Iyy = Iyy + (geom_data(IDj,4)-geom_data(i,4))*(geom_data(IDj,4)-geom_data(i,4))
Ixy = Ixy + (geom_data(IDj,3)-geom_data(i,3))*(geom_data(IDj,4)-geom_data(i,4))
DO k=1,nbvar
Jx(k) = Jx(k) + (geom_data(IDj,3)-geom_data(i,3))*(q((IDj-1)*nbvar+k)-q((i-1)*nbvar+k))
Jy(k) = Jy(k) + (geom_data(IDj,4)-geom_data(i,4))*(q((IDj-1)*nbvar+k)-q((i-1)*nbvar+k))
ENDDO
ENDDO
D = Ixx*Iyy - Ixy*Ixy
DO k=1,nbvar
gradX((i-1)*nbvar+k) = (Jx(k)*Iyy - Jy(k)*Ixy)/D
gradY((i-1)*nbvar+k) = (Jy(k)*Ixx - Jx(k)*Ixy)/D
ENDDO
ENDDO
!$OMP END DO
!$OMP END PARALLEL
END SUBROUTINE getGradients
SUBROUTINE applyTVD_Gradients(gradX,gradY)
USE module_shallow
USE OMP_LIB
IMPLICIT NONE
! Subroutine parameters
REAL(kr), DIMENSION(1:nbvar*nbrElem), INTENT(INOUT) :: gradX, gradY
! Local parameters
INTEGER(ki) :: i,j,k,IDj,IDk
REAL(kr), DIMENSION(1:nbvar*nbrElem) :: gradXlim, gradYlim, signX, signY
REAL(kr), DIMENSION(1:nbvar) :: minVx, minVy, minSVx, minSVy, maxSVx, maxSVy
signX = gradX
signY = gradY
WHERE (signX>zero)
signX = 1.d00
ELSEWHERE (signX<zero)
signX = -1.d00
END WHERE
WHERE (signY>zero)
signY = 1.d00
ELSEWHERE (signY<zero)
signY = -1.d00
END WHERE
!$OMP PARALLEL &
!$OMP& default (shared) &
!$OMP& private (minVx,minVy,minSVx,minSVy,maxSVx,maxSVy,j,IDj,k,IDk)
!$OMP DO
DO i=1,nbrElem
minVx = 1.E16
minVy = 1.E16
minSVx = 1.E16
minSVy = 1.E16
maxSVx = zero
maxSVy = zero
DO j=1,nbr_nodes_per_elem(i)
IDj = geom_data_ind(i,j)
DO k=1,nbvar
IDk = (IDj-1)*nbvar+k
minVx(k) = min( minVx(k) , abs(gradX( IDk ) ) )
minVy(k) = min( minVy(k) , abs(gradY( IDk ) ) )
minSVx(k)= min( minSVx(k), signX( IDk ) )
minSVy(k)= min( minSVy(k), signY( IDk ) )
maxSVx(k)= max( maxSVx(k), signX( IDk ) )
maxSVy(k)= max( maxSVy(k), signY( IDk ) )
ENDDO
ENDDO
DO k=1,nbvar
gradXlim((i-1)*nbvar+k) = 0.5d00 * ( minSVx(k) + maxSVx(k) ) * minVx(k)
gradYlim((i-1)*nbvar+k) = 0.5d00 * ( minSVy(k) + maxSVy(k) ) * minVy(k)
ENDDO
ENDDO
!$OMP END DO
!$OMP END PARALLEL
gradX = gradXlim
gradY = gradYlim
END SUBROUTINE applyTVD_Gradients