lsp-mode keeps prompting "File to save in" in minibuffer when the buffer content is changed #4418

IceAsteroid · 2024-04-07T13:52:22Z

IceAsteroid
Apr 7, 2024

IDEInEmacsIssue.mp4

It didn't happen before I updated emacs to 29.3, or maybe by other factors

I've also tried to disable "auto-save-mode" and "auto-save-visited-mode", but still no help.

Buffer is able to be saved to file by "(save-buffer)/C-x C-s".

This also happens when using Eglot instead. See the issue page I posted on Eglot repo: Link

lsp-mode version is LSP :: lsp-mode 20240328.605, Emacs 29.3, gnu/linux

Using pyright 1.1.357, on VoidLinux, kernel 6.6.22_1

Also I tried with haskell-mode and haskell-language-server, but resulted the same.

Edit: It seems to be a configuration problem, when I tried emacs -q, both eglot & lsp-moe were working fine. Now I'm investigating it first

*Message* buffer

Error loading autoloads: (file-missing Cannot open load file No such file or directory /home/apple/.emacs.d/elpa/lsp-mode-20240328.605/lsp-mode-autoloads)
Error loading autoloads: (file-missing Cannot open load file No such file or directory /home/apple/.emacs.d/elpa/embark-20240327.1408/embark-autoloads)
Loading /home/apple/.emacs.d/recentf...done
Cleaning up the recentf list...done (0 removed)
Repeat mode is enabled for 36 commands and 11 keymaps; see ‘describe-repeat-maps’
Loading /home/apple/.emacs.d/custom.el (source)...done
For information about GNU Emacs and the GNU system, type C-h C-a.
Quit
LSP :: Yasnippet is not installed, but `lsp-enable-snippet' is set to `t'. You must either install yasnippet, or disable snippet support.
LSP :: Connected to [pyright:23322/starting /home/apple/TestArea/Python].
Error processing message (void-function lsp-lens--enable). [3 times]
funcall-interactively: End of buffer
error in process filter: Quit [2 times]
Quit [2 times]
Auto-saving...done

*lsp-log* buffer

Error loading autoloads: (file-missing Cannot open load file No such file or directory /home/apple/.emacs.d/elpa/lsp-mode-20240328.605/lsp-mode-autoloads)
Error loading autoloads: (file-missing Cannot open load file No such file or directory /home/apple/.emacs.d/elpa/embark-20240327.1408/embark-autoloads)
Loading /home/apple/.emacs.d/recentf...done
Cleaning up the recentf list...done (0 removed)
Repeat mode is enabled for 36 commands and 11 keymaps; see ‘describe-repeat-maps’
Loading /home/apple/.emacs.d/custom.el (source)...done
For information about GNU Emacs and the GNU system, type C-h C-a.
Quit
LSP :: Yasnippet is not installed, but `lsp-enable-snippet' is set to `t'. You must either install yasnippet, or disable snippet support.
LSP :: Connected to [pyright:23322/starting /home/apple/TestArea/Python].
Error processing message (void-function lsp-lens--enable). [3 times]
funcall-interactively: End of buffer
error in process filter: Quit [2 times]
Quit [2 times]
Auto-saving...done

emacs init.el

;;;; Emacs configuration file
;;; Network connection
(setq url-proxy-services '(("no_proxy" . "127.0.0.1")    
                           ("http" . "127.0.0.1:8118")   
                           ("https" . "127.0.0.1:8118")))

