initial commit

Author: seandepagnier

.gitignore

@@ -0,0 +1 @@
+*.stl

README

@@ -0,0 +1 @@
+This repository contains models for various 3d printed parts used in the pypilot project.

anemometer/cup.scad

@@ -0,0 +1,70 @@
+$fn=60;
+
+cup_d = 45;
+cup_r = 50;
+
+bearing_d = 22.3;
+bearing_h = 7;
+
+angle=86;
+
+pipe_d=10;
+
+magnet_d=4;
+
+key_r=.9;
+
+difference() {
+    union() {
+        translate([0, 0, -bearing_h])
+        
+        minkowski() {
+            cylinder(r=bearing_d/2+1, h=bearing_h*2+key_r*2);
+            sphere(1.4);
+        }
+        translate([0, 0, bearing_h-key_r])
+            minkowski() {
+                cylinder(r=bearing_d/2+1.5, h=key_r*2);
+                sphere(1.4);
+            }
+        for(i=[0:2])
+            rotate(i*120) {
+              difference() {
+                rotate([angle, 0, 0]) {
+                   cylinder(r=cup_d/8, h=cup_r);
+                   scale([.7, 1, 1]) {
+                      translate([0, 0, cup_r*3/4])
+                         cylinder(r1=cup_d/8, r2=cup_d/3, h=cup_r/3);
+                      translate([0, 0, cup_r*1/5])
+                         cylinder(r2=cup_d/8, r1=cup_d/6, h=cup_r/3);
+                   }
+                   translate([cup_r/8, 0, cup_r+cup_d/3])
+                      sphere(cup_d/2);
+                }
+                translate([0, -cup_r-cup_d, -cup_d/2]) 
+                    cube([cup_d, cup_d*3, cup_d*2]);
+                rotate([angle, 0, 0]) 
+                  translate([cup_r/8, 0, cup_r+cup_d/3])
+                     sphere(.94*cup_d/2);
+            }
+         }
+    }
+
+  translate([0, 0, -1])
+    cylinder(r=bearing_d/2, h=bearing_h*2);
+  translate([0, 0, -2])
+    cylinder(r=bearing_d/2-2, h=bearing_h*2);
+
+  cylinder(r=pipe_d/2, h=bearing_h*3, center=true);
+  translate([0, 0, -bearing_d/4])
+    rotate(60)
+      rotate([90, 0, 0])
+        cylinder(r=magnet_d/2, h=bearing_d/2);
+
+  for(i=[0:2])
+      translate([0, 0, bearing_h])
+        rotate(60+120*i)
+          rotate([90, 0, 0])
+            cylinder(r=key_r, h=bearing_d*2);
+
+}

anemometer/naca4.scad

