-
-
Notifications
You must be signed in to change notification settings - Fork 298
/
lookup_refs.cljc
274 lines (218 loc) · 9.96 KB
/
lookup_refs.cljc
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
(ns datascript.test.lookup-refs
(:require
#?(:cljs [cljs.test :as t :refer-macros [is are deftest testing]]
:clj [clojure.test :as t :refer [is are deftest testing]])
[datascript.core :as d]
[datascript.db :as db]
[datascript.test.core :as tdc])
#?(:clj
(:import [clojure.lang ExceptionInfo])))
(deftest test-lookup-refs
(let [db (d/db-with (d/empty-db {:name { :db/unique :db.unique/identity }
:email { :db/unique :db.unique/value }})
[{:db/id 1 :name "Ivan" :email "@1" :age 35}
{:db/id 2 :name "Petr" :email "@2" :age 22}])]
(are [eid res] (= (tdc/entity-map db eid) res)
[:name "Ivan"] {:db/id 1 :name "Ivan" :email "@1" :age 35}
[:email "@1"] {:db/id 1 :name "Ivan" :email "@1" :age 35}
[:name "Sergey"] nil
[:name nil] nil)
(are [eid msg] (thrown-msg? msg (d/entity db eid))
[:name] "Lookup ref should contain 2 elements: [:name]"
[:name 1 2] "Lookup ref should contain 2 elements: [:name 1 2]"
[:age 10] "Lookup ref attribute should be marked as :db/unique: [:age 10]")))
(deftest test-lookup-refs-transact
(let [db (d/db-with (d/empty-db {:name { :db/unique :db.unique/identity }
:friend { :db/valueType :db.type/ref }})
[{:db/id 1 :name "Ivan"}
{:db/id 2 :name "Petr"}])]
(are [tx res] (= res (tdc/entity-map (d/db-with db tx) 1))
;; Additions
[[:db/add [:name "Ivan"] :age 35]]
{:db/id 1 :name "Ivan" :age 35}
[{:db/id [:name "Ivan"] :age 35}]
{:db/id 1 :name "Ivan" :age 35}
[[:db/add 1 :friend [:name "Petr"]]]
{:db/id 1 :name "Ivan" :friend {:db/id 2}}
[[:db/add 1 :friend [:name "Petr"]]]
{:db/id 1 :name "Ivan" :friend {:db/id 2}}
[{:db/id 1 :friend [:name "Petr"]}]
{:db/id 1 :name "Ivan" :friend {:db/id 2}}
[{:db/id 2 :_friend [:name "Ivan"]}]
{:db/id 1 :name "Ivan" :friend {:db/id 2}}
;; lookup refs are resolved at intermediate DB value
[[:db/add 3 :name "Oleg"]
[:db/add 1 :friend [:name "Oleg"]]]
{:db/id 1 :name "Ivan" :friend {:db/id 3}}
;; CAS
[[:db.fn/cas [:name "Ivan"] :name "Ivan" "Oleg"]]
{:db/id 1 :name "Oleg"}
[[:db/add 1 :friend 1]
[:db.fn/cas 1 :friend [:name "Ivan"] 2]]
{:db/id 1 :name "Ivan" :friend {:db/id 2}}
[[:db/add 1 :friend 1]
[:db.fn/cas 1 :friend 1 [:name "Petr"]]]
{:db/id 1 :name "Ivan" :friend {:db/id 2}}
;; Retractions
[[:db/add 1 :age 35]
[:db/retract [:name "Ivan"] :age 35]]
{:db/id 1 :name "Ivan"}
[[:db/add 1 :friend 2]
[:db/retract 1 :friend [:name "Petr"]]]
{:db/id 1 :name "Ivan"}
[[:db/add 1 :age 35]
[:db.fn/retractAttribute [:name "Ivan"] :age]]
{:db/id 1 :name "Ivan"}
[[:db.fn/retractEntity [:name "Ivan"]]]
nil)
(are [tx msg] (thrown-msg? msg (d/db-with db tx))
[{:db/id [:name "Oleg"], :age 10}]
"Nothing found for entity id [:name \"Oleg\"]"
[[:db/add [:name "Oleg"] :age 10]]
"Nothing found for entity id [:name \"Oleg\"]")
))
(deftest test-lookup-refs-transact-multi
(let [db (d/db-with (d/empty-db {:name { :db/unique :db.unique/identity }
:friends { :db/valueType :db.type/ref
:db/cardinality :db.cardinality/many }})
[{:db/id 1 :name "Ivan"}
{:db/id 2 :name "Petr"}
{:db/id 3 :name "Oleg"}
{:db/id 4 :name "Sergey"}])]
(are [tx res] (= (tdc/entity-map (d/db-with db tx) 1) res)
;; Additions
[[:db/add 1 :friends [:name "Petr"]]]
{:db/id 1 :name "Ivan" :friends #{{:db/id 2}}}
[[:db/add 1 :friends [:name "Petr"]]
[:db/add 1 :friends [:name "Oleg"]]]
{:db/id 1 :name "Ivan" :friends #{{:db/id 2} {:db/id 3}}}
[{:db/id 1 :friends [:name "Petr"]}]
{:db/id 1 :name "Ivan" :friends #{{:db/id 2}}}
[{:db/id 1 :friends [[:name "Petr"]]}]
{:db/id 1 :name "Ivan" :friends #{{:db/id 2}}}
[{:db/id 1 :friends [[:name "Petr"] [:name "Oleg"]]}]
{:db/id 1 :name "Ivan" :friends #{{:db/id 2} {:db/id 3}}}
[{:db/id 1 :friends [2 [:name "Oleg"]]}]
{:db/id 1 :name "Ivan" :friends #{{:db/id 2} {:db/id 3}}}
[{:db/id 1 :friends [[:name "Petr"] 3]}]
{:db/id 1 :name "Ivan" :friends #{{:db/id 2} {:db/id 3}}}
;; reverse refs
[{:db/id 2 :_friends [:name "Ivan"]}]
{:db/id 1 :name "Ivan" :friends #{{:db/id 2}}}
[{:db/id 2 :_friends [[:name "Ivan"]]}]
{:db/id 1 :name "Ivan" :friends #{{:db/id 2}}}
[{:db/id 2 :_friends [[:name "Ivan"] [:name "Oleg"]]}]
{:db/id 1 :name "Ivan" :friends #{{:db/id 2}}}
)))
(deftest lookup-refs-index-access
(let [db (d/db-with (d/empty-db {:name { :db/unique :db.unique/identity }
:friends { :db/valueType :db.type/ref
:db/cardinality :db.cardinality/many}})
[{:db/id 1 :name "Ivan" :friends [2 3]}
{:db/id 2 :name "Petr" :friends 3}
{:db/id 3 :name "Oleg"}])]
(are [index attrs datoms] (= (map (juxt :e :a :v) (apply d/datoms db index attrs)) datoms)
:eavt [[:name "Ivan"]]
[[1 :friends 2] [1 :friends 3] [1 :name "Ivan"]]
:eavt [[:name "Ivan"] :friends]
[[1 :friends 2] [1 :friends 3]]
:eavt [[:name "Ivan"] :friends [:name "Petr"]]
[[1 :friends 2]]
:aevt [:friends [:name "Ivan"]]
[[1 :friends 2] [1 :friends 3]]
:aevt [:friends [:name "Ivan"] [:name "Petr"]]
[[1 :friends 2]]
:avet [:friends [:name "Oleg"]]
[[1 :friends 3] [2 :friends 3]]
:avet [:friends [:name "Oleg"] [:name "Ivan"]]
[[1 :friends 3]])
(are [index attrs resolved-attrs] (= (vec (apply d/seek-datoms db index attrs))
(vec (apply d/seek-datoms db index resolved-attrs)))
:eavt [[:name "Ivan"]] [1]
:eavt [[:name "Ivan"] :name] [1 :name]
:eavt [[:name "Ivan"] :friends [:name "Oleg"]] [1 :friends 3]
:aevt [:friends [:name "Petr"]] [:friends 2]
:aevt [:friends [:name "Ivan"] [:name "Oleg"]] [:friends 1 3]
:avet [:friends [:name "Oleg"]] [:friends 3]
:avet [:friends [:name "Oleg"] [:name "Petr"]] [:friends 3 2]
)
(are [attr start end datoms] (= (map (juxt :e :a :v) (d/index-range db attr start end)) datoms)
:friends [:name "Oleg"] [:name "Oleg"]
[[1 :friends 3] [2 :friends 3]]
:friends [:name "Petr"] [:name "Petr"]
[[1 :friends 2]]
:friends [:name "Petr"] [:name "Oleg"]
[[1 :friends 2] [1 :friends 3] [2 :friends 3]])
))
(deftest test-lookup-refs-query
(let [schema {:name { :db/unique :db.unique/identity }
:friend { :db/valueType :db.type/ref }}
db (d/db-with (d/empty-db schema)
[{:db/id 1 :id 1 :name "Ivan" :age 11 :friend 2}
{:db/id 2 :id 2 :name "Petr" :age 22 :friend 3}
{:db/id 3 :id 3 :name "Oleg" :age 33 }])]
(is (= (set (d/q '[:find ?e ?v
:in $ ?e
:where [?e :age ?v]]
db [:name "Ivan"]))
#{[[:name "Ivan"] 11]}))
(is (= (set (d/q '[:find [?v ...]
:in $ [?e ...]
:where [?e :age ?v]]
db [[:name "Ivan"] [:name "Petr"]]))
#{11 22}))
(is (= (set (d/q '[:find [?e ...]
:in $ ?v
:where [?e :friend ?v]]
db [:name "Petr"]))
#{1}))
(is (= (set (d/q '[:find [?e ...]
:in $ [?v ...]
:where [?e :friend ?v]]
db [[:name "Petr"] [:name "Oleg"]]))
#{1 2}))
(is (= (d/q '[:find ?e ?v
:in $ ?e ?v
:where [?e :friend ?v]]
db [:name "Ivan"] [:name "Petr"])
#{[[:name "Ivan"] [:name "Petr"]]}))
(is (= (d/q '[:find ?e ?v
:in $ [?e ...] [?v ...]
:where [?e :friend ?v]]
db [[:name "Ivan"] [:name "Petr"] [:name "Oleg"]]
[[:name "Ivan"] [:name "Petr"] [:name "Oleg"]])
#{[[:name "Ivan"] [:name "Petr"]]
[[:name "Petr"] [:name "Oleg"]]}))
;; https://github.com/tonsky/datascript/issues/214
(is (= (d/q '[:find ?e
:in $ [?e ...]
:where [?e :friend 3]]
db [1 2 3 "A"])
#{[2]}))
(let [db2 (d/db-with (d/empty-db schema)
[{:db/id 3 :name "Ivan" :id 3}
{:db/id 1 :name "Petr" :id 1}
{:db/id 2 :name "Oleg" :id 2}])]
(is (= (d/q '[:find ?e ?e1 ?e2
:in $1 $2 [?e ...]
:where [$1 ?e :id ?e1]
[$2 ?e :id ?e2]]
db db2 [[:name "Ivan"] [:name "Petr"] [:name "Oleg"]])
#{[[:name "Ivan"] 1 3]
[[:name "Petr"] 2 1]
[[:name "Oleg"] 3 2]})))
(testing "inline refs"
(is (= (d/q '[:find ?v
:where [[:name "Ivan"] :friend ?v]]
db)
#{[2]}))
(is (= (d/q '[:find ?e
:where [?e :friend [:name "Petr"]]]
db)
#{[1]}))
(is (thrown-msg? "Nothing found for entity id [:name \"Valery\"]"
(d/q '[:find ?e
:where [[:name "Valery"] :friend ?e]]
db)))
)
))