initial commit

Author: pheobeayo

README.md

@@ -1,2 +1,34 @@
-# StakeHub
-A blockchain app for staking
+# Krypto-staking
+A Defi Staking Application
+
+
+In a typical developing market like Ghana, Nigeria and Kenya, many problems exist, making transactions very difficult. For instance, currency depreciation makes investment unattractive and makes holding foreign currencies impossible. The Prices of goods and services keep doubling and inflation continues to increase. 
+
+A platform which provides a simpler yet rewarding opportunity for many to earn extra income and get good returns on investments. 
+
+Target Audience 
+
+High-income individuals 
+
+Mid-level Career person (middle-income) 
+
+We posited that crypto enthusiasts are the early adopters who will later become brand evangelists. 
+
+
+Features 
+
+1. Users should be able to register and log in on the web and app 
+2. User must be thoroughly verified as a first-timer before accessing the app
+3. Users should be able to load or upload money through Visa and mobile money
+4. Users should be able to see rewards visibly on the platform 
+5. Users should be able to self-educate by having self-help tips and videos on the web and app 
+6. User should be able to see the trade rates and the number of users on each
+7. User should be able to buy and sell cryptocurrency 
+8. User should have access to a community 
+9. Users should be able to see their account balance and transaction history.
+10. Users should be able to enter contracts with experts in staking on the platform.
+11. Users should be able to network with experts to stake on their behalf.
+12. User should be able to see the best crypto-staking coins
+
+
+    

contracts/Erc20.sol

@@ -0,0 +1,66 @@
+// SPDX-License-Identifier: UNLICENSED
+pragma solidity ^0.8.10;
+
+interface IERC20{
+    function totalSupply() external view returns(uint);
+
+    function balanceOf(address account) external view returns(uint);
+
+    function transfer(address recipient, uint amount) external returns(bool);
+
+    function allowance(address owner, address spender) external view returns(uint);
+
+    function approve(address spender, uint amount) external returns(bool);
+
+    function transferFrom(address sender, address recipient, uint amount) external returns (bool);
+
+    event Transfer(address indexed from, address indexed to, uint amount);
+    event Approval(address indexed owner, address indexed spender, uint amount);
+}
+
+contract ERC20 is IERC20 {
+    uint public totalSupply;
+    mapping (address=>uint) public balanceOf;
+    mapping (address => mapping (address => uint)) public allowance;
+    string public name;
+    string public symbol;
+    uint8 public decimals = 18;
+
+    constructor(string memory _tokenName, string memory _tokenSymbol){
+        name = _tokenName;
+        symbol = _tokenSymbol;
+    }
+
+    function transfer(address recipient, uint amount) external returns(bool){
+        balanceOf[msg.sender] -= amount;
+        balanceOf[recipient] += amount;
+        emit Transfer(msg.sender, recipient, amount);
+        return true;
+    }
+
+    function approve(address spender,uint amount) external returns(bool){
+        allowance[msg.sender][spender] = amount;
+        emit Approval(msg.sender, spender, amount);
+        return true;
+    }
+
+    function transferFrom(address sender,address recipient, uint amount) external returns(bool){
+        allowance[sender][msg.sender] -= amount;
+        balanceOf[sender] -= amount;
+        balanceOf[recipient] += amount;
+        emit Transfer(sender, recipient, amount);
+        return true;
+    }
+
+    function mint(uint amount) external{
+        balanceOf[msg.sender] += amount;
+        totalSupply += amount;
+        emit Transfer(address(0), msg.sender, amount);
+    }
+
+    function burn(uint amount) external{
+        balanceOf[msg.sender] -= amount;
+        totalSupply -= amount;
+        emit Transfer( msg.sender,address(0), amount);
+    }
+}

contracts/KryptoStaking.sol

