gradle-bintray-push.gradle

/*
 * Copyright 2015 James Barr
 *
 * Licensed under the Apache License, Version 2.0 (the "License");
 * you may not use this file except in compliance with the License.
 * You may obtain a copy of the License at
 *
 *     http://www.apache.org/licenses/LICENSE-2.0
 *
 * Unless required by applicable law or agreed to in writing, software
 * distributed under the License is distributed on an "AS IS" BASIS,
 * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
 * See the License for the specific language governing permissions and
 * limitations under the License.
 */

// NOTE: be sure to have the following items added to your buildscript's dependencies in your root build.gradle:
//
//       classpath 'com.github.dcendents:android-maven-plugin:1.2'
//       classpath 'com.jfrog.bintray.gradle:gradle-bintray-plugin:1.1'

apply plugin: 'com.github.dcendents.android-maven'
apply plugin: 'com.jfrog.bintray'

install {
    repositories.mavenInstaller {
        pom.project {
            name POM_NAME
            packaging POM_PACKAGING
            description POM_DESCRIPTION
            url POM_URL

            scm {
                url POM_SCM_URL
                connection POM_SCM_CONNECTION
                developerConnection POM_SCM_DEV_CONNECTION
            }

            licenses {
                license {
                    name POM_LICENCE_NAME
                    url POM_LICENCE_URL
                    distribution POM_LICENCE_DIST
                }
            }

            developers {
                developer {
                    id POM_DEVELOPER_ID
                    name POM_DEVELOPER_NAME
                }
            }
        }
    }
}

task androidJavadocs(type: Javadoc) {
    source = android.sourceSets.main.java.srcDirs
    classpath += project.files(android.getBootClasspath().join(File.pathSeparator))
}

task androidJavadocsJar(type: Jar, dependsOn: androidJavadocs) {
    classifier = 'javadoc'
    from androidJavadocs.destinationDir
}

task androidSourcesJar(type: Jar) {
    classifier = 'sources'
    from android.sourceSets.main.java.sourceFiles
}

artifacts {
    archives androidSourcesJar
    archives androidJavadocsJar
}

bintray {
    user = BINTRAY_USER
    key = BINTRAY_API_KEY

    configurations = ['archives']
    dryRun = false
    publish = true
    pkg {
        repo = BINTRAY_REPO
        userOrg = BINTRAY_ORGANIZATION
        name = BINTRAY_PROJECT_NAME
        websiteUrl = BINTRAY_SITE_URL
        vcsUrl = BINTRAY_GIT_URL
        licenses = [BINTRAY_PROJECT_LICENSE]
        version {
            gpg {
                sign = true // Determines whether to GPG sign the files. The default is false
                passphrase = BINTRAY_GPG_PASSWORD // Optional. The passphrase for GPG signing'
            }
            mavenCentralSync {
                sync = true // Optional (true by default). Determines whether to sync the version to Maven Central.
                user = BINTRAY_OSS_USER // OSS user token
                password = BINTRAY_OSS_PASSWORD // OSS user password
                close = '1' // Optional property. By default the staging repository is closed and artifacts are released to Maven Central. You can optionally turn this behaviour off (by puting 0 as value) and release the version manually.
            }
        }
    }
}