Cannot use I2S Microphone with this library

[nitesh-1306]

I am using an I2S Microphone module and an I2S Amplifier Module. I configured everything, but the library configures I2S in transmission mode, which eventually disables my microphone as it requires receiver mode. How do I fix this? Can anyone help

[nitesh-1306]

Heres the code I am working on

#include <driver/i2s.h>
#include <SPIFFS.h>
#include <Arduino.h>
#include <Audio.h>

#define I2S_WS 18
#define I2S_SD 25
#define I2S_SCK 26
#define I2S_PORT I2S_NUM_0
#define I2S_SAMPLE_RATE   (16000)
#define I2S_SAMPLE_BITS   (16)
#define I2S_READ_LEN      (16 * 1024)
#define RECORD_TIME       (5) //Seconds
#define I2S_CHANNEL_NUM   (1)
#define FLASH_RECORD_SIZE (I2S_CHANNEL_NUM * I2S_SAMPLE_RATE * I2S_SAMPLE_BITS / 8 * RECORD_TIME)

#define I2S_DOUT      14
#define I2S_BCLK      27
#define I2S_LRC       12

File file;
Audio audio; // As soon as I create an object of type audio, i2s mode changes to I2S_MODE_TX
const char filename[] = "/recording.wav";
const int headerSize = 44;


void i2sInit(){
  i2s_config_t i2s_config = {
    .mode = (i2s_mode_t)(I2S_MODE_MASTER | I2S_MODE_RX), //Even if I am changing the mode here still the mode remains I2S_MODE_TX
    .sample_rate = I2S_SAMPLE_RATE,
    .bits_per_sample = i2s_bits_per_sample_t(I2S_SAMPLE_BITS),
    .channel_format = I2S_CHANNEL_FMT_ONLY_LEFT,
    .communication_format = i2s_comm_format_t(I2S_COMM_FORMAT_I2S | I2S_COMM_FORMAT_I2S_MSB),
    .intr_alloc_flags = 0,
    .dma_buf_count = 64,
    .dma_buf_len = 1024,
    .use_apll = 1
  };

  i2s_driver_install(I2S_PORT, &i2s_config, 0, NULL);

  const i2s_pin_config_t pin_config = {
    .bck_io_num = I2S_SCK,
    .ws_io_num = I2S_WS,
    .data_out_num = -1,
    .data_in_num = I2S_SD
  };

  i2s_set_pin(I2S_PORT, &pin_config);
}

void i2s_adc_data_scale(uint8_t * d_buff, uint8_t* s_buff, uint32_t len)
{
    uint32_t j = 0;
    uint32_t dac_value = 0;
    for (int i = 0; i < len; i += 2) {
        dac_value = ((((uint16_t) (s_buff[i + 1] & 0xf) << 8) | ((s_buff[i + 0]))));
        d_buff[j++] = 0;
        d_buff[j++] = dac_value * 256 / 2048;
    }
}

void i2s_adc(void *arg)
{
    int i2s_read_len = I2S_READ_LEN;
    int flash_wr_size = 0;
    size_t bytes_read;

    char* i2s_read_buff = (char*)calloc(i2s_read_len, sizeof(char));
    uint8_t* flash_write_buff = (uint8_t*)malloc(i2s_read_len * sizeof(uint8_t));

    if (i2s_read_buff == NULL || flash_write_buff == NULL) {
        Serial.println("Memory allocation error");
        vTaskDelete(NULL);
        return;
    }

    i2s_read(I2S_PORT, (void*)i2s_read_buff, i2s_read_len, &bytes_read, portMAX_DELAY);
    i2s_read(I2S_PORT, (void*)i2s_read_buff, i2s_read_len, &bytes_read, portMAX_DELAY);

    Serial.println(" *** Recording Start *** ");

    while (flash_wr_size < FLASH_RECORD_SIZE) {
        i2s_read(I2S_PORT, (void*)i2s_read_buff, i2s_read_len, &bytes_read, portMAX_DELAY);
        example_disp_buf((uint8_t*) i2s_read_buff, 64);

        i2s_adc_data_scale(flash_write_buff, (uint8_t*)i2s_read_buff, i2s_read_len);

        int bytes_to_write = min(i2s_read_len, FLASH_RECORD_SIZE - flash_wr_size);
        file.write((const byte*)flash_write_buff, bytes_to_write);

        flash_wr_size += bytes_to_write;
        ets_printf("Sound recording %u%%\n", flash_wr_size * 100 / FLASH_RECORD_SIZE);
        ets_printf("Never Used Stack Size: %u\n", uxTaskGetStackHighWaterMark(NULL));
    }

    file.close();

    free(i2s_read_buff);
    free(flash_write_buff);

    audio.connecttoFS(SPIFFS, "recording.wav"); //I used a prerecorded audio to test out speaker, mic is not recording anything but the speaker can play the audio
    vTaskDelete(NULL);
}