@@ -0,0 +1,153 @@
+// SPDX-License-Identifier: MIT
+pragma solidity ^0.8;
+
+contract StakingRewards {
+    IERC20 public immutable stakingToken;
+    IERC20 public immutable rewardsToken;
+
+    address public owner;
+
+    /*++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
+    staking-contract = 0x81908580A50517432d180e6e5eE3C05B06505314
+    staking-token = 0x06CF90BdcA174e02d960BF59483c7e09b6393d58
+    reward-token = 0xe0558beBC4D9c53333dACFc395e7a2FbfcAEeE32
+    +++++++++++++++++++++++++++++++++++++++++++++++++++++++++*/
+
+    // Duration of rewards to be paid out (in seconds)
+    uint public duration;
+    // Timestamp of when the rewards finish
+    uint public finishAt;
+    // Minimum of last updated time and reward finish time
+    uint public updatedAt;
+    // Reward to be paid out per second
+    
+    uint public rewardRate;
+    // Sum of (reward rate * dt * 1e18 / total supply)
+    uint public rewardPerTokenStored;
+    // User address => rewardPerTokenStored
+    mapping(address => uint) public userRewardPerTokenPaid;
+    // User address => rewards to be claimed
+    mapping(address => uint) public rewards;
+
+    // Total staked
+    uint public totalSupply;
+    // User address => staked amount
+    mapping(address => uint) public balanceOf;
+
+    constructor(address _stakingToken, address _rewardToken) {
+        owner = msg.sender;
+        stakingToken = IERC20(_stakingToken);
+        rewardsToken = IERC20(_rewardToken);
+    }
+
+    modifier onlyOwner() {
+        require(msg.sender == owner, "not authorized");
+        _;
+    }
+
+    modifier updateReward(address _account) {
+        rewardPerTokenStored = rewardPerToken();
+        updatedAt = lastTimeRewardApplicable();
+
+        if (_account != address(0)) {
+            rewards[_account] = earned(_account);
+            userRewardPerTokenPaid[_account] = rewardPerTokenStored;
+        }
+
+        _;
+    }
+
+    function lastTimeRewardApplicable() public view returns (uint) {
+        return _min(finishAt, block.timestamp);
+    }
+
+    function rewardPerToken() public view returns (uint) {
+        if (totalSupply == 0) {
+            return rewardPerTokenStored;
+        }
+
+        return
+            rewardPerTokenStored +
+            (rewardRate * (lastTimeRewardApplicable() - updatedAt) * 1e18) /
+            totalSupply;
+    }
+
+    function stake(uint _amount) external updateReward(msg.sender) {
+        require(_amount > 0, "amount = 0");
+        stakingToken.transferFrom(msg.sender, address(this), _amount);
+        balanceOf[msg.sender] += _amount;
+        totalSupply += _amount;
+    }
+
+    function withdraw(uint _amount) external updateReward(msg.sender) {
+        require(_amount > 0, "amount = 0");
+        balanceOf[msg.sender] -= _amount;
+        totalSupply -= _amount;
+        stakingToken.transfer(msg.sender, _amount);
+    }
+
+    function earned(address _account) public view returns (uint) {
+        return
+            ((balanceOf[_account] *
+                (rewardPerToken() - userRewardPerTokenPaid[_account])) / 1e18) +
+            rewards[_account];
+    }
+
+    function getReward() external updateReward(msg.sender) {
+        uint reward = rewards[msg.sender];
+        if (reward > 0) {
+            rewards[msg.sender] = 0;
+            rewardsToken.transfer(msg.sender, reward);
+        }
+    }
+
+    function setRewardsDuration(uint _duration) external onlyOwner {
+        require(finishAt < block.timestamp, "reward duration not finished");
+        duration = _duration;
+    }
+
+    function notifyRewardAmount(
+        uint _amount
+    ) external onlyOwner updateReward(address(0)) {
+        if (block.timestamp >= finishAt) {
+            rewardRate = _amount / duration;
+        } else {
+            uint remainingRewards = (finishAt - block.timestamp) * rewardRate;
+            rewardRate = (_amount + remainingRewards) / duration;
+        }
+
+        require(rewardRate > 0, "reward rate = 0");
+        require(
+            rewardRate * duration <= rewardsToken.balanceOf(address(this)),
+            "reward amount > balance"
+        );
+
+        finishAt = block.timestamp + duration;
+        updatedAt = block.timestamp;
+    }
+
+    function _min(uint x, uint y) private pure returns (uint) {
+        return x <= y ? x : y;
+    }
+}
+
+interface IERC20 {
+    function totalSupply() external view returns (uint);
+
+    function balanceOf(address account) external view returns (uint);
+
+    function transfer(address recipient, uint amount) external returns (bool);
+
+    function allowance(address owner, address spender) external view returns (uint);
+
+    function approve(address spender, uint amount) external returns (bool);
+
+    function transferFrom(
+        address sender,
+        address recipient,
+        uint amount
+    ) external returns (bool);
+
+    event Transfer(address indexed from, address indexed to, uint value);
+    event Approval(address indexed owner, address indexed spender, uint value);
+}