Write invariant test for tokenURI

[PaulRBerg]

Idea

It would be nice to add an invariant test for the tokenURI implemented in #440.

We could do it like this:

• Install svglint as a Node.js dev dependency
• Use vm.ffi to run pnpm svglint from within Solidity
• Define an invariant test like the one in the code snippet below
• Use Foundry's recently introduced inline test configuration to override the default number of runs - as this would be a heavy-load test, which would read and write content to files.

I have tried to write it myself now, but I encountered this bug in Foundry, so I will just mark this as "backlog" for the time being.

Code Snippet

import { Base64 } from "solady/utils/Base64.sol";
import { LibString } from "solady/utils/LibString.sol";

/// @dev Extracts the SVG from a base-64 encoded token URI.
function extractSVG(string memory uri) internal returns (string memory) {
    string memory decodedURI = string(Base64.decode(uri));
    string memory sanitizedURI = decodedURI.replace({ search: "data:application/json;base64,", replacement: "" });
    string memory image = vm.parseJsonString(sanitizedURI, ".image");
    string memory sanitizedImage = image.replace({ search: "data:image/svg+xml;base64,", replacement: "" });
    string memory svg = string(Base64.decode(sanitizedImage));
    return svg;
}

/// forge-config: default.invariant.depth = 1
/// forge-config: default.invariant.runs = 1
function invariant_TokenURI() external useCurrentTimestamp {
    uint256 lastStreamId = lockupStore.lastStreamId();
    for (uint256 i = 0; i < lastStreamId; ++i) {
        uint256 streamId = lockupStore.streamIds(i);

        // Skip burned NFTs.
        if (lockup.getRecipient(streamId) == address(0)) {
            continue;
        }

        string memory uri = lockup.tokenURI(streamId);
        string memory svg = extractSVG(uri);
        string memory filePath = "test/nft.svg";
        vm.writeFile(filePath, svg);

        string[] memory inputs = new string[](3);
        inputs[0] = "pnpm";
        inputs[1] = "svglint";
        inputs[2] = filePath;

        // TODO: check result
        bytes memory response = vm.ffi(inputs);
        console2.logBytes(response);
    }
}