Convert string keys to keyword?

[nkabir]

Is there a function available to perform this operation?

{"color" "red"} --> {:color "red"}

https://github.com/borkdude/jet

[allison-casey]

The constructor for hy.models.Keyword will do this for you

=> (hy.models.Keyword "hello")
:hello

[nkabir]

Thank you! I extended it to take a nested dictionary. Is there something like this already?

(defn keywordize [ multi-level-dict ]
  (let [kwdict {}]
    (for [(, k v) (.items multi-level-dict)]
      (if (isinstance v dict)
          (setv v (keywordize v)))
      (if (not (isinstance k Keyword))
          (setv k (Keyword k)))
      (assoc kwdict k v))
    kwdict))

[allison-casey]

no there's not. It's generally discouraged in Hy to use keywords as dict keys. Hy is much much closer to Python than clojure is to java and Python generally expects strings as keys. In addition we use keywords for keyword args and the dict constructor produces string keys (dict :a 1 :b 2) => {"a" 1 "b" 2}. It's why keyword look ups query by string such that the following is true

=> (:hello {"hello" 1})
1
=> (:hello (dict :hello 1))
1

You should generally think of Hy as lispy Python and not a completely separate language. i.e. your solution could also be solved
using dfor the Hy analog of Python's dictionary comprehension.

(defn keywordize [coll]
  (dfor [k v] (.items coll)
    :setv value (if (isinstance v dict) (keywordize v) v)
    :setv key (if (isinstance k Keyword) k (Keyword k))
    [key value]))

[nkabir]

I see. I think I recall reading something that indicated HyLang was following Clojure aesthetics ;-) Thank you for the clarification.

[allison-casey]

we take a lot of inspiration for sure, but at it's core Hy is Python and trying to force Clojure-esque semantics on Hy ended up making interop and maintenance of the language difficult given how important interopping with python libs is. I hope you're having fun with Hy!

[nkabir]

A follow-up question about keywords. I am using hylang to generate edn files to import into Clojure. I have a structure in Hylang that renders as expected in the repl:

=> x
{:author {:name "John Smith"}  :color "red"  :size [1 2 3]}

I'd like to write this out to a file. However, any conversion produces this:

=> (str x)
(+ "{hy.models.Keyword('color'): 'red', hy.models.Keyword('size'): [1, 2, 3], "
   "hy.models.Keyword('author'): {hy.models.Keyword('name'): 'John Smith'}}")
=> (repr x)
(+ "{hy.models.Keyword('color'): 'red', hy.models.Keyword('size'): [1, 2, 3], "
   "hy.models.Keyword('author'): {hy.models.Keyword('name'): 'John Smith'}}")

How is the repl rendering x with colon keywords?

[allison-casey]

use hy.repr to get the hy representation of data structures

[nkabir]

That works. Thank you!

[allison-casey]

hyrule.hypprint.PrettyPrinter can give you nicer output, but it does not give you edn and you'd have to overwrite the dispatch method for str to not break them up via (+ ...)