Help with module logik

[ChrisVonFrosta]

I have a "bigger" script in the following form:

#def ObjectA
    ...
end

#def ObjectB
    ...
end

def functionA
    ...
end


def functionB
    ...
end


var objekt_a1   = ObjectA(...)
...
var objekt_a8   = ObjectA(...)
...
var object_b15   = ObjectB(...)

tasmota.add_rule("PCF8574-2_INP", functionB)

For the next time i will often change some parameter on the object initialisation. I do not want to edit the big file on a smartphone while being in the field.
so i want to split this script in a Module like this form:

SensorAktor.be:

var SensorAktorModul = module("SensorAktorModul")    # use for import

#def ObjectA
    ...
end

#def ObjectB
    ...
end

def functionA
    ...
end


def functionB
    ...
end

return SensorAktorModul    # return the module as the output of import

app.be:

import  SensorAktorModul

var ovabjekt_a1   = SensorAktor.ObjectA(...)
...
var objekt_a8   = SensorAktor.ObjectA(...)
...
var object_b15   = SensorAktor.ObjectB(...)

tasmota.add_rule("PCF8574-2_INP", SensorAktor.functionB)

if i do so, i got the compiling error message: "module 'SensorAktorModul' has no member 'ObjectA'".
Is there a better way to fragment this?
or do i have to define helper functions outside the classes for all methods i want to use inside the app.be?

thx, again, and again, ...

[s-hadinger]

You need to do something like SensorAktor.ObjectA = ObjectA in the code of the module

The module does not automatically gets all declared objects but only those that you explicitly add.

[ChrisVonFrosta]

Thank you! that is bad. it was the reason why i want to split this script to have not the initialisate the instances in the large module file.

BUT, pls notice: the error message said: "... no member 'ObjectA'
'ObjectA` ist the init function, not a single instance.

[ChrisVonFrosta]

Berry output:

SensorAktorModul loaded
BRY: failed to run compiled code 'attribute_error' - module 'SensorAktorModul' has no member 'ObjectA'

[sfromis]

Not clear what structure you are aiming for with those ObjectX. Do you want class instances, or do you want static-like functions returning "something unspecified"? You may have "simplified" your example to the point of not being understandable.

You could have the module creation returning an instance of a class having "static-like" functions, and then you could have those functions callable by modulename.functionname().

It generally works better if simplified examples are still valid syntax, and executable to the point of your issue, unlike what you posted.

[ChrisVonFrosta]

yes, understood. Thx. i will try to show a better example soon, hopefully.

[ChrisVonFrosta]

I have now tried to reduce the project as much as possible and filled the few methods with print statements.
Here and there might still be an old comment, I hope that doesn't bother you.
I am not using a standard board and only use inputs and outputs like PCA9685 and PCF8574). Therefore, I had to rebuild many Tasmota functions in Berry (LightColor, double_push, long_push).
Which makes it relatively large. Hence my question.

Basically, my question is simple. I would like to have everything from the definition of class Taster : Sensor... end in another file.
Especially, I want to get the instantiations of the objects out of the large file.

If I understand you correctly, all the suggestions made have the consequence that I would also have to maintain the objects in the SensorAktor.be. That's exactly what I wanted to avoid.

# Main Class Aktor
class Aktor
    var name, aktortype
    static all=[]    

    def init( name, aktortype )
        self.name = name
        self.aktortype = aktortype
        Aktor.all.push(self)
    end

    static def list_all()
        for aktor : Aktor.all
            print(aktor.name)
        end
    end
end


# # Subclass from Aktor
class Licht : Aktor
    var output_number

    def init(output_number, name)      # sub-class takes 2 arguments
        super(self).init( name, "Licht" )     # call constructor of super-class
        self.output_number = output_number
    end
    
    def on()
        print("Aktor: ",self.aktortype, " ON")
    end

end


# Main Class Sensor
class Sensor
    var name, sensortype
    static all=[]

    def init(name, sensortype )
        self.name = name
        self.sensortype = sensortype
        Sensor.all.push(self) 
    end
    
    static def triggerNo(input_number, input_value)           # wird  von parse_trigger_msg() aufgerufen
        for sens : Sensor.all
            if sens.input_number==input_number
                sens.actual_value   =   input_value
                sens.trigger(1)
                print("||>> sensor",sens.sensortype, "trigger(1)")
                return
            end
        end
        print("No Sensor with input_number:", input_number , "gefunden")
        
    end
    
end

# Subclass from Sensor
class Taster : Sensor
    var input_number
    #ar single_push_actions, double_push_actions, triple_push_actions, long_push_actions
  
    def init(input_number,name)
        super(self).init(name, "Taster" )     # call constructor of super-class
        self.input_number = input_number
    end

    def trigger(trigger)        # trigger=1 only when called from parse_trigger_msg() 
        print("Sensor", self.sensortype, ": Trigger")
            
    end # Ende Funktion trigger() 


