build.gradle

plugins {
  id 'io.spinnaker.project' version "$spinnakerGradleVersion" apply false
}

allprojects {
  apply plugin: 'io.spinnaker.project'
}

subprojects {
  group = "io.spinnaker.rosco"

  if (name != "rosco-bom") {
    apply plugin: 'java-library'
    apply plugin: "groovy"

    dependencies {
      implementation enforcedPlatform("io.spinnaker.kork:kork-bom:$korkVersion")

      compileOnly "org.projectlombok:lombok"

      annotationProcessor enforcedPlatform("io.spinnaker.kork:kork-bom:$korkVersion")
      annotationProcessor "org.projectlombok:lombok"
      annotationProcessor("org.springframework.boot:spring-boot-configuration-processor")

      testCompileOnly "org.projectlombok:lombok"

      testAnnotationProcessor enforcedPlatform("io.spinnaker.kork:kork-bom:$korkVersion")
      testAnnotationProcessor "org.projectlombok:lombok"

      testRuntimeOnly "org.junit.jupiter:junit-jupiter-engine"
    }

    test {
      testLogging {
        exceptionFormat = 'full'
      }
      useJUnitPlatform()
    }
  }

  if (korkVersion.endsWith("-SNAPSHOT")) {
    logger.info("Enabling mavenLocal")
    repositories {
      mavenLocal()
    }
  }

  tasks.withType(JavaExec) {
    if (System.getProperty('DEBUG', 'false') == 'true') {
      jvmArgs '-agentlib:jdwp=transport=dt_socket,server=y,suspend=n,address=8187'
    }
  }

  tasks.withType(JavaCompile).configureEach {
    javaCompiler = javaToolchains.compilerFor {
      languageVersion = JavaLanguageVersion.of(11)
    }
  }
  tasks.withType(Test).configureEach {
    javaLauncher = javaToolchains.launcherFor {
      languageVersion = JavaLanguageVersion.of(17)
    }
  }
}

defaultTasks ':rosco-web:run'