-
Notifications
You must be signed in to change notification settings - Fork 265
/
evil-collection.el
1032 lines (935 loc) · 37.6 KB
/
evil-collection.el
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
;;; evil-collection.el --- A set of keybindings for Evil mode -*- lexical-binding: t -*-
;; Copyright (C) 2017, 2023 James Nguyen
;; Author: James Nguyen <[email protected]>
;; Pierre Neidhardt <[email protected]>
;; Maintainer: James Nguyen <[email protected]>
;; Pierre Neidhardt <[email protected]>
;; URL: https://github.com/emacs-evil/evil-collection
;; Version: 0.0.2
;; Package-Requires: ((emacs "26.3") (evil "1.2.13") (annalist "1.0"))
;; Keywords: evil, tools
;; This program is free software; you can redistribute it and/or modify
;; it under the terms of the GNU General Public License as published by
;; the Free Software Foundation, either version 3 of the License, or
;; (at your option) any later version.
;; This program is distributed in the hope that it will be useful,
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
;; GNU General Public License for more details.
;; You should have received a copy of the GNU General Public License
;; along with this program. If not, see <http://www.gnu.org/licenses/>.
;;; Commentary:
;; A set of keybindings for Evil mode.
;;
;; If you want to use Evil in the minibuffer, you'll have to enable it by
;; setting `evil-collection-setup-minibuffer' to t before loading this package.
;; This is so because many users find it confusing.
;; Some minibuffer-related packages such as Helm rely on this option.
;;; Code:
;; `evil' requires `seq-into'?
;; This require on `seq' before loading `evil 'prevents `evil' from erroring
;; out with the below message on Emacs 29.
;; Symbol's function definition is void: seq-into
;; Looks like this error can be traced through evil ->
;; Look at the commit that moved this line above `evil' to see the error message.
;; evil -> evil-vars -> read-kbd-macro -> seq-into -> error.
;; https://github.com/emacs-evil/evil/issues/1627
(require 'seq)
(require 'cl-lib)
(require 'evil)
(require 'annalist)
(defvar evil-collection-base-dir (file-name-directory load-file-name)
"Store the directory evil-collection.el was loaded from.")
(defvar evil-want-integration)
(defvar evil-want-keybinding)
(if (featurep 'evil-keybindings)
(if evil-want-keybinding
(display-warning
'(evil-collection)
"Make sure to set `evil-want-keybinding' to nil before loading evil \
or evil-collection.\
\n
See https://github.com/emacs-evil/evil-collection/issues/60 for more details.")
(display-warning
'(evil-collection)
"`evil-want-keybinding' was set to nil but not before loading evil.\
\n
Make sure to set `evil-want-keybinding' to nil before loading evil \
or evil-collection.\
\n
See https://github.com/emacs-evil/evil-collection/issues/60 for more details.")))
(unless (featurep 'evil-integration)
(message "Requiring evil-integration. Set evil-want-integration to t to\
remove this message.\
\n
See https://github.com/emacs-evil/evil-collection/issues/60 for more details.")
(require 'evil-integration))
(defgroup evil-collection nil
"A set of keybindings for Evil mode."
:group 'evil)
(defcustom evil-collection-setup-minibuffer nil
"Whether to setup Evil bindings in the minibuffer."
:type 'boolean
:group 'evil-collection)
(defcustom evil-collection-calendar-want-org-bindings nil
"Whether to bind Org functions in calendar keymap."
:type 'boolean
:group 'evil-collection)
(defcustom evil-collection-setup-debugger-keys t
"Whether to bind debugger keys when debugger is active.
Debugger in this case is dependent on mode.
This is only relevant for debug modes that are part of another mode,
e.g. `indium'. Modes like `edebug' or `realgud' needs to be explicitly disabled
through removing their entry from `evil-collection-mode-list'."
:type 'boolean
:group 'evil-collection)
(defcustom evil-collection-want-unimpaired-p t
"Whether to enable unimpaired style bindings globally."
:type 'boolean
:group 'evil-collection)
(defcustom evil-collection-want-find-usages-bindings t
"Whether to bind `xref-find-references'-like bindings.
This will bind additional find-* type commands, e.g. usages, assignments, etc.."
:type 'boolean
:group 'evil-collection)
(defvar evil-collection--modes-with-delayed-setup
`(emms
eshell)
"List of modes whose keybinds aren't completely set up after the mode is
loaded. This can be a problem for cases where we're doing key translations
using `evil-collection-setup-hook' which would result in an empty keymap.
Normally we run `evil-collection-setup-hook' right away after the mode
is loaded in `with-eval-after-load' (see `evil-collection-init') but for these
modes, we skip running that hook and let the corresponding `evil-collection'
package handle running `evil-collection-setup-hook'.
Elements in this list either match a target mode symbol or the car of a list in
`evil-collection--supported-modes'.
If `evil-collection-always-run-setup-hook-after-load' is t, this list isn't
read and `evil-collection-setup-hook' will be ran in the
`with-eval-after-load' block in `evil-collection-init'.")
(defcustom evil-collection-always-run-setup-hook-after-load nil
"Whether to always run `evil-collection-setup-hook' after mode is loaded.
See `evil-collection-init' and `evil-collection--modes-with-delayed-setup'."
:type 'boolean
:group 'evil-collection)
(defvar evil-collection--supported-modes
`(2048-game
ag
alchemist
anaconda-mode
apropos
arc-mode
atomic-chrome
auto-package-update
beginend
bluetooth
bm
bookmark
(buff-menu "buff-menu")
bufler
calc
calendar
cider
cmake-mode
color-rg
comint
company
compile
consult
corfu
crdt
(csv "csv-mode")
(custom cus-edit)
cus-theme
dashboard
daemons
deadgrep
debbugs
debug
devdocs
dictionary
diff-hl
diff-mode
dired
dired-sidebar
disk-usage
distel
doc-view
docker
eat
ebib
ebuku
edbi
edebug
ediff
eglot
elpaca
ement
explain-pause-mode
eldoc
elfeed
elisp-mode
elisp-refs
elisp-slime-nav
embark
emms
,@(when (>= emacs-major-version 29) '(emoji))
epa
ert
eshell
eval-sexp-fu
evil-mc
eww
fanyi
finder
flycheck
flymake
forge
free-keys
geiser
ggtags
git-timemachine
gited
gnus
go-mode
grep
guix
hackernews
helm
help
helpful
hg-histedit
hungry-delete
ibuffer
(image image-mode)
image-dired
image+
imenu
imenu-list
(indent "indent")
indium
info
ivy
js2-mode
,@(when (>= emacs-major-version 30) '(kmacro))
leetcode
lispy
lms
log-edit
log-view
lsp-ui-imenu
lua-mode
kotlin-mode
macrostep
man
(magit magit-submodule) ;; See https://github.com/emacs-evil/evil-collection/issues/637
magit-repos
magit-section
magit-todos
markdown-mode
,@(when evil-collection-setup-minibuffer '(minibuffer))
monky
mpc
mpdel
mpdired
mu4e
mu4e-conversation
neotree
newsticker
notmuch
nov
omnisharp
org
org-present
org-roam
osx-dictionary
outline
p4
(package-menu package)
pass
(pdf pdf-view)
popup
proced
(process-menu simple)
prodigy
profiler
python
quickrun
racer
racket-describe
realgud
reftex
replace ;; For `occur'.
restclient
rg
ripgrep
rjsx-mode
robe
rtags
ruby-mode
scheme
scroll-lock
selectrum
sh-script
,@(when (>= emacs-major-version 28) '(shortdoc))
simple
simple-mpc
slime
sly
snake
so-long
speedbar
,@(when (>= emacs-major-version 27) '(tab-bar))
tablist
tabulated-list
tar-mode
telega
(term term ansi-term multi-term)
tetris
,@(when (>= emacs-major-version 27) '(thread))
tide
timer-list
transmission
trashed
tuareg
typescript-mode
vc-annotate
vc-dir
vc-git
vdiff
vertico
view
vlf
vterm
vundo
w3m
wdired
wgrep
which-key
woman
xref
xwidget
yaml-mode
youtube-dl
zmusic
(ztree ztree-diff ztree-dir))
"List of modes supported by evil-collection. Elements are
either target mode symbols or lists which `car' is the mode
symbol and `cdr' the packages to register.")
(dolist (mode evil-collection--supported-modes)
(let ((ec-mode-name (if (listp mode) (car mode) mode)))
(autoload
(intern (format "evil-collection-%s-setup" ec-mode-name))
(expand-file-name
(format "modes/%s/evil-collection-%s" ec-mode-name ec-mode-name)
evil-collection-base-dir))))
(defcustom evil-collection-mode-list evil-collection--supported-modes
"The list of modes which will be evilified by `evil-collection-init'.
Elements are either target mode symbols or lists which `car' is the
mode symbol and `cdr' the packages to register.
By default, `minibuffer' is not included because many users find
this confusing. It will be included if
`evil-collection-setup-minibuffer' is set to t."
:type '(repeat (choice symbol sexp))
:group 'evil-collection)
(defcustom evil-collection-config
'((buff-menu :defer t)
(calc :defer t)
(comint :defer t)
(debug :defer t)
(diff-mode :defer t)
(dired :defer t)
(edebug :defer t)
(eldoc :defer t)
(help :defer t)
(image :defer t)
(indent :defer t)
(dired :defer t)
(info :defer t)
(replace :defer t)
(outline :defer t)
(package :defer t)
(package-menu :defer t)
(process-menu :defer t)
(simple :defer t)
(tab-bar :defer t)
(tabulated-list :defer t)
(xref :defer t))
"The list of modes with special configuration.
These modes should match entries within `evil-collection-mode-list'.
This variable is consumed only by `evil-collection-setup'.
NOTE: The API of this variable may change drastically.
Currently supported keys:
:defer t or TIME in seconds to defer loading mode."
:type '(repeat (choice symbol sexp))
:group 'evil-collection)
(defcustom evil-collection-key-whitelist '()
"List of keys that may be used by Evil Collection.
This is a list of strings that are suitable for input to
`kbd'. If there are no keys in the list, the whitelist will be ignored."
:type '(repeat string)
:group 'evil-collection)
(defcustom evil-collection-key-blacklist '()
"List of keys that may not be used by Evil Collection.
This is a list of strings that are suitable for input to `kbd'."
:type '(repeat string)
:group 'evil-collection)
(defcustom evil-collection-state-passlist '()
"List of evil states that may be used by Evil Collection.
This is a list of symbols that are suitable for input to
`evil-define-key'. Ignore when there are no states in the list."
:type '(repeat symbol)
:group 'evil-collection)
(defcustom evil-collection-state-denylist
(if (bound-and-true-p evil-disable-insert-state-bindings)
'(insert)
'())
"List of evil states that may not be used by Evil Collection.
This is a list of symbols that are suitable for input to
`evil-define-key'."
:type '(repeat symbol)
:group 'evil-collection)
(defvar evil-collection-setup-hook nil
"Hook run by `evil-collection-init' for each mode that is evilified.
This hook runs after all setup (including keybindings) for a mode has already
taken place. The arguments passed to functions for this hook are the name of the
mode and a list of keymap names (i.e. symbols, not actual keymaps) customized by
Evil Collection for that mode. More arguments may be added in the future, so
functions added to this hook should include a \"&rest _rest\" for forward
compatibility.")
(defun evil-collection-define-operator-key (operator map-sym &rest bindings)
"Define a key on a specific OPERATOR e.g. yank or delete.
This function is useful for adding specific binds to operator maps
\(e.g. `evil-yank' or `evil-delete') without erasing the original bind.
For example, say one wants to bind \"yf\" to something but also wants to keep
\"yy\".
This function takes care of checking the whitelist/blacklist against the full
binding.
For example:
\(evil-collection-define-operator-key \='yank
\='pass-mode-map \"f\" \='pass-copy-field)
This will check \"yf\" against a user's white/blacklist and also record the
binding in `annalist' as so."
(declare (indent defun))
(let* ((prefix (if (eq operator 'yank) "y" "d"))
(operators (if (eq operator 'yank)
'evil-collection-yank-operators
'evil-collection-delete-operators))
(remap (if (eq operator 'yank) [remap evil-yank] [remap evil-delete]))
(whitelist (mapcar 'kbd evil-collection-key-whitelist))
(blacklist (mapcar 'kbd evil-collection-key-blacklist))
filtered-bindings)
(while bindings
(let* ((key (pop bindings))
(key-with-prefix (concat prefix key))
(def (pop bindings))
(def-with-menu-item
`(menu-item
""
nil
:filter
(lambda (&optional _)
(when (or
(eq evil-this-operator (key-binding ,remap))
(memq evil-this-operator ,operators))
(setq evil-inhibit-operator t)
',def)))))
(when (or (and whitelist (member key-with-prefix whitelist))
(not (member key-with-prefix blacklist)))
(annalist-record 'evil-collection 'keybindings
;; Record the binding as if it was in 'normal mode
;; instead of 'operator mode as the user would be in
;; normal mode when triggering the operator.
(list map-sym 'normal key-with-prefix def)
:local (or (eq map-sym 'local)
(local-variable-p map-sym)))
;; Use the original key declared when actually setting the binding.
(push key filtered-bindings)
;; Use the definition attached to the menu-item when setting the
;; binding.
(push def-with-menu-item filtered-bindings))))
(setq filtered-bindings (nreverse filtered-bindings))
(evil-collection--define-key 'operator map-sym filtered-bindings)))
(defun evil-collection--filter-states (state)
"Return a list states after filtering STATE (a single symbol or list of symbols).
The return value adheres to `evil-collection-state-passlist' and
`evil-collection-state-denylist'. When the STATE is nil, which
means all states for `evil-define-key', return nil."
(let ((states (if (listp state) state (list state))))
(seq-difference
(if evil-collection-state-passlist
(seq-intersection states evil-collection-state-passlist)
states)
evil-collection-state-denylist)))
(defun evil-collection-define-key (state map-sym &rest bindings)
"Wrapper for `evil-define-key*' with additional features.
Unlike `evil-define-key*' MAP-SYM should be a quoted keymap other than the
unquoted keymap required for `evil-define-key*'. This function adds the ability
to filter keys on the basis of `evil-collection-key-whitelist' and
`evil-collection-key-blacklist'. It also records bindings with annalist.el."
(declare (indent defun))
(let* ((whitelist (mapcar 'kbd evil-collection-key-whitelist))
(blacklist (mapcar 'kbd evil-collection-key-blacklist))
(states-to-bind (evil-collection--filter-states state))
filtered-bindings)
(when (or states-to-bind (null state))
(while bindings
(let ((key (pop bindings))
(def (pop bindings)))
(when (or (and whitelist (member key whitelist))
(not (member key blacklist)))
(annalist-record 'evil-collection 'keybindings
(list map-sym state key def)
:local (or (eq map-sym 'local)
(local-variable-p map-sym)))
(push key filtered-bindings)
(push def filtered-bindings))))
(setq filtered-bindings (nreverse filtered-bindings))
(evil-collection--define-key states-to-bind map-sym filtered-bindings))))
(defun evil-collection-can-bind-key (key)
"Return whether or not we should bind KEY."
(let* ((whitelist (mapcar 'kbd evil-collection-key-whitelist))
(blacklist (mapcar 'kbd evil-collection-key-blacklist)))
(or (and whitelist (member key whitelist))
(not (member key blacklist)))))
(defun evil-collection--define-key (state map-sym bindings)
"Workhorse function for `evil-collection-define-key'.
See `evil-collection-define-key' docstring for more details."
(cond ((null bindings))
((and (boundp map-sym) (keymapp (symbol-value map-sym)))
(condition-case-unless-debug err
(apply #'evil-define-key*
state (symbol-value map-sym) bindings)
(error
(message "evil-collection: error setting key in %s %S"
map-sym err))))
((boundp map-sym)
(user-error "evil-collection: %s is not a keymap" map-sym))
(t
(let* ((fname (format "evil-collection-define-key-in-%s" map-sym))
(fun (make-symbol fname)))
(fset fun `(lambda (&rest args)
(when (and (boundp ',map-sym) (keymapp ,map-sym))
(remove-hook 'after-load-functions #',fun)
(condition-case-unless-debug err
(apply #'evil-define-key*
',state ,map-sym ',bindings)
(error
(message
,(format
"evil-collection: error setting key in %s %%S"
map-sym)
err))))))
(add-hook 'after-load-functions fun t)))))
(defun evil-collection-inhibit-insert-state (map-sym)
"Unmap insertion keys from normal state.
This is particularly useful for read-only modes."
(evil-collection-define-key 'normal map-sym
[remap evil-append] #'ignore
[remap evil-append-line] #'ignore
[remap evil-insert] #'ignore
[remap evil-insert-line] #'ignore
[remap evil-change] #'ignore
[remap evil-change-line] #'ignore
[remap evil-substitute] #'ignore
[remap evil-change-whole-line] #'ignore
[remap evil-delete] #'ignore
[remap evil-delete-line] #'ignore
[remap evil-delete-char] #'ignore
[remap evil-delete-backward-char] #'ignore
[remap evil-replace] #'ignore
[remap evil-replace-state] #'ignore
[remap evil-open-below] #'ignore
[remap evil-open-above] #'ignore
[remap evil-paste-after] #'ignore
[remap evil-paste-before] #'ignore
[remap evil-join] #'ignore
[remap evil-indent] #'ignore
[remap evil-shift-left] #'ignore
[remap evil-shift-right] #'ignore
[remap evil-invert-char] #'ignore))
(defun evil-collection-set-readonly-bindings (map-sym)
"Unmap insertion keys from normal state. Additionally q can `quit-window'.
This is particularly useful for read-only modes. Make sure it's
called before setting up other evil bindings so that it can be
overriden."
(evil-collection-inhibit-insert-state map-sym)
(evil-collection-define-key 'normal map-sym
"q" #'quit-window
"ZZ" #'quit-window
"ZQ" #'evil-quit))
(defun evil-collection--binding-lessp (a b)
"Comparison function used to sort bindings of the form (state key def)."
(let ((a-state (symbol-name (nth 0 a)))
(b-state (symbol-name (nth 0 b)))
(a-key (nth 1 a))
(b-key (nth 1 b)))
(if (not (string= a-state b-state))
(string-lessp a-state b-state)
(string-lessp a-key b-key))))
(annalist-define-view 'keybindings 'evil-collection-valid
(list (list 'keymap :sort #'annalist-string-<)
(list 'state :sort #'annalist-string-<))
:inherit 'valid)
(annalist-define-view 'keybindings 'evil-collection-active
(list (list 'keymap :sort #'annalist-string-<)
(list 'state :sort #'annalist-string-<))
:inherit 'active)
(defun evil-collection-describe-bindings (&optional arg)
"Print bindings made by Evil Collection to separate buffer.
With non-nil ARG, restrict to bindings corresponding to active
modes in the current buffer."
(interactive "P")
(annalist-describe 'evil-collection 'keybindings
(if arg
'evil-collection-active
'evil-collection-valid)))
(defun evil-collection--mode-file (mode file)
"Return path to FILE for MODE. Return nil if it doesn't exist."
(let ((path (expand-file-name
(format "modes/%s/%s" mode file) evil-collection-base-dir)))
(when (file-exists-p path)
path)))
(defun evil-collection-open-config-file (mode)
"Open configuration file corresponding to MODE."
(interactive
(list
(completing-read
"Mode: "
(cl-remove-if-not
(lambda (mode)
(evil-collection--mode-file mode (format "evil-collection-%s.el" mode)))
(directory-files
(expand-file-name "modes" evil-collection-base-dir)
nil "^[^.]")))))
(find-file (evil-collection--mode-file mode (format "evil-collection-%s.el" mode))))
(defun evil-collection-open-readme (mode)
"Open README.org corresponding to MODE."
(interactive
(list
(completing-read
"Mode: "
(cl-remove-if-not
(lambda (mode)
(evil-collection--mode-file mode "README.org"))
(directory-files
(expand-file-name "modes" evil-collection-base-dir)
nil "^[^.]")))))
(find-file (evil-collection--mode-file mode "README.org")))
(defun evil-collection--delay (condition form hook &optional append local name)
"Execute FORM when CONDITION becomes true, checking with HOOK.
NAME specifies the name of the entry added to HOOK. If APPEND is
non-nil, the entry is appended to the hook. If LOCAL is non-nil,
the buffer-local value of HOOK is modified.
This is a backport of `evil-delay' without the deprecation notice to deal with
CI until migration can be done.
Ref: https://github.com/emacs-evil/evil-collection/issues/750"
(eval `(evil-with-delay ,condition (,hook ,append ,local ,name) ,form) t))
;;;###autoload
(cl-defun evil-collection-translate-minor-mode-key (states modes
&rest translations
&key destructive
&allow-other-keys)
"Translate keys in the keymap(s) corresponding to STATES and MODES.
Similar to `evil-collection-translate-key' but for minor modes.
STATES should be the name of an evil state, a list of states, or nil. MODES
should be a symbol corresponding to minor-mode to make the translations in or a
list of minor-mode symbols. TRANSLATIONS corresponds to a list of
key replacement pairs. For example, specifying \"a\" \"b\" will bind \"a\" to
\"b\"'s definition in the keymap. Specifying nil as a replacement will unbind a
key. If DESTRUCTIVE is nil, a backup of the keymap will be stored on the initial
invocation, and future invocations will always look up keys in the backup
keymap. When no TRANSLATIONS are given, this function will only create the
backup keymap without making any translations. On the other hand, if DESTRUCTIVE
is non-nil, the keymap will be destructively altered without creating a backup.
For example, calling this function multiple times with \"a\" \"b\" \"b\" \"a\"
would continue to swap and unswap the definitions of these keys. This means that
when DESTRUCTIVE is non-nil, all related swaps/cycles should be done in the same
invocation."
(declare (indent defun))
(unless (listp modes)
(setq modes (list modes)))
(unless (and (listp states)
(not (null states)))
(setq states (list states)))
(dolist (mode-symbol modes)
(let ((keymap-symbol (intern (format "%S-map" mode-symbol))))
(dolist (state states)
(let ((hook-name
(symbol-name
(cl-gensym
(format "evil-collection-translate-key-in-%s" keymap-symbol)))))
(evil-collection--delay `(and (boundp ',keymap-symbol)
(keymapp ,keymap-symbol))
`(evil-collection--translate-minor-mode-key
',state
',mode-symbol
',translations
,destructive)
'after-load-functions
t
nil
hook-name))))))
(defun evil-collection--translate-minor-mode-key (state
mode-symbol
translations
destructive)
"Helper function for `evil-collection-translate-minor-mode-key'.
In the minor mode keymap corresponding to STATE and MODE-SYMBOL, make the key
TRANSLATIONS. When DESTRUCTIVE is non-nil, make the TRANSLATIONS destructively
without creating/referencing a backup keymap."
(let* ((keymap-symbol (intern (format "%S-map" mode-symbol)))
(backup-keymap-symbol (intern (format "evil-collection-%s%s-backup-map"
mode-symbol
(if state
(format "-%s-state" state)
""))))
(keymap (symbol-value keymap-symbol))
(lookup-keymap (if (and (not destructive)
(boundp backup-keymap-symbol))
(symbol-value backup-keymap-symbol)
(copy-keymap
(if state
(evil-get-minor-mode-keymap state mode-symbol)
keymap))))
(maps (cl-loop for (key replacement) on translations by 'cddr
;; :destructive can be in TRANSLATIONS
unless (keywordp key)
collect key
and collect (when replacement
(evil-lookup-key lookup-keymap replacement)))))
(unless (or destructive
(boundp backup-keymap-symbol))
(set backup-keymap-symbol lookup-keymap))
(apply #'evil-define-minor-mode-key state mode-symbol maps)))
(defun evil-collection--translate-key (state keymap-symbol
translations
destructive)
"Helper function for `evil-collection-translate-key'.
In the keymap corresponding to STATE and KEYMAP-SYMBOL, make the key
TRANSLATIONS. When DESTRUCTIVE is non-nil, make the TRANSLATIONS destructively
without creating/referencing a backup keymap."
(let* ((backup-keymap-symbol (intern (format "evil-collection-%s%s-backup-map"
keymap-symbol
(if state
(format "-%s-state" state)
""))))
(keymap (symbol-value keymap-symbol))
(lookup-keymap (if (and (not destructive)
(boundp backup-keymap-symbol))
(symbol-value backup-keymap-symbol)
(copy-keymap
(if state
(evil-get-auxiliary-keymap keymap state t t)
keymap))))
(maps (cl-loop for (key replacement) on translations by 'cddr
;; :destructive can be in TRANSLATIONS
unless (keywordp key)
collect key
and collect (when replacement
(evil-lookup-key lookup-keymap replacement)))))
(unless (or destructive
(boundp backup-keymap-symbol))
(set backup-keymap-symbol lookup-keymap))
(apply #'evil-define-key* state keymap maps)))
;;;###autoload
(cl-defun evil-collection-translate-key (states keymaps
&rest translations
&key destructive
&allow-other-keys)
"Translate keys in the keymap(s) corresponding to STATES and KEYMAPS.
STATES should be the name of an evil state, a list of states, or nil. KEYMAPS
should be a symbol corresponding to the keymap to make the translations in or a
list of keymap symbols. Like `evil-define-key', when a keymap does not exist,
the keybindings will be deferred until the keymap is defined, so
`with-eval-after-load' is not necessary. TRANSLATIONS corresponds to a list of
key replacement pairs. For example, specifying \"a\" \"b\" will bind \"a\" to
\"b\"'s definition in the keymap. Specifying nil as a replacement will unbind a
key. If DESTRUCTIVE is nil, a backup of the keymap will be stored on the initial
invocation, and future invocations will always look up keys in the backup
keymap. When no TRANSLATIONS are given, this function will only create the
backup keymap without making any translations. On the other hand, if DESTRUCTIVE
is non-nil, the keymap will be destructively altered without creating a backup.
For example, calling this function multiple times with \"a\" \"b\" \"b\" \"a\"
would continue to swap and unswap the definitions of these keys. This means that
when DESTRUCTIVE is non-nil, all related swaps/cycles should be done in the same
invocation."
(declare (indent defun))
(unless (listp keymaps)
(setq keymaps (list keymaps)))
(unless (and (listp states)
(not (null states)))
(setq states (list states)))
(dolist (keymap-symbol keymaps)
(dolist (state states)
(let ((hook-name
(symbol-name
(cl-gensym
(format "evil-collection-translate-key-in-%s" keymap-symbol)))))
(evil-collection--delay `(and (boundp ',keymap-symbol)
(keymapp ,keymap-symbol))
`(evil-collection--translate-key
',state
',keymap-symbol
',translations
,destructive)
'after-load-functions
t
nil
hook-name)))))
;;;###autoload
(defmacro evil-collection-swap-key (states keymaps &rest args)
"Wrapper around `evil-collection-translate-key' for swapping keys.
STATES, KEYMAPS, and ARGS are passed to `evil-collection-translate-key'. ARGS
should consist of key swaps (e.g. \"a\" \"b\" is equivalent to \"a\" \"b\" \"b\"
\"a\" with `evil-collection-translate-key') and optionally keyword arguments for
`evil-collection-translate-key'."
(declare (indent defun))
(setq args (cl-loop for (key replacement) on args by 'cddr
collect key and collect replacement
and unless (keywordp key)
collect replacement and collect key))
`(evil-collection-translate-key ,states ,keymaps ,@args))
;;;###autoload
(defmacro evil-collection-swap-minor-mode-key (states modes &rest args)
"Wrapper around `evil-collection-translate-minor-mode-key' for swapping keys.
STATES, MODES, and ARGS are passed to
`evil-collection-translate-minor-mode-key'. ARGS should consist of key swaps
\(e.g. \"a\" \"b\" is equivalent to \"a\" \"b\" \"b\" \"a\"
with `evil-collection-translate-minor-mode-key') and optionally keyword
arguments for `evil-collection-translate-minor-mode-key'."
(declare (indent defun))
(setq args (cl-loop for (key replacement) on args by 'cddr
collect key and collect replacement
and unless (keywordp key)
collect replacement and collect key))
`(evil-collection-translate-minor-mode-key ,states ,modes ,@args))
;;;###autoload
(defun evil-collection-require (mode &optional noerror)
"Require the evil-collection-MODE file, but do not activate it.
MODE should be a symbol. This requires the evil-collection-MODE
feature without needing to manipulate `load-path'. NOERROR is
forwarded to `require'."
(let* ((mode-name (symbol-name mode))
(feature (intern (format "evil-collection-%s" mode-name)))
(file (expand-file-name
(format "modes/%s/evil-collection-%s" mode-name mode-name)
evil-collection-base-dir)))
(require feature file noerror)))
(declare-function evil-collection-unimpaired-setup "evil-collection-unimpaired")
;;;###autoload
(defun evil-collection-init (&optional modes)
"Register the Evil bindings for all modes in `evil-collection-mode-list'.
Alternatively, you may register select bindings manually, for
instance:
(with-eval-after-load \='calendar
(evil-collection-calendar-setup))
If MODES is specified (as either one mode or a list of modes), use those modes
instead of the modes in `evil-collection-mode-list'."
(interactive)
(if modes
(or (listp modes) (setq modes (list modes)))
(setq modes evil-collection-mode-list))
(dolist (mode modes)
(let ((m mode)
(reqs (list mode)))
(when (listp mode)
(setq m (car mode)
reqs (cdr mode)))
(dolist (req reqs)
(with-eval-after-load req
;; (message (format "Loaded %S..." req))
(evil-collection-require m)
(funcall (intern (concat "evil-collection-" (symbol-name m)
"-setup")))
(let ((mode-keymaps
(ignore-errors
(symbol-value
(intern (format "evil-collection-%s-maps" m))))))
(when (or evil-collection-always-run-setup-hook-after-load
(not (memq m evil-collection--modes-with-delayed-setup)))
(run-hook-with-args 'evil-collection-setup-hook
m mode-keymaps)))))))
(when evil-collection-want-unimpaired-p
(evil-collection-require 'unimpaired)
(evil-collection-unimpaired-setup)))
(defun evil-collection-setup (&optional modes)
"Register the Evil bindings for all modes in `evil-collection-mode-list'.
----------------------EXPERIMENTAL------------------------------------------
This is a special wrapper over `evil-collection-init' that respects
configuration from `evil-collection-config'. This function is experimental,
so don't use if you don't want breakages or API changes.
If MODES is specified (as either one mode or a list of modes), use those modes
instead of the modes in `evil-collection-mode-list'.
----------------------EXPERIMENTAL------------------------------------------"
(if modes
(or (listp modes) (setq modes (list modes)))
(setq modes evil-collection-mode-list))
(let ((configs evil-collection-config)
(deferred-modes)
(delays))
(dolist (config configs)
(let ((defer (plist-get (cdr config) :defer)))
(when defer
(push (car config) deferred-modes)
(push defer delays))))
(let ((filtered-modes
(cl-remove-if
(lambda (mode)
(let ((filterp nil)
(modes (if (consp mode) mode (list mode))))
(dolist (m modes)
(let ((x (memq m deferred-modes)))
(when x
(setf filterp t)
;; `evil-collection-config' format is slightly different
;; than `evil-collection-mode-list', so use the mode
;; entry from the mode list instead.
(setf (car x) mode))))
filterp))
modes)))
(evil-collection-init filtered-modes))
(message (format "Deferring: %S" deferred-modes))
(dotimes (i (length deferred-modes))
(let ((mode (nth i deferred-modes))
(delay (nth i delays)))
;; (message (format "Delaying %S..."
;; (if (consp mode) (car mode) mode)))
(run-with-idle-timer
(if (numberp delay) delay 3) nil
(apply-partially 'evil-collection-init (list mode)))))))
(defvar evil-collection-delete-operators '(evil-delete
evil-cp-delete
evil-sp-delete
lispyville-delete)
"List of delete operators.")
(defvar evil-collection-yank-operators '(evil-yank
evil-cp-yank
evil-sp-yank
lispyville-yank)
"List of yank operators.")