@@ -0,0 +1,60 @@
+// Naca4.scad - library for parametric airfoils of 4 digit NACA series
+// Code: Rudolf Huttary, Berlin 
+// June 2015
+// commercial use prohibited
+
+
+// general use: for more examples refer to sampler.scad
+// naca = naca digits or 3el vector  (default = 12 or [0, 0, .12])
+// L    = chord length [mm]      (default= 100)
+// N    = # sample points        (default= 81)
+// h    = height [mm]            (default= 1)
+// open = close at the thin end? (default = true)
+// two equivalent example calls
+// airfoil(naca = 2408, L = 60, N=1001, h = 30, open = false); 
+// airfoil(naca = [.2, .4, .32], L = 60, N=1001, h = 30, open = false); 
+
+module help_Naca4()
+{
+  echo(str("\n\nList of signatures in lib:\n=================\n", 
+  "module help() - displays this help\n",
+  "module help_Naca() - displays this help\n",
+  "module help_Naca4() - displays this help\n",
+  "module airfoil(naca=2412, L = 100, N = 81, h = 1, open = false) - renders airfoil object\n", 
+  "module airfoil(naca=[.2, .4, .12], L = 100, N = 81, h = 1, open = false) - renders airfoil object using percentage for camber,  camber distance and thicknes\n", 
+  "function airfoil_data(naca=12, L = 100, N = 81, open = false)\n",
+  "=================\n")); 
+}
+
+module help() help_Naca4(); 
+
+// help(); 
+// this is the object
+module airfoil(naca=12, L = 100, N = 81, h = 1, open = false)
+{
+  linear_extrude(height = h)
+  polygon(points = airfoil_data(naca, L, N, open)); 
+}
+
+// this is the main function providing the airfoil data
+function airfoil_data(naca=12, L = 100, N = 81, open = false) = 
+  let(Na = len(naca)!=3?NACA(naca):naca)
+  let(A = [.2969, -0.126, -.3516, .2843, open?-0.1015:-0.1036])
+  [for (b=[-180:360/(N):179.99]) 
+    let (x = (1-cos(b))/2)  
+    let(yt = sign(b)*Na[2]/.2*(A*[sqrt(x), x, x*x, x*x*x, x*x*x*x])) 
+    Na[0]==0?L*[x, yt]:L*camber(x, yt, Na[0], Na[1], sign(b))];  
+
+// helper functions
+function NACA(naca) = 
+  let (M = floor(naca/1000))
+  let (P = floor((naca-M*1000)/100)) 
+  [M/100, P/10, floor(naca-M*1000-P*100)/100];  
+
+function camber(x, y, M, P, upper) = 
+  let(yc = (x<P)?M/P/P*(2*P*x-x*x): M/(1-P)/(1-P)*(1 - 2*P + 2*P*x -x*x))
+  let(dy = (x<P)?2*M/P/P*(P-x):2*M/(1-P)/(1-P)*(P-x))
+  let(th = atan(dy))
+  [upper ? x - y*sin(th):x + y*sin(th), upper ? yc + y*cos(th):yc - y*cos(th)];
+
+

anemometer/original/bearing_spacer.scad

@@ -0,0 +1,15 @@
+$fn=60;
+
+module spacer()
+  difference() {
+    union() {
+        cylinder(r=6/2, h=18, center=true);
+    //    cylinder(r=8/2, h=6, center=true);
+    }
+    cylinder(r=5/2, h=19, center=true);
+  }
+  
+
+spacer();
+//translate([20, 0, 0])
+  //  spacer();

anemometer/original/body.scad

