build.gradle

buildscript {
	repositories {
		mavenCentral()
	}
	dependencies {
		classpath 'com.adaptc.gradle:nexus-workflow:0.7'
	}
}

apply plugin:'idea'
apply plugin:com.adaptc.gradle.nexusworkflow.NexusWorkflowPlugin

subprojects { proj ->
	group = "com.adaptc.gradle"

	apply plugin:'java'
	apply plugin:'groovy'
	apply plugin:'maven'
	apply plugin:'signing'
	apply plugin:'eclipse'
	apply plugin:'idea'

	configurations {
		deployerJars
	}

	configurations.all {
		// check for updates every build
		resolutionStrategy.cacheChangingModulesFor 0, 'seconds'
	}

	repositories {
		mavenCentral()
	}

	dependencies {
		deployerJars "org.apache.maven.wagon:wagon-http:1.0-beta-2"
		testCompile ("org.spockframework:spock-core:0.7-groovy-2.0") {
			exclude module:"groovy-all"
		}
		compile gradleApi()
		compile localGroovy()
	}

	sourceCompatibility = "1.8"
	targetCompatibility = "1.8"

	jar {
		manifest.mainAttributes(
				"Built-By": System.properties['user.name'],
				"Created-By": System.properties['java.vm.version'] + " (" + System.properties['java.vm.vendor'] + ")",
				"Implementation-Title": "Adaptive Computing Gradle Plugins - " + proj.archivesBaseName,
				"Implementation-Version": proj.version,
				"Implementation-Vendor": 'adaptivecomputing.com')
	}

	task sourcesJar(type: Jar) {
		classifier = 'sources'
		from sourceSets.main.allSource
	}

	task javadocJar(type: Jar, dependsOn:javadoc) {
		classifier = 'javadoc'
		from javadoc.destinationDir
	}

	artifacts {
		archives jar
		archives sourcesJar
		archives javadocJar
	}

	signing {
		required { !proj.version.contains("-SNAPSHOT") }
		sign configurations.archives
	}

	uploadArchives {
		repositories.mavenDeployer {
			beforeDeployment { deployment -> signing.signPom(deployment) }

			configuration = configurations.deployerJars
			repository(url:rootProject."oss-releases.url") {
				authentication(userName:rootProject."oss-releases.username", password:rootProject."oss-releases.password")
			}
			snapshotRepository(url:rootProject."oss-snapshots.url") {
				authentication(userName:rootProject."oss-snapshots.username", password:rootProject."oss-snapshots.password")
			}

			pom {
				project {
					name proj.projectName
					description proj.projectDescription
					licenses {
						license {
							name "The Apache Software License, Version 2.0"
							url "http://www.apache.org/licenses/LICENSE-2.0.txt"
							distribution "repo"
						}
					}
					url "http://github.com/adaptivecomputing/plugins-gradle"
					scm {
						connection "scm:git:https://github.com/adaptivecomputing/plugins-gradle.git"
						developerConnection "scm:git:https://github.com/adaptivecomputing/plugins-gradle.git"
						url "http://github.com/adaptivecomputing/plugins-gradle"
					}
					developers {
						developer {
							id "bsaville"
							name "Brian Saville"
							email "bsaville@adaptivecomputing.com"
							organization = "Adaptive Computing, Inc."
							organizationUrl "http://adaptivecomputing.com"
							timezone "-7"
						}
					}
				}
			}
		}
	}
}

task wrapper(type: Wrapper) {
	gradleVersion = '2.3'
	jarFile = 'wrapper/wrapper.jar'
}