end

#######################################################################
###     I wish to have all the stuff below in a seperate file       ###
#######################################################################


##  Aktoren Instanzen intitialisieren
#   Licht:      output_number, name, aktortype, room, floor) 
#   CCTLicht:   output_number, name, DEFAULT_brightness, DEFAULT_color, room, floor
#   TasmoRemote:

var l_wohnz     = Licht(1, "Name1")
#....
var l_essz      = Licht(15, "Name15")

##  Sensoren Instanzen intitialisieren
#   Taster: (output_number,"Name",  [single_push_actions]  , [double_push_actions], [tripple_push_actions], [long_push_actions], "room",FLOOR)  
#   Bwm:    

var t_wohnz     =   Taster(1,"room1")
#...
var t_essz      =   Taster(5,"room5")

# runtime
Aktor.list_all()
t_wohnz.trigger(1)
l_wohnz.on(2000)

[sfromis]

everything from the definition of class Taster : Sensor... end

Does that mean all of classes Aktor, Licht, Sensor and Taster? Assuming yes.

You did not show where you stumbled.... Anyway, if all you want is to be able to create instances of classes, without the module as such housing data, one approach would be to let the module be a singleton only able to create class instances, like this:

var mymodule = module("mymodule")

#  your classes

mymodule.Licht = def (output_number, name) return Licht(output_number, name) end
mymodule.Taster = def (input_number, name) return Taster(input_number, name) end
return mymodule

And then code like var l_wohnz = mymodule.Licht(1, 'Name1')

As the Licht class is encapsulated in the module, a Licht field is added to the module, and having a function to create an instance of the class. The return mymodule does not have to return the module, it could also return some class or class instance to do similar stuff, and also have fields.

You could also do it all without a module, by simply having the classes in a file, and then do a load('myclasses.be'), to have the classes defined in the same scope as the following lines.

[ChrisVonFrosta]

Does that mean all of classes Aktor, Licht, Sensor and Taster? Assuming yes.

if i understand this correctly, then no. But your example is that what i am looking for.
I had this idea for a short moment and forgot it your answer.
Thank you alot!

The return mymodule does not have to return the module, it could also return some class or class instance to do similar stuff, and also have fields.

That is a new information for me, i keep in mind. thx

You could also do it all without a module, by simply having the classes in a file, and then do a load('myclasses.be'), to have the classes defined in the same scope as the following lines.

i tried this before open the thread. Maybe i missinterprated the error messages and the reason was another.

since i plan to extend the features (zigbee, MCP23008, extend webGUI), i thought it could a better idea to use modules.

Your answers are aswome and animate me to ask more.
But i learnd here, i should open a new dissusion ;)

[sfromis]

BTW. As classes also "just" become instances, this shorter form of exposing classes outside of the module encapsulation should also work:
mymodule.Licht = Licht

[ChrisVonFrosta]

your example:

mymodule.Licht = def (output_number, name) return Licht(output_number, name) end

i did this in another project in a sligthly different style - with no return:

mymodule.myfunction = def (arg)
    myfunction (arg)    
end

what differents makes the return?
it worked at that time, so do not niced that i have to add a return.

[sfromis]

Without context, like what you did, hard to say anything, but removing the return mymodule from my example makes the result of the import mymodule be nil, which is obviously bad.

[ChrisVonFrosta]

thank you so much for verifying! i wonder what kind of test envirement you have, to check all things in this fast time.
Maybe, i was wondering about some nils in former time. i keep that in mind

[sfromis]

My test environment is just a regular Tasmota device, and having some examples in the file system, or for copy/paste.

[ChrisVonFrosta]

You could also do it all without a module, by simply having the classes in a file, and then do a load('myclasses.be'), to have the classes defined in the same scope as the following lines.

this results in an error:

BRY: failed to load '/controll.be' (syntax_error - /controll.be:13: 'Licht' undeclared (first use in this function))
false

[sfromis]

Without context, like what you did, hard to say anything, not even about what that line 13 is. I put the 4 classes in a .be file and had no trouble doing a load of that.

[ChrisVonFrosta]

var l_wohnz = Licht(0, "name1")
i cannot use the init function Licht() if loading th class only version of AktorSensor.be

but if you test it with a simple example, the problem/fault is on my side
did you also try to initialize one instance?

[sfromis]

You are still not indicating what you even loaded. What I posted was that the 4 classes in one .be file was one way of doing it. What you post now looks completely different from what I posted. And yes, I did test.

[ChrisVonFrosta]

sorry. that is not so easy since i tried with the original objects (much more parameter) and I don't want to cause any more confusion.
i loaded a file that includes my classes. But not this simple test example...

however. both options work. Module version and the "load" version.
Thank you for your efforts.