@@ -0,0 +1,222 @@
+$fn=40;
+
+support_diameter = 15.6;
+radius = 13;
+
+top_ball_bearing = 1;
+top_bearing_diameter = 17.8;
+top_bearing_height = 6.4;
+top_bearing_spacing = 6;
+top_bearing_inside = 14;
+
+top_sleeve_size=6.5;
+top_sleeve_inside = 5.2;
+
+magnet_height = 15;
+magnet_diameter = 14;
+
+bottom_ball_bearing = 1;
+bottom_bearing_diameter = 17.8;
+bottom_bearing_height = 6.4;
+bottom_bearing_spacing = 6;
+bottom_bearing_inside = 14;
+bottom_nut_height = 1;
+
+bottom_sleeve_size=6.5;
+bottom_sleeve_inside = 5.2;
+
+bottom_bolt_height = 7;
+bottom_bolt_diameter = 14;
+
+reed_sensor=0;
+reed_offset=9.4;
+reed_diameter=2.8;
+reed_length=17;
+
+hall_sensor=1;
+hall_offset=8;
+
+height = 80;
+
+ fit = 0.4;
+
+module screw_hole(h, r) {
+        union() {
+            cylinder(h=h, r=r);
+            translate([0, 0, 12])
+            cylinder(h=7, r2=6, r1=r);
+        }
+}
+
+module body() {
+  difference() {
+   union() {
+     cylinder(h=height*2/3, r=radius, center=true);
+      rotate(90, [1, 0, 0])
+        cylinder(h=support_diameter*2, r1=radius, r2=support_diameter/2+2);
+      translate([0, 0, -height*7/18+1])
+        cylinder(h=height/9+1, r=radius*.9, center=true);
+       translate([0, 0, -height*8/18-1.5])
+       cylinder(h=height/18+1, r=1*radius, center=true);
+
+       // top cone
+      translate([0, 0, height/3])
+        cylinder(h=height/5, r1=radius*1.1, r2=radius*.8 + .5);
+       
+       // support for speed wiring
+        translate([0, -reed_offset,  bottom_bearing_start + height/4+1])
+            cylinder(h=height/2, r=reed_diameter/2+1.2, center=true);
+   }
+
+    // vane bearing holder
+    if(top_ball_bearing) {
+     translate([0, 0, height/2-top_bearing_height/2+.1-1])
+      cylinder(h=top_bearing_height, r=top_bearing_diameter/2, center=true);
+     translate([0, 0, height/2 - top_bearing_height*3/2 - top_bearing_spacing-1])
+      cylinder(h=top_bearing_height, r=top_bearing_diameter/2, center=true);
+     translate([0, 0, height/2 - top_bearing_height - top_bearing_spacing/2-1]) {
+        cylinder(h=top_bearing_spacing+2, r=    top_bearing_diameter/2 - fit*2, center=true);
+        cylinder(h=top_bearing_spacing+top_bearing_height*2+3, r=    top_bearing_inside/2, center=true);
+     }
+       translate([0, 0, height/2 - top_bearing_height - top_bearing_spacing/2-1]) {
+          cylinder(h=top_bearing_spacing+2, r=    top_bearing_diameter/2 - fit*2, center=true);
+          cylinder(h=top_bearing_spacing+top_bearing_height*2+3, r=top_bearing_inside/2, center=true);
+       }
+     } else {
+        translate([0, 0, height/2 - top_bearing_height - top_bearing_spacing/2+1])
+            cylinder(h=top_bearing_spacing+top_bearing_height*2+3, r= top_sleeve_size/2, center=true);
+        translate([0, 0, height/2 - top_bearing_height - top_bearing_spacing/2-1])
+            cylinder(h=top_bearing_spacing+top_bearing_height*2+3, r=top_sleeve_inside/2, center=true);
+     }
+
+     // magnet
+     translate([0, 0, height/2 - top_bearing_height*2 - top_bearing_spacing - magnet_height/2 -2])
+         cylinder(h=magnet_height, r=magnet_diameter/2, center=true);   
+
+   // keyhole
+   rotate(90, [0, 1, 0])
+   translate([0, -3/2*radius, 0])
+       cylinder(h=25, r=1.8, center=true); 
+ 
+   // main cutaway
+     cylinder(h=support_diameter, r=support_diameter/2+1, center=true);
+ 
+    bottom_bearing_start=-height/2;
+    
+    // circuit board
+    translate([0, 0, 6])
+    cube([18.4, 12, 2], center=true);
+    
+    // cups bearing holders
+        translate([0, 0, bottom_bearing_start+bottom_bearing_height*2+bottom_bearing_spacing+bottom_bolt_height/2+bottom_nut_height-.5])
+        cylinder(h=bottom_bolt_height+.1, r=bottom_bolt_diameter/2, center=true);
+    
+    if(bottom_ball_bearing) {
+        translate([0, 0, bottom_bearing_start+bottom_bearing_height*3/2+bottom_bearing_spacing+bottom_nut_height-1])
+        cylinder(h=bottom_bearing_height, r=bottom_bearing_diameter/2, center=true);
+        translate([0, 0, bottom_bearing_start+bottom_bearing_height+bottom_bearing_spacing/2+bottom_nut_height]) {
+            cylinder(h=bottom_bearing_spacing+1, r=bottom_bearing_diameter/2 - 2*fit, center=true);
+            cylinder(h=bottom_bearing_spacing+bottom_bearing_height*2+3, r=bottom_bearing_inside/2, center=true);
+        }
+
+     translate([0, 0, bottom_bearing_start+(bottom_bearing_height+bottom_nut_height)/2+1])
+      cylinder(h=bottom_bearing_height+bottom_nut_height+.1, r=bottom_bearing_diameter/2, center=true);
+     } else {
+         translate([0, 0, bottom_bearing_start+bottom_bearing_height+bottom_bearing_spacing/2+bottom_nut_height+2])
+       cylinder(h=bottom_bearing_spacing+bottom_bearing_height*2+3, r=bottom_sleeve_size/2, center=true);
+         translate([0, 0, bottom_bearing_start+bottom_bearing_height+bottom_bearing_spacing/2+bottom_nut_height])
+       cylinder(h=bottom_bearing_spacing+bottom_bearing_height*2+3, r=bottom_sleeve_inside/2, center=true);
+     }
+
+     // slot for reed sensor
+     if(reed_sensor) {
+     translate([0, -reed_offset,  bottom_bearing_start + height/4+.2+5])
+      cylinder(h=height/2, r=1.2, center=true);
+     translate([0, -reed_offset, bottom_bearing_start+.8]) 
+       scale([1,1,1.4])
+       rotate([0,90,0])
+       cylinder(h=reed_length, r=reed_diameter/2, center=true);
+     }
+     
+     if(hall_sensor) {
+     translate([0, -reed_offset,  bottom_bearing_start + height/4+.2+1])
+      cylinder(h=height/2, r=1.9, center=true);
+     translate([0, -hall_offset, bottom_bearing_start+.8-2]) 
+       cube([4,4,4], center=true);
+     }
+
+    // screw holes    
+    rotate([90, 0, 0]) {
+       translate([0,  bottom_bearing_start+height/3-17*(1-bottom_ball_bearing), -7]) {
+          translate([support_diameter/2, 0, 0])
+            screw_hole(h=20, r=1.2);
+          translate([-support_diameter/2, 0, 0])
+            screw_hole(h=20, r=1.2);
+        }
+       translate([0,  bottom_bearing_start+height*2/3+15*(1-top_ball_bearing), -7]) {
+          translate([support_diameter/2+1, 0, 0])
+            screw_hole(h=20, r=1.2);
+          translate([-support_diameter/2-1, 0, 0])
+            screw_hole(h=20, r=1.2);
+        }
+    }
+    // screw holes
+   if(0)
+    for(i=[0:2])
+        rotate(i*120, [0, 0, 1]) {
+         translate([0,-radius-1,bottom_bearing_start+bottom_bearing_height])
+    rotate(90, [1, 0, 0])
+    cylinder(h=10, r=1.6, center=true);
+        }
+    
+     // cut away support
+    translate([0, 6, 0])
+    rotate(90, [1, 0, 0])
+    cylinder(h=radius*3 + 6, r=support_diameter/2);
+  }
+}
+
+
+module pegs(r) {
+    for(i=[-1:1]) {
+        translate([radius*.85, 0, height/4*i])
+            sphere(r, $fn=24);
+        translate([-radius*.85, 0, height/4*i])
+            sphere(r, $fn=24);
+    }
+}
+
+if(1) {
+// split in half
+  union() {  
+    intersection() {
+        body();
+        translate([0, -height/2, 0])
+            cube([height, height, height],center=true);
+    }
+    pegs(1.1);
+  }
+    translate([3*radius, 0, 0])
+        intersection() {    
+            rotate(180, [0, 0, 1])
+              difference() {
+                body();
+                pegs(1.2);
+              }
+            translate([0, -height/2, 0])
+                cube([height, height, height],center=true);
+        }
+} else {
+ translate([30, 0, 0])
+  intersection() {
+    body();
+    translate([0, 0, -height/2])
+      cylinder(h=12, r1=12.7, r=7.2);
+  }
+
+  difference() {
+    body();
+    translate([0, 0, -height/2])
+      cylinder(h=13, r1=13, r2=7.5);
+  }
+}