publish-maven.gradle

apply plugin: "propdeps-maven"

install {
	repositories.mavenInstaller {
		customizePom(pom, project)
	}
}

def customizePom(pom, gradleProject) {
	pom.whenConfigured { generatedPom ->
		// eliminate test-scoped dependencies (no need in maven central poms)
		generatedPom.dependencies.removeAll { dep ->
			dep.scope == "test"
		}

		// sort to make pom dependencies order consistent to ease comparison of older poms
		generatedPom.dependencies = generatedPom.dependencies.sort { dep ->
			"$dep.scope:$dep.groupId:$dep.artifactId"
		}

		// add all items necessary for maven central publication
		generatedPom.project {
			name = gradleProject.description
			description = gradleProject.description
			url = "https://github.com/pivotal-cf/cloudfoundry-certificate-truster"
			organization {
				name = "Pivotal Software, Inc"
				url = "http://pivotal.io"
			}
			licenses {
				license {
					name "The Apache Software License, Version 2.0"
					url "http://www.apache.org/licenses/LICENSE-2.0.txt"
					distribution "repo"
				}
			}
			scm {
				url = "https://github.com/pivotal-cf/cloudfoundry-certificate-truster"
				connection = "scm:git:git://github.com/pivotal-cf/cloudfoundry-certificate-truster"
				developerConnection = "scm:git:git://github.com/pivotal-cf/cloudfoundry-certificate-truster"
			}
			developers {
				developer {
					id = "wtran"
					name = "Will Tran"
					email = "wtran@pivotal.io"
				}
				developer {
					id = "royclarkson"
					name = "Roy Clarkson"
					email = "rclarkson@pivotal.io"
				}
			}
		}
	}
}