build.gradle

import org.gradle.plugins.ide.idea.model.IdeaModel

buildscript {
    repositories {
        mavenCentral() { metadataSources { mavenPom(); ignoreGradleMetadataRedirection() } }
        gradlePluginPortal() { metadataSources { mavenPom(); ignoreGradleMetadataRedirection() } }
    }

    dependencies {
        classpath 'com.palantir.jakartapackagealignment:jakarta-package-alignment:0.6.0'
        classpath 'com.netflix.nebula:gradle-info-plugin:13.3.0'
        classpath 'com.netflix.nebula:nebula-publishing-plugin:21.1.0'
        classpath 'com.palantir.baseline:gradle-baseline-java:6.1.0'
        classpath 'com.palantir.gradle.conjure:gradle-conjure:5.51.0'
        classpath 'com.palantir.gradle.consistentversions:gradle-consistent-versions:2.29.0'
        classpath 'com.palantir.gradle.docker:gradle-docker:0.35.0'
        classpath 'com.palantir.gradle.externalpublish:gradle-external-publish-plugin:1.19.0'
        classpath 'com.palantir.gradle.failure-reports:gradle-failure-reports:1.13.0'
        classpath 'com.palantir.gradle.gitversion:gradle-git-version:3.1.0'
        classpath 'com.palantir.gradle.jdks:gradle-jdks:0.56.0'
        classpath 'com.palantir.gradle.jdkslatest:gradle-jdks-latest:0.16.0'
        classpath 'com.palantir.javaformat:gradle-palantir-java-format:2.50.0'
        classpath 'com.palantir.metricschema:gradle-metric-schema:0.32.0'
        classpath 'com.palantir.sls-packaging:gradle-sls-packaging:7.13.0'
        classpath 'com.google.protobuf:protobuf-gradle-plugin:0.9.4'
        classpath 'gradle.plugin.com.github.johnrengelman:shadow:7.1.2'
        classpath 'gradle.plugin.com.hierynomus.gradle.plugins:license-gradle-plugin:0.16.1'
        classpath 'gradle.plugin.org.inferred:gradle-processors:3.7.0'
        classpath 'org.unbroken-dome.gradle-plugins:gradle-testsets-plugin:4.1.0'
        classpath 'com.palantir.gradle.revapi:gradle-revapi:1.8.0'
    }
}

apply plugin: 'java'
apply plugin: 'com.palantir.baseline'
apply plugin: 'com.palantir.baseline-java-versions'
apply plugin: 'com.palantir.consistent-versions'
apply plugin: 'com.palantir.external-publish'
apply plugin: 'com.palantir.failure-reports'
apply plugin: 'com.palantir.git-version'
apply plugin: 'com.palantir.jdks'
apply plugin: 'com.palantir.jdks.latest'

javaVersions {
    libraryTarget = 17
}

group = 'com.palantir.atlasdb'
version = sanitizeVersion()
description = 'Transactional distributed database layer'

def sanitizeVersion() {
    def isClean = "git status --porcelain".execute().text.isEmpty()
    def pluginReportedVersion = gitVersion()
    def dirtySuffix = ".dirty"

    if (isClean && pluginReportedVersion.endsWith(dirtySuffix)) {
        return pluginReportedVersion.substring(0, pluginReportedVersion.length() - dirtySuffix.length())
    }
    return pluginReportedVersion
}

task printLastVersion {
    doLast {
        def details = versionDetails()
        println details.lastTag
    }
}

allprojects {
    repositories {
        mavenCentral() { metadataSources { mavenPom(); ignoreGradleMetadataRedirection() } }
    }

    apply plugin: 'java-library'
    apply plugin: 'org.inferred.processors'  // installs the "processor" configuration needed for baseline-error-prone
    apply plugin: 'com.palantir.java-format'
    apply plugin: 'com.palantir.jakarta-package-alignment'

    // temporary until this is merged/fixed inside gradle-processors
    configurations.allProcessors {
        canBeConsumed = false
        attributes {
            attribute Usage.USAGE_ATTRIBUTE, objects.named(Usage, Usage.JAVA_API)
        }
    }

    configurations.all {
        resolutionStrategy.dependencySubstitution {
            it.substitute it.module('org.glassfish.hk2.external:javax.inject') using it.module('javax.inject:javax.inject:1')
            it.substitute it.module('org.glassfish.hk2.external:jakarta.inject') using it.module('javax.inject:javax.inject:1')

            // See internal migration plugin PR 26: this direction is intentional.
            it.substitute it.module('javax.el:javax.el-api') using it.module('org.glassfish:jakarta.el:3.0.4')
            it.substitute it.module('jakarta.el:jakarta.el-api') using it.module('org.glassfish:jakarta.el:3.0.4')
        }
    }

    tasks.withType(JavaCompile) {
        options.compilerArgs += ['-Werror']
        // temporarily relax constraints until we can fix all violations
        options.errorprone.disable 'CloseableProvides',
                'DangerousCompletableFutureUsage',
                'EqualsGetClass',
                'FutureReturnValueIgnored',
                'NarrowingCompoundAssignment',
                'Slf4jLogsafeArgs',
                'StaticAssignmentInConstructor',
                'StrictUnusedVariable'
        options.errorprone.error 'SafeLoggingPropagation'
    }

    tasks.check.dependsOn checkImplicitDependenciesMain, checkUnusedDependenciesMain
}

subprojects {
    task allDeps(type: DependencyReportTask) {}
}

afterEvaluate {
    configure(subprojects.findAll {!it.getPath().startsWith(":examples")}) {
        if (!project.plugins.hasPlugin('com.palantir.external-publish-dist')) {
            apply from: "$rootDir/gradle/publish-jars.gradle"
        }
    }
}


// Setup copyright notice as a block comment, and no newline after it
project.afterEvaluate {
    def ideaRootModel = project.rootProject.extensions.findByType(IdeaModel)
    if (ideaRootModel) {
        ideaRootModel.project.ipr.withXml { provider ->
            def node = provider.asNode()
            def copyrightManager = node.component.find { it.'@name' == 'CopyrightManager' }
            copyrightManager.append(new XmlParser().parseText("""
                <LanguageOptions name="__TEMPLATE__">
                    <option name="addBlankAfter" value="false" />
                    <option name="separateBefore" value="true" />
                    <option name="lenBefore" value="2" />
                </LanguageOptions>
                """.stripIndent()))
            copyrightManager.append(new XmlParser().parseText("""
                <LanguageOptions name="JAVA">
                    <option name="fileTypeOverride" value="3" />
                </LanguageOptions>
                """.stripIndent()))
        }
    }
}

allprojects {
    // This allows tests that require an artefact to exist to
    // decide whether to call gradle themselves or not
    tasks.withType(Test) {
        systemProperty 'RUNNING_IN_GRADLE', 'true'
    }
}