;;; Package & Source management
;; https://stackoverflow.com/questions/10092322/how-to-automatically-install-emacs-packages-by-specifying-a-list-of-package-name
;; https://emacs.stackexchange.com/questions/28932/how-to-automate-installation-of-packages-with-emacs-file
(progn
  (require 'package)
  (add-to-list 'package-archives
	       '("melpa" . "https://melpa.org/packages/"))
  (package-initialize)
  (defvar my/package-list '(vertico
			    marginalia
			    orderless
			    consult
			    embark
			    doom-themes
			    doom-modeline
			    centered-cursor-mode
			    all-the-icons
			    treemacs-all-the-icons
			    treemacs
			    treesit-auto
			    company
			    lsp-mode
			    lsp-pyright
			    ace-window
			    popper)
    "List of packages to be installed & ensure installed")
  (dolist (pkg my/package-list)
    (unless (package-installed-p pkg)
      (package-install pkg)))
  )

;; Manually source packages when not loaded
;; https://www.emacswiki.org/emacs/LoadPath
;;(let ((default-directory  "~/.emacs.d/elpa/"))
;;  (normal-top-level-add-to-load-path '("."))
;;  (normal-top-level-add-subdirs-to-load-path))

;;; Theming
(defun my/theming-setup ()
  (load-theme 'doom-oksolar-dark t)
  (defun my/disable-all-themes (&rest _)
    (mapcar 'disable-theme custom-enabled-themes))
  (advice-add 'load-theme :before 'my/disable-all-themes)
  (with-eval-after-load 'consult
    (defalias 'load-theme-consult 'consult-theme))
  )
(my/theming-setup)

;;; Modeline configuration
(with-eval-after-load 'doom-themes (doom-modeline-mode t))

;;; Mini-buffer Completion
(defun my/completion-setup ()
  (setq read-file-name-completion-ignore-case t
	read-buffer-completion-ignore-case t
	completion-ignore-case t)
  (setq completion-styles '(orderless basic)
	completion-category-defaults nil
	completion-category-overrides '((file (styles partial-completion))))
  (marginalia-mode 1)
  (with-eval-after-load 'vertico
    (setq vertico-count 20)
    (setq vertico-scroll-margin (/ vertico-count 2))
    (require 'consult) ;consult has no mode
    (global-set-key (kbd "C-x b") 'consult-buffer))
  (vertico-mode t)
  (require 'embark) ;embark has no mode & autoload
  (with-eval-after-load 'embark
    (setq embark-indicators '(embark-minimal-indicator embark-highlight-indicator embark-isearch-highlight-indicator))
    (setq prefix-help-command #'embark-prefix-help-command)
    (keymap-global-set "C-." 'embark-act)
    (keymap-global-set "C-;" 'embark-dwim)
    (keymap-global-set "C-h b" ;replace (describe-bingings)
		       (lambda () (interactive) (embark-bindings 1))))
  )
(my/completion-setup)

;;; Buffer configuration
(defun my/buffer-setup ()
  (global-centered-cursor-mode 1)
  (defun my/outline-minor-mode-setup ()
    ;; https://old.reddit.com/r/emacs/comments/1axkgx4/folding_everywhere_literate_programming_almost/
    (with-eval-after-load 'outline
      (setq outline-minor-mode-highlight t)
      (keymap-set outline-minor-mode-map "C-c"
		  (keymap-lookup outline-minor-mode-map "C-c @"))
      (keymap-set outline-minor-mode-map "C-c C-<tab>" 'outline-cycle)
      (keymap-unset outline-minor-mode-map "C-c TAB" 'outline-show-children)
      (keymap-set outline-minor-mode-map "C-c <tab>" 'outline-cycle-buffer)
      )
    (add-hook 'emacs-lisp-mode-hook 'outline-minor-mode)
    (add-hook 'outline-minor-mode-hook
	      (lambda () (keymap-local-set "C-c C-g" 'consult-outline))))
  (my/outline-minor-mode-setup)
  )
(my/buffer-setup)

;;; Window configuration
(defun my/window-management-setup ()
  (keymap-global-set "M-o" 'other-window)
  (when (fboundp 'ace-window)
    (setq aw-dispatch-when-more-than 1)
    (setq aw-minibuffer-flag t)
    (setq aw-keys '(?q ?w ?e ?r ?t ?y ?u ?i ?o ?p))
    (defvar aw-dispatch-alist
      '((?d aw-delete-window "Delete Window")
	(?s aw-swap-window "Swap Widnows")
	(?m aw-move-window "Move Window")
	(?c aw-copy-window "Copy Window")
	(?f aw-flip-window "Flip Widnows")
	(?h aw-show-dispatch-help))
      "List of actions for `aw-dispatch-default'.")
    (keymap-global-set "C-x o" 'ace-window))
  (ace-window-display-mode 1)
  ;;(ace-window-mode 1) ; ace-window has no mode
  (with-eval-after-load 'popper
    (setq popper-reference-buffers
	  '("\\*Messages\\*"
	    "Output\\*$"
	    "\\*Async Shell Command\\*"
	    help-mode
	    compilation-mode))
    (global-unset-key (kbd "C-z"))
    (defvar ctl-z-map (make-sparse-keymap))
    (keymap-global-set "C-z" ctl-z-map)
    (keymap-global-set "C-z C-z" 'popper-toggle)
    (keymap-global-set "C-z C-<tab>" 'popper-cycle)
    (keymap-global-set "C-z <tab>" 'popper-toggle-type)
    )
  (popper-mode +1)
  (popper-echo-mode +1)
  (setq help-window-select t)
  (advice-add 'split-window-below :after (lambda (&rest _) (other-window 1)))
  (advice-add 'split-window-right :after (lambda (&rest _) (other-window 1)))
  (winner-mode 1)
  ;; my/window-switching
  (defun my/window-switching-setup ()
    (with-eval-after-load 'windmove
      (windmove-default-keybindings 'meta)
      (keymap-global-set "M-S-<left>" 'windmove-swap-states-left)
      (keymap-global-set "M-S-<right>" 'windmove-swap-states-right)
      (keymap-global-set "M-S-<up>" 'windmove-swap-states-up)
      (keymap-global-set "M-S-<down>" 'windmove-swap-states-down))
    (windmove-mode 1))
  (my/window-switching-setup)
  )
(my/window-management-setup)

;;; Programming IDE
(defun my/programming-setup ()
  (add-hook 'prog-mode-hook 'rainbow-delimiters-mode)
  (with-eval-after-load 'treemacs (treemacs-load-all-the-icons-with-workaround-font "Hermit"))
  (add-hook 'prog-mode-hook 'company-mode)
  ;;(add-hook 'haskell-mode-hook 'eglot-ensure)
  ;;(add-hook 'python-mode-hook 'eglot-ensure)
  (require 'lsp-mode) ;has no autoload
  (require 'lsp-pyright)
  (require 'treesit-auto)
  (with-eval-after-load 'treesit-auto
    (setq treesit-auto-install 'prompt)
    (treesit-auto-add-to-auto-mode-alist 'all))
  (global-treesit-auto-mode t)
  )
(my/programming-setup)

;;; Org-mode configuration
;; Implement subentry count in title for each heading
;;-This implementation was created as barely a scratch by me
;;-, but was improved to perfection by @dalanicolai on StackExchange.
;;- https://emacs.stackexchange.com/questions/79785/how-to-display-sub-heading-count-somewhere-in-a-heading-in-org-mode/79829?noredirect=1#comment133905_79829
(defun my/org-subentry-count ()
  (defcustom org-subentry-count-at-start nil
    "Show the subentry count before the title, not after."
    :group 'org-subenty-count
    :type 'boolean)
  (defvar org-subentry-count-in-headings-p nil
    "t to enable org-subentry-count-in-headings
       nil to disable org-subentry-count-in-headings")
  (defun org-subentry-count-in-headings ()
    (org-map-entries
     (lambda ()
       (when (looking-at org-complex-heading-regexp)
	 (let* ((group (if org-subentry-count-at-start 1 0))
		(beg (match-beginning group))
		(end (match-end group))
		(level (length (match-string 1))) ; stars in headline
		(subheading-count (format "%s" (1- (length (org-map-entries nil nil 'tree)))))
		(ov (car (seq-filter
			  ;; search for subentry-count overlay
			  (lambda (o)
			    (eq (overlay-get o 'type) 'subentry-count)) 
			  (overlays-in (line-beginning-position)
				       (line-end-position))))))
	   (if ov ; only create overlay if not exists yet
	       (move-overlay ov beg end)
	     (setq ov (make-overlay beg end))
	     (overlay-put ov 'type 'subentry-count) ; add a type, for easy filtering
	     (overlay-put ov 'evaporate t))
	   ;; only add/remove 'after-string' prop in toggle
	   (if org-subentry-count-in-headings-p
	       (overlay-put ov 'after-string (propertize (format " %s" subheading-count)
							 'face (intern-soft (format "org-level-%d" level))))
	     (overlay-put ov 'after-string nil)))))))
  (defun toggle-org-subentry-count-in-headings ()
    (interactive)
    (if org-subentry-count-in-headings-p
	(setq org-subentry-count-in-headings-p nil)
      (setq org-subentry-count-in-headings-p t))
    (org-subentry-count-in-headings))
  (defun toggle-org-subentry-position ()
    (interactive)
    (setq org-subentry-count-at-start (not org-subentry-count-at-start))
    (setq org-subentry-count-in-headings-p t)
    (org-subentry-count-in-headings))
  (add-hook 'org-mode-hook (lambda ()
			     (setq org-subentry-count-in-headings-p t)
			     (setq org-subentry-count-at-start t)
			     (org-subentry-count-in-headings)
			     (add-hook 'after-save-hook 'org-subentry-count-in-headings)))
  )
(my/org-subentry-count)

;;; Emacs configuration
(progn
  (blink-cursor-mode 0)
  (tool-bar-mode -1)
  (setq inhibit-splash-screen t)
  (setq use-file-dialog nil)
  (defalias 'yes-or-no-p 'y-or-n-p)
  (setq display-line-numbers-type 'relative)
  (add-hook 'text-mode-hook 'display-line-numbers-mode)
  (add-hook 'prog-mode-hook 'display-line-numbers-mode)
  (setq mouse-wheel-progressive-speed nil)
  (add-to-list 'default-frame-alist '(font . "JetBrainsMono Nerd Font-13"))
  (save-place-mode 1)
  (recentf-mode 1)
  (global-auto-revert-mode 1)
  (setq eshell-glob-case-insensitive t)
  (setq eshell-cmpl-ignore-case t)
  (defun my/repeat-mode-setup ()
    (setq repeat-on-final-keystroke t)
    (setq set-mark-command-repeat-pop t)
    (with-eval-after-load 'repeat
      (with-eval-after-load 'outline
    	(keymap-set outline-navigation-repeat-map "<tab>" 'outline-cycle-buffer)
        (keymap-set outline-navigation-repeat-map "C-<tab>" 'outline-cycle)
	(put 'outline-cycle 'repeat-map 'outline-navigation-repeat-map)
	(put 'outline-cycle-buffer 'repeat-map 'outline-navigation-repeat-map)
	;; Keys are to exit repeat-mode if not :repeat-map property
	(keymap-set outline-navigation-repeat-map "C-p" 'previous-line)
	(keymap-set outline-navigation-repeat-map "C-n" 'next-line))
      (with-eval-after-load 'window
	(defvar-keymap my/window-repeat-map
	  :repeat (:exit (delete-other-windows))
	  :doc "Keymap for window managements in repeat-mode"
	  "o" #'other-window
	  "0" #'delete-window
	  "1" #'delete-other-windows
	  "2" #'split-window-below
	  "3" #'split-window-right
	  "+" #'balance-windows
	  "%" #'shrink-window
	  "^" #'enlarge-window
	  "{" #'shrink-window-horizontally
	  "}" #'enlarge-window-horizontally
	  "-" #'shrink-window-if-larger-than-buffer
	  )))
    (repeat-mode 1))
  (my/repeat-mode-setup)
  (defun my/custom-file-location-setup ()
    (setq custom-file "~/.emacs.d/custom.el")
    (unless (file-exists-p custom-file)
      (make-empty-file custom-file))
    (load custom-file))
  (my/custom-file-location-setup)
  ;; Backup management
  ;; https://old.reddit.com/r/emacs/comments/15wr8xu/emacs_291_as_ide_for_python/
  (defun my/backup-file-setup ()
    (setq backup-directory-alist '(("." . "~/.emacsVisitedFileBckps"))
	  backup-by-copying t
	  version-control t
	  delete-old-versions t
	  kept-new-versions 10
	  kept-old-versions 2 ;keep N versions of original file undeleted	  
	  ))
  (my/backup-file-setup)
  )

;;; My self-defined functions
;; my/toggle-edition
(defun my/toggle-edition-setup ()
  ;;(add-hook 'find-file-hook 'read-only-mode)
  (add-hook 'read-only-mode-hook
	    (lambda ()
	      (unless (buffer-match-p ".*\\*scratch\\*.*" (current-buffer))
		(save-buffer))))
  (with-eval-after-load 'corfu (add-hook 'read-only-mode-hook 'corfu-quit))
  (with-eval-after-load 'company (add-hook 'read-only-mode-hook 'company-abort))
  (defun my/toggle-edition-command ()
    (interactive)
    (read-only-mode 'toggle))
  (global-set-key (kbd "C-`") 'my/toggle-edition-command)
  )
(my/toggle-edition-setup)

Answered by IceAsteroid

Apr 7, 2024

It turns out that the culprit was a command that I defined. :(

;;; My self-defined functions
;; my/toggle-edition
(defun my/toggle-edition-setup ()
  ;;(add-hook 'find-file-hook 'read-only-mode)
  ;;(add-hook 'read-only-mode-hook
  ;;	    (lambda ()
  ;;	      (unless (buffer-match-p ".*\\*scratch\\*.*" (current-buffer))
  ;;		(save-buffer))))
  (with-eval-after-load 'corfu (add-hook 'read-only-mode-hook 'corfu-quit))
  (with-eval-after-load 'company (add-hook 'read-only-mode-hook 'company-abort))
  (defun my/toggle-edition-command ()
    (interactive)
    (read-only-mode 'toggle))
  (global-set-key (kbd "C-`") 'my/toggle-edition-command)
  )
(my/toggle-edition-setup)

The part which is t…

View full answer

IceAsteroid · 2024-04-07T14:44:31Z

IceAsteroid
Apr 7, 2024
Author

It turns out that the culprit was a command that I defined. :(

;;; My self-defined functions
;; my/toggle-edition
(defun my/toggle-edition-setup ()
  ;;(add-hook 'find-file-hook 'read-only-mode)
  ;;(add-hook 'read-only-mode-hook
  ;;	    (lambda ()
  ;;	      (unless (buffer-match-p ".*\\*scratch\\*.*" (current-buffer))
  ;;		(save-buffer))))
  (with-eval-after-load 'corfu (add-hook 'read-only-mode-hook 'corfu-quit))
  (with-eval-after-load 'company (add-hook 'read-only-mode-hook 'company-abort))
  (defun my/toggle-edition-command ()
    (interactive)
    (read-only-mode 'toggle))
  (global-set-key (kbd "C-`") 'my/toggle-edition-command)
  )
(my/toggle-edition-setup)

The part which is the following caused the problem.

  ;;(add-hook 'read-only-mode-hook
  ;;	    (lambda ()
  ;;	      (unless (buffer-match-p ".*\\*scratch\\*.*" (current-buffer))
  ;;		(save-buffer))))

0 replies

Provide feedback

Saved searches

Use saved searches to filter your results more quickly

lsp-mode keeps prompting "File to save in" in minibuffer when the buffer content is changed #4418

{{title}}

{{editor}}'s edit

{{editor}}'s edit

Replies: 1 comment

{{title}}

Select a reply

lsp-mode keeps prompting "File to save in" in minibuffer when the buffer content is changed #4418

IceAsteroid Apr 7, 2024

Replies: 1 comment

IceAsteroid Apr 7, 2024 Author

IceAsteroid
Apr 7, 2024

IceAsteroid
Apr 7, 2024
Author