。

Author: drzwz

.vs/ProjectSettings.json

@@ -0,0 +1,3 @@
+{
+  "CurrentProjectSetting": null
+}

.vs/slnx.sqlite

@@ -0,0 +1,19 @@
+# qWindTick
+
+  Wind DataFeed for kdb+tick
+
+## 功能
+
+  通过qWind/windkdb+接口订阅Wind实时行情，将行情发送到kdb+tick，供各类客户端订阅使用。
+
+## 用法
+
+1、下载qWindTick相关文件；下载kdb+，将q.k和q.exe放到指定文件夹下。
+
+2、根据需要修改.\q\windmd.q里的拟订阅行情的证券代码。
+
+3、运行qwindtibk.bat。
+
+4、q或其它客户端向tickerplant订阅行情（详见kdb+tick：<http://code.kx.com/q/tutorials/startingq/tick/>）
+
+## 注：对qWindTick的kdb+tick作了一些修改，主要包括日期改用time，收盘改为16:00等。

Readme.md

@@ -0,0 +1 @@
+q.k(download from kx.com)

q/q.k [download from kx.com]

@@ -0,0 +1 @@
+kdbuser:kdbpassword

q/qusers

@@ -0,0 +1,48 @@
+/ cx.q
+/ example clients
+
+x:.z.x 0                  / client type
+s:`;                   	  / default all symbols
+d:`GOOG`IBM`MSFT          / symbol selection
+t:`bar`taq`msg           / default tables
+h:hopen `::5010:kdbuser:kdbpassword           / connect to tickerplant
+
+
+/ rdb
+if[x~"rdb";
+ upd:insert]
+
+/ high low close volume
+if[x~"hlcv";
+ t:`trade;
+ hlcv:([sym:()]high:();low:();price:();size:());
+ upd:{[t;x]hlcv::select max high,min low,last price,sum size by sym
+  from(0!hlcv),select sym,high:price,low:price,price,size from x}]
+
+/ last
+if[x~"last";
+ upd:{[t;x].[t;();,;select by sym from x]}]
+
+/ show only
+if[x~"show";
+ tabcount:()!();
+ / count the incoming updates
+ upd:{[t;x] tabcount+::(enlist t)!enlist count x};
+ / show the dictionary every t milliseconds
+ .z.ts:{if[0<count tabcount; 
+	 -1"current total received record counts at time ",string .z.T;
+	 show tabcount;
+	 -1"";]};
+ if[0=system"t"; system"t 5000"]]
+
+/ all trades with then current quote
+if[x~"tq";
+ upd:{[t;x]$[t~`trade;
+  @[{tq,:x lj q};x;""];
+  q,:select by sym from x]}]
+
+if[x~"vwap";t:`trade;
+ upd:{[t;x]vwap+:select size wsum price,sum size by sym from x};
+ upds:{[t;x]vwap+:select size wsum price,sum size by sym from x;show x}]
+
+{h(".u.sub";x;s)} each t;

q/tick/cx.q

@@ -0,0 +1,3 @@
+if[not system"p";system"p 5012"];
+if[11h<>type key hsym `$ myhdbdir1: ssr[myhdbdir: getenv[`qhome],"\\..\\hdb";  "\\";  "/"]; system "md ",myhdbdir];
+system "l ",myhdbdir1;

q/tick/hdb.q

@@ -0,0 +1,79 @@
+/ q tick.q sym . -p 5001 </dev/null >foo 2>&1 &
+ /2014.03.12 remove license check
+ /2013.09.05 warn on corrupt log
+ /2013.08.14 allow <endofday> when -u is set
+ /2012.11.09 use timestamp type rather than time. -19h/"t"/.z.Z -> -16h/"n"/.z.P
+ /2011.02.10 i->i,j to avoid duplicate data if subscription whilst data in buffer
+ /2009.07.30 ts day (and "d"$a instead of floor a)
+ /2008.09.09 .k -> .q, 2.4
+ /2008.02.03 tick/r.k allow no log
+ /2007.09.03 check one day flip
+ /2006.10.18 check type?
+ /2006.07.24 pub then log
+ /2006.02.09 fix(2005.11.28) .z.ts end-of-day
+ /2006.01.05 @[;`sym;`g#] in tick.k load
+ /2005.12.21 tick/r.k reset `g#sym
+ /2005.12.11 feed can send .u.endofday
+ /2005.11.28 zero-end-of-day
+ /2005.10.28 allow`time on incoming
+ /2005.10.10 zero latency
+"kdb+tick 2.8 2014.03.12"
+
+if[not system"p";system"p 5010"];
+
+
+ /q tick.q SRC [DST] [-p 5010] [-o h]    //z.:SRC sym.q; DST log file path
+system"l tick/",(src:first .z.x,enlist"sym"),".q"
+
+
+\l tick/u.q
+\d .u
+ld:{if[not type key L::`$(-10_string L),string x;.[L;();:;()]];i::j::-11!(-2;L);if[0<=type i;-2 (string L)," is a corrupt log. Truncate to length ",(string last i)," and restart";exit 1];hopen L};
+tick:{init[];if[not min(`time`sym~2#key flip value@)each t;'`timesym];@[;`sym;`g#]each t;d::.z.D;if[l::count y;L::`$":",y,"/",x,10#".";l::ld d]};
+
+//endofday:{end d;d+:1;if[l;hclose l;l::0(`.u.ld;d)]};
+endofday:{ wday:d mod 7; if[wday within 2 6; end d];d+:1; if[l;hclose l;l::0(`.u.ld;d)]}; //  只在周1-5保存数据(2i=mon 6i=fir)
+ts:{if[d<x;if[d<x-1;system"t 0";'"more than one day?"];endofday[]]};
+
+
+if[system"t";
+    .z.ts:{pub'[t;value each t];@[`.;t;@[;`sym;`g#]0#];i::j;ts .z.D};
+    upd:{[t;x]
+    //if[not -16=type first first x;if[d<"d"$a:.z.P;.z.ts[]];a:"n"$a;x:$[0>type first x;a,x;(enlist(count first x)#a),x]];  //z.
+    if[not (type first first x)in(-16h;-19h);if[d<"d"$a:.z.P;.z.ts[]];a:"n"$a;x:$[0>type first x;a,x;(enlist(count first x)#a),x]]; //z.
+    t insert x;if[l;l enlist (`upd;t;x);j+:1];}
+  ];
+
+if[not system"t";system"t 1000";
+    //.z.ts:{ts .z.D};    
+    .z.ts:{ts `date$.z.Z+08:00:00};    //z. 收盘定在 16:00 数据保存日期=结算日
+    upd:{[t;x]ts"d"$a:.z.P;
+    //if[not -16=type first first x; a:"n"$a; x:$[0>type first x;a,x;(enlist(count first x)#a),x] ];  //z.
+    //z.:如果x第0个元素不是time或timestamp，则添加一个time字段
+    if[not (type first first x)in(-16h;-19h); a:"t"$a; x:$[0>type first x;a,x;(enlist(count first x)#a),x] ];  //z.
+    //z.: f:key flip value t 相当于cols `t;  enlist `a`b!1 2和flip `a`b!(1 2;3 4)均为表
+    f:key flip value t;pub[t;$[0>type first x;enlist f!x;flip f!x]];if[l;l enlist (`upd;t;x);i+:1];}
+  ];
+
+\d .
+.u.tick[src;.z.x 1];
+
+\
+  globals used
+  .u.w - dictionary of tables->(handle;syms)
+  .u.i - msg count in log file
+  .u.j - total msg count (log file plus those held in buffer)
+  .u.t - table names
+  .u.L - tp log filename, e.g. `:./sym2008.09.11
+  .u.l - handle to tp log file
+  .u.d - date
+
+ /test
+ >q tick.q
+ >q tick/ssl.q
+
+ /run
+ >q tick.q sym  .  -p 5010   /tick
+ >q tick/r.q :5010 -p 5011   /rdb
+ >q sym            -p 5012   /hdb
+ >q tick/ssl.q sym :5010     /feed

q/tick/tick.q

@@ -0,0 +1,43 @@
+/q tick/r.q [host]:port[:usr:pwd] [host]:port[:usr:pwd]
+/2008.09.09 .k ->.q
+
+if[not system"p";system"p 5011"];
+
+.z.zd:17 3 0;   //z.
+if[not "w"=first string .z.o;system "sleep 1"];
+
+//upd:insert;
+upd:{[t;x]$[t=`taq;`taq upsert `sym xkey x;t insert x];};  //z.
+
+/ get the ticker plant and history ports, defaults are 5010,5012
+//.u.x:.z.x,(count .z.x)_(":5010";":5012");
+.u.x:.z.x,(count .z.x)_(":5010:kdbuser:kdbpassword";":5012:kdbuser:kdbpassword"); //z.
+
+/ end of day: save, clear, hdb reload
+//z.:At end of day, the tickerplant sends messages to all its real time subscribers, telling them to execute their monadic end of day function called `.u.end. The tickerplant supplies a date which is typically the previous day’s date. When customizing your RTS, define .u.end to achieve whatever behavior you deem appropriate at end of day. 
+//z.:t@:where `g=attr each t@\:`sym;: This line obtains the subset of tables in t that have the grouped attribute on their sym column. This is done because later these tables will be emptied out and their attribute information will be lost. Therefore we store this attribute information now so the attributes can be re-applied after the clear out.
+//z.:.Q.hdpf is a high level function which saves all in memory tables to disk in partitioned format, empties them out and then instructs the HDB to reload. Its inputs at runtime will be: (1)location of HDB,(2) `:. (current working directory – root of on-disk partitioned database),(3) x=2016.07.12 (input to .u.end as supplied by TP. This is the partition to write to),(4) `sym (column on which to sort/part the tables prior to persisting)
+//z.:@[;`sym;`g#] each t;  applies the g attribute to the sym column of each table as previously discussed
+//.u.end:{t:tables`.;t@:where `g=attr each t@\:`sym;.Q.hdpf[`$":",.u.x 1;`:.;x;`sym];@[;`sym;`g#] each t;}; //orginal
+
+k)hdpft:{[h;d;p;f;t](@[`.;;0#].Q.dpft[d;p;f]@)'t@>(#.:)'t;if[h:@[<:;h;0];h"\\l .";>h]}; //z. added;changed from .Q.hdpf
+.u.end:{t:enlist`bar;t@:where `g=attr each t@\:`sym;hdpft[`$":",.u.x 1;hsym[`$ssr[ssr[getenv[`qhome];"\\";"/"];"/q";"/hdb"]];x;`sym;t];@[;`sym;`g#] each t;};  // changed by z.; 修改保存路径；修改为只保存bar表；若要保存taq,请参照修改，并删除本文件最后一行）
+
+/ init schema and sync up from log file;cd to hdb(so client save can run)
+//z.:This function is invoked at startup once the RDB has connected/subscribed to the TP. .u.rep takes two inputs. The first input, x, is a list of two-element lists, each containing a table name (as a symbol) and an empty schema for that table. The second argument to .u.rep, y, is a single two-element list. These inputs are supplied by the TP upon subscription.y is a pair where the last element is the TP logfile and the first element is the number of messages written to this logfile so far.
+//z.:(.[;();:;].)each x; ==((set[;].) each x;)This line just loops over the table name/empty table pairs and initializes these tables accordingly within the current working namespace (default namespace).
+//z.:-11!y;   This line simply replays an appropriate number of messages from the start of the TP logfile. 
+//z.:system "cd ",1_-10_string first reverse y;    This changes the current working directory of the RDB to the root of the on-disk partitioned database. Therefore, when .Q.hdpf is invoked at EOD, the day’s records will be written to the correct place.
+.u.rep:{(.[;();:;].)each x;if[null first y;:()];-11!y;system "cd ",1_-10_string first reverse y};
+/ HARDCODE \cd if other than logdir/db
+
+/ connect to ticker plant for (schema;(logcount;log))
+//z.:kicks the RDB into life.   hopen `$":",.u.x 0    Reading this from the right, we obtain the location of the tickerplant process which is then passed into the hopen function. hopen returns a handle (connection) to the tickerplant. Through this handle, we then send a synchronous message to the tickerplant, telling it to do two things:1. Subscribe to all tables and to all symbols. 2. Obtain name/location of TP logfile and number of messages written by TP to said logfile .  `.u `i:  .u.i - msg count in log file    `.u `L: .u.L - tp log filename, e.g. `:./sym2008.09.11
+
+//z.:.u.sub is a dyadic function defined on the tickerplant. If passed null symbols (as is the case here), it will return a list of pairs (table name/empty table), consistent with the first input to .u.rep
+.u.rep .(hopen `$":",.u.x 0)"(.u.sub[`;`];`.u `i`L)"; //original
+
+
+//z.: ref: Building Real Time Tick Subscribers q_for_Gods_Aug_2014.pdf  http://www.firstderivatives.com/downloads/q_for_Gods_July_2014.pdf
+
+if[`taq in key `.;taq:`sym xkey taq];  //z.

q/tick/tick/r.q

@@ -0,0 +1,6 @@
+taq:([]time:`time$();sym:`g#`symbol$();prevclose:`real$();open:`real$();high:`real$();low:`real$();close:`real$();volume:`real$();openint:`real$();bid:`real$();bsize:`real$();ask:`real$();asize:`real$()); //trade & quote
+
+bar:([]time:`time$();sym:`g#`symbol$();close:`real$();volume:`real$());    //trade
+
+msg:([]time:`time$();sym:`g#`symbol$();src:`int$();dst:();t:`$();data:());  
+