void example_disp_buf(uint8_t* buf, int length){
    printf("======\n");
    for (int i = 0; i < length; i++) {
        printf("%02x ", buf[i]);
        if ((i + 1) % 8 == 0) {
            printf("\n");
        }
    }
    printf("======\n");
}

void wavHeader(byte* header, int wavSize){
  header[0] = 'R';
  header[1] = 'I';
  header[2] = 'F';
  header[3] = 'F';
  unsigned int fileSize = wavSize + headerSize - 8;
  header[4] = (byte)(fileSize & 0xFF);
  header[5] = (byte)((fileSize >> 8) & 0xFF);
  header[6] = (byte)((fileSize >> 16) & 0xFF);
  header[7] = (byte)((fileSize >> 24) & 0xFF);
  header[8] = 'W';
  header[9] = 'A';
  header[10] = 'V';
  header[11] = 'E';
  header[12] = 'f';
  header[13] = 'm';
  header[14] = 't';
  header[15] = ' ';
  header[16] = 0x10;
  header[17] = 0x00;
  header[18] = 0x00;
  header[19] = 0x00;
  header[20] = 0x01;
  header[21] = 0x00;
  header[22] = 0x01;
  header[23] = 0x00;
  header[24] = 0x80;
  header[25] = 0x3E;
  header[26] = 0x00;
  header[27] = 0x00;
  header[28] = 0x00;
  header[29] = 0x7D;
  header[30] = 0x00;
  header[31] = 0x00;
  header[32] = 0x02;
  header[33] = 0x00;
  header[34] = 0x10;
  header[35] = 0x00;
  header[36] = 'd';
  header[37] = 'a';
  header[38] = 't';
  header[39] = 'a';
  header[40] = (byte)(wavSize & 0xFF);
  header[41] = (byte)((wavSize >> 8) & 0xFF);
  header[42] = (byte)((wavSize >> 16) & 0xFF);
  header[43] = (byte)((wavSize >> 24) & 0xFF);
  
}

void audio_info(const char *info) {
  Serial.print("audio_info: "); Serial.println(info);
}

void setup() {
  Serial.begin(115200);
  delay(10);

  if(!SPIFFS.begin(true)){
    Serial.println("SPIFFS initialisation failed!");
    return;
  }

  audio.setPinout(I2S_BCLK, I2S_LRC, I2S_DOUT);
  audio.setVolume(21);
  audio.forceMono(true);

  i2sInit();
  
  xTaskCreate(i2s_adc, "i2s_adc", 1024*2, NULL, 1, NULL);
}

void loop() {
  audio.loop();
}

[nitesh-1306]

Actually the Audio is getting saved in the spiffs but the audio is completely silent and when I checked the buffer, I found that no data is being received from mic, because even if I configure I2S for RX_Mode, the audio library object changes the mode to TX_Mode.

[schreibfaul1]

The library is meant for sound output, if you want to save data from one microphone simultaneously as wav you can use the second I2S channel. And half of the possible DMA is still free.

[nitesh-1306]

I'm relatively new to the I2S series, and your guidance is greatly appreciated. I was wondering if you could share some specific pointers or changes I should consider in my code to make the most of the second I2S channel and free DMA resources. What are the sections in my code where i can change the mic recording to 2nd channel of the i2s

[nitesh-1306]

I tried changing the port #define I2S_PORT I2S_NUM_0 to #define I2S_PORT I2S_NUM_1, but then at this point it gives error

char* i2s_read_buff = (char*)calloc(i2s_read_len, sizeof(char));
    uint8_t* flash_write_buff = (uint8_t*)malloc(i2s_read_len * sizeof(uint8_t));

    if (i2s_read_buff == NULL || flash_write_buff == NULL) {
        Serial.println("Memory allocation error");
        vTaskDelete(NULL);
        return;
    }

in i2s_adc function, it gives memory allocation error, on channel 1 it doesn't but as soon as I change to channel 2, it gives the error. Can you help me resolve this issue. Do I need to change any pins..?

#define I2S_WS 18
#define I2S_SD 25
#define I2S_SCK 26
#define I2S_PORT I2S_NUM_1
#define I2S_SAMPLE_RATE   (16000)
#define I2S_SAMPLE_BITS   (16)
#define I2S_READ_LEN      (16 * 1024)
#define RECORD_TIME       (5) //Seconds
#define I2S_CHANNEL_NUM   (1)
#define FLASH_RECORD_SIZE (I2S_CHANNEL_NUM * I2S_SAMPLE_RATE * I2S_SAMPLE_BITS / 8 * RECORD_TIME)

[nitesh-1306]

Ahh I got it working, I reduced the dma buffer size and the memory allocation error resolved. Also the code is working perfectly fine. Thankyou very much for the help.