Add magit to project-switch-commands before magit is loaded

[Andre0991]

Hi. The binding m is added to project.el switch command when magit is started.
However, it is not usual for me to open Emacs and try to consult the git status of some project right away, before calling magit for the first time. So I'd like m to be available in the project switch commands before loading magit.

Is there any alternative besides simply using (require 'magit)?

This is the relevant code in magit extras:

;;;###autoload
(defun magit-project-status ()
  "Run `magit-status' in the current project's root."
  (interactive)
  (magit-status-setup-buffer (project-root (project-current t))))

(defvar magit-bind-magit-project-status t
  "Whether to bind \"m\" to `magit-project-status' in `project-prefix-map'.
If so, then an entry is added to `project-switch-commands' as
well.  If you want to use another key, then you must set this
to nil before loading Magit to prevent \"m\" from being bound.")

(with-eval-after-load 'project
  ;; Only more recent versions of project.el have `project-prefix-map' and
  ;; `project-switch-commands', though project.el is available in Emacs 25.
  (when (and magit-bind-magit-project-status
             (boundp 'project-prefix-map)
             ;; Only modify if it hasn't already been modified.
             (equal project-switch-commands
                    (eval (car (get 'project-switch-commands 'standard-value))
                          t)))
    (define-key project-prefix-map "m" #'magit-project-status)
    (add-to-list 'project-switch-commands '(magit-project-status "Magit") t)))

[tarsius]

Since the command is autoloaded you can just add (define-key project-prefix-map "m" #'magit-project-status) to your init file.

[Andre0991]

I was not able to get m to be displayed using only the snippet you posted. However, it seems that this works:

(with-eval-after-load 'project
  (define-key project-prefix-map "m" #'magit-project-status)
  (add-to-list 'project-switch-commands '(magit-project-status "Magit") t))

[ragnese]

This is only tangentially related to this issue, but I have a question here.

Would it make sense to wrap the (with-eval-after-load 'project [...]) with (when magit-bind-magit-project-status [...]), rather than have the check inside the after-load? It's entirely possible that I'm missing something about how autoloads work, but it seems like it would be "cleaner" to not hook into the project.el package loading at all, rather than to add a callback that won't do anything.

Technically, such a change would be a change in behavior, because changing the magit-bind-magit-project-status variable will only have an effect if done before loading magit. Today, you could still change the variable after loading magit, but before loading project.el (If I understand correctly, which is NOT a given...).

[tarsius]

This is only tangentially related to this issue, but I have a question here.

Would it make sense to wrap the (with-eval-after-load 'project [...]) with (when magit-bind-magit-project-status [...]), rather than have the check inside the after-load? It's entirely possible that I'm missing something about how autoloads work, but it seems like it would be "cleaner" to not hook into the project.el package loading at all, rather than to add a callback that won't do anything.

Cleaner maybe, but it needs more documentation, imposes unnecessary restrictions, and wastes the time of users who overlooked that and possibly the time of the maintainer who has to point them in the right direction.

And what for? Just to avoid installing some code, which under some but not all circumstances, ends up doing nothing.

Technically, such a change would be a change in behavior, because changing the magit-bind-magit-project-status variable will only have an effect if done before loading magit. Today, you could still change the variable after loading magit, but before loading project.el (If I understand correctly, which is NOT a given...).

Reason enough to keep things as is.