Add FETestHelpers.HeartbeatTracker

aaronrenner · aaronrenner · commit fb7ab7668695 · 2019-05-15T21:35:27.000-06:00
This will make tracking heartbeat intervals much easier
diff --git a/.gitlab-ci.yml b/.gitlab-ci.yml
@@ -121,6 +121,24 @@ dialyzer:fe_reporting:
     - install_asdf_env_and_deps
     - build:dev
 
+dialyzer:fe_test_helpers:
+  stage: test
+  variables:
+    DIALYZER_FE_TEST_HELPERS_CACHE_VERSION: 1
+  # --format short can't be used here due to: https://github.com/jeremyjh/dialyxir/issues/314
+  # --list-unused-filters must be used as a command line option instead of in
+  #      mix.exs due to: https://github.com/jeremyjh/dialyxir/issues/313
+  script: make dialyzer_fe_test_helpers
+  cache:
+    key: $CI_JOB_NAME-$DIALYZER_FE_TEST_HELPERS_CACHE_VERSION
+    paths:
+      - "*/_build/dev/*.plt"
+      - "*/_build/dev/*.plt.hash"
+      - $MIX_HOME/*.plt
+  dependencies:
+    - install_asdf_env_and_deps
+    - build:dev
+
 dialyzer:freezer_eye:
   stage: test
   variables:
diff --git a/Makefile b/Makefile
@@ -28,12 +28,13 @@ endef
 
 
 $(eval $(call APP_TEMPLATE,adafruit_io_http_client))
+$(eval $(call APP_TEMPLATE,fe_test_helpers))
 $(eval $(call APP_TEMPLATE,fe_reporting))
 $(eval $(call APP_TEMPLATE,freezer_eye))
 
-install_deps: install_deps_adafruit_io_http_client install_deps_freezer_eye install_deps_fe_reporting
-compile: compile_adafruit_io_http_client compile_freezer_eye compile_fe_reporting
-test: test_adafruit_io_http_client test_freezer_eye test_fe_reporting
-dialyzer: dialyzer_adafruit_io_http_client dialyzer_freezer_eye dialyzer_fe_reporting
-check_format: check_format_adafruit_io_http_client check_format_freezer_eye check_format_fe_reporting
-check_unused_deps: check_unused_deps_adafruit_io_http_client check_unused_deps_freezer_eye check_unused_deps_fe_reporting
+install_deps: install_deps_adafruit_io_http_client install_deps_freezer_eye install_deps_fe_reporting install_deps_fe_test_helpers
+compile: compile_adafruit_io_http_client compile_freezer_eye compile_fe_reporting compile_fe_test_helpers
+test: test_adafruit_io_http_client test_freezer_eye test_fe_reporting test_fe_test_helpers
+dialyzer: dialyzer_adafruit_io_http_client dialyzer_freezer_eye dialyzer_fe_reporting dialyzer_fe_test_helpers
+check_format: check_format_adafruit_io_http_client check_format_freezer_eye check_format_fe_reporting check_format_fe_test_helpers
+check_unused_deps: check_unused_deps_adafruit_io_http_client check_unused_deps_freezer_eye check_unused_deps_fe_reporting check_unused_deps_fe_test_helpers
diff --git a/fe_test_helpers/.dialyzer_ignore.exs b/fe_test_helpers/.dialyzer_ignore.exs
@@ -0,0 +1,3 @@
+# Used for ignoring dialyzer errors
+# See: https://github.com/jeremyjh/dialyxir/tree/fd13c1cef28cde1b563236405e1441ada867b314#elixir-term-format
+[]
diff --git a/fe_test_helpers/.formatter.exs b/fe_test_helpers/.formatter.exs
@@ -0,0 +1,4 @@
+# Used by "mix format"
+[
+  inputs: ["{mix,.formatter}.exs", "{config,lib,test}/**/*.{ex,exs}"]
+]
diff --git a/fe_test_helpers/.gitignore b/fe_test_helpers/.gitignore
@@ -0,0 +1,24 @@
+# The directory Mix will write compiled artifacts to.
+/_build/
+
+# If you run "mix test --cover", coverage assets end up here.
+/cover/
+
+# The directory Mix downloads your dependencies sources to.
+/deps/
+
+# Where third-party dependencies like ExDoc output generated docs.
+/doc/
+
+# Ignore .fetch files in case you like to edit your project deps locally.
+/.fetch
+
+# If the VM crashes, it generates a dump, let's ignore it too.
+erl_crash.dump
+
+# Also ignore archive artifacts (built via "mix archive.build").
+*.ez
+
+# Ignore package tarball (built via "mix hex.build").
+fe_test_helpers-*.tar
+
diff --git a/fe_test_helpers/README.md b/fe_test_helpers/README.md
@@ -0,0 +1,3 @@
+# FETestHelpers
+
+Test helpers for use with FreezerEye.
diff --git a/fe_test_helpers/config/config.exs b/fe_test_helpers/config/config.exs
@@ -0,0 +1,30 @@
+# This file is responsible for configuring your application
+# and its dependencies with the aid of the Mix.Config module.
+use Mix.Config
+
+# This configuration is loaded before any dependency and is restricted
+# to this project. If another project depends on this project, this
+# file won't be loaded nor affect the parent project. For this reason,
+# if you want to provide default values for your application for
+# third-party users, it should be done in your "mix.exs" file.
+
+# You can configure your application as:
+#
+#     config :fe_test_helpers, key: :value
+#
+# and access this configuration in your application as:
+#
+#     Application.get_env(:fe_test_helpers, :key)
+#
+# You can also configure a third-party app:
+#
+#     config :logger, level: :info
+#
+
+# It is also possible to import configuration files, relative to this
+# directory. For example, you can emulate configuration per environment
+# by uncommenting the line below and defining dev.exs, test.exs and such.
+# Configuration from the imported file will override the ones defined
+# here (which is why it is important to import them last).
+#
+#     import_config "#{Mix.env()}.exs"
diff --git a/fe_test_helpers/lib/fe_test_helpers.ex b/fe_test_helpers/lib/fe_test_helpers.ex
@@ -0,0 +1,5 @@
+defmodule FETestHelpers do
+  @moduledoc """
+  Test helpers for FreezerEye
+  """
+end
diff --git a/fe_test_helpers/lib/fe_test_helpers/heartbeat_tracker.ex b/fe_test_helpers/lib/fe_test_helpers/heartbeat_tracker.ex
@@ -0,0 +1,36 @@
+defmodule FETestHelpers.HeartbeatTracker do
+  @moduledoc """
+  Heartbeat tracking helper
+  """
+
+  alias __MODULE__.Impl
+
+  @type start_link_opt :: GenServer.option()
+  @type tracker :: pid()
+
+  @spec start_link([start_link_opt]) :: GenServer.on_start()
+  def start_link(_opts) do
+    Agent.start_link(fn -> Impl.new() end)
+  end
+
+  @spec record_heartbeat(tracker) :: :ok
+  def record_heartbeat(pid) do
+    Agent.update(pid, fn impl ->
+      Impl.record_heartbeat(impl)
+    end)
+  end
+
+  @spec list_heartbeat_timestamps(tracker) :: [DateTime.t()]
+  def list_heartbeat_timestamps(pid) do
+    pid
+    |> Agent.get(& &1)
+    |> Impl.list_heartbeat_timestamps()
+  end
+
+  @spec list_heartbeat_intervals(tracker, System.time_unit()) :: [integer]
+  def list_heartbeat_intervals(pid, time_unit \\ :second) do
+    pid
+    |> Agent.get(& &1)
+    |> Impl.list_heartbeat_intervals(time_unit)
+  end
+end
diff --git a/fe_test_helpers/lib/fe_test_helpers/heartbeat_tracker/impl.ex b/fe_test_helpers/lib/fe_test_helpers/heartbeat_tracker/impl.ex
@@ -0,0 +1,38 @@
+defmodule FETestHelpers.HeartbeatTracker.Impl do
+  @moduledoc false
+
+  @opaque t :: [DateTime.t()]
+
+  defguardp is_impl(data) when is_list(data)
+
+  @spec new :: t
+  def new, do: []
+
+  @spec record_heartbeat(t, DateTime.t()) :: t
+  def record_heartbeat(reversed_heartbeats, timestamp = %DateTime{} \\ DateTime.utc_now())
+      when is_impl(reversed_heartbeats) do
+    [timestamp | reversed_heartbeats]
+  end
+
+  @spec list_heartbeat_timestamps(t) :: [DateTime.t()]
+  def list_heartbeat_timestamps(reversed_heartbeats) when is_impl(reversed_heartbeats) do
+    Enum.reverse(reversed_heartbeats)
+  end
+
+  @spec list_heartbeat_intervals(t, System.time_unit()) :: [integer]
+  def list_heartbeat_intervals(reversed_heartbeats, time_unit \\ :second) do
+    reversed_heartbeats
+    |> Enum.reverse()
+    |> do_list_heartbeat_intervals(time_unit)
+  end
+
+  defp do_list_heartbeat_intervals(
+         [%DateTime{} = current | [%DateTime{} = next | _] = rest],
+         time_unit
+       ) do
+    [DateTime.diff(next, current, time_unit) | do_list_heartbeat_intervals(rest, time_unit)]
+  end
+
+  defp do_list_heartbeat_intervals([%DateTime{} | []], _), do: []
+  defp do_list_heartbeat_intervals([], _), do: []
+end
diff --git a/fe_test_helpers/mix.exs b/fe_test_helpers/mix.exs
@@ -0,0 +1,36 @@
+defmodule FETestHelpers.MixProject do
+  use Mix.Project
+
+  def project do
+    [
+      app: :fe_test_helpers,
+      version: "0.1.0",
+      elixir: "~> 1.8",
+      start_permanent: Mix.env() == :prod,
+      deps: deps(),
+      dialyzer: dialyzer()
+    ]
+  end
+
+  # Run "mix help compile.app" to learn about applications.
+  def application do
+    [
+      extra_applications: [:logger]
+    ]
+  end
+
+  # Run "mix help deps" to learn about dependencies.
+  defp deps do
+    [
+      {:propcheck, "~> 1.1", only: [:dev, :test]},
+      {:dialyxir, "~> 1.0.0-rc.6", only: [:dev], runtime: false}
+    ]
+  end
+
+  defp dialyzer do
+    [
+      ignore_warnings: ".dialyzer_ignore.exs",
+      list_unused_filters: true
+    ]
+  end
+end
diff --git a/fe_test_helpers/mix.lock b/fe_test_helpers/mix.lock
@@ -0,0 +1,6 @@
+%{
+  "dialyxir": {:hex, :dialyxir, "1.0.0-rc.6", "78e97d9c0ff1b5521dd68041193891aebebce52fc3b93463c0a6806874557d7d", [:mix], [{:erlex, "~> 0.2.1", [hex: :erlex, repo: "hexpm", optional: false]}], "hexpm"},
+  "erlex": {:hex, :erlex, "0.2.1", "cee02918660807cbba9a7229cae9b42d1c6143b768c781fa6cee1eaf03ad860b", [:mix], [], "hexpm"},
+  "propcheck": {:hex, :propcheck, "1.1.5", "be6e904bed62b556273338ce51e4246764f0439d7367c4de78542bb43059d636", [:mix], [{:proper, "~> 1.3", [hex: :proper, repo: "hexpm", optional: false]}], "hexpm"},
+  "proper": {:hex, :proper, "1.3.0", "c1acd51c51da17a2fe91d7a6fc6a0c25a6a9849d8dc77093533109d1218d8457", [:make, :mix, :rebar3], [], "hexpm"},
+}
diff --git a/fe_test_helpers/test/fe_test_helpers/heartbeat_tracker/impl_test.exs b/fe_test_helpers/test/fe_test_helpers/heartbeat_tracker/impl_test.exs
@@ -0,0 +1,82 @@
+defmodule FETestHelpers.HeartbeatTracker.ImplTest do
+  use ExUnit.Case, async: true
+  use PropCheck
+
+  alias FETestHelpers.HeartbeatTracker.Impl
+
+  test "record_heartbeat/1 records the heartbeat at the current time" do
+    [recorded_timestamp] =
+      Impl.new()
+      |> Impl.record_heartbeat()
+      |> Impl.list_heartbeat_timestamps()
+
+    assert DateTime.diff(recorded_timestamp, DateTime.utc_now(), :millisecond) < 20
+  end
+
+  property "list_heartbeat_timestamps/1 returns the timestamps in the order received" do
+    current_timestamp = DateTime.utc_now()
+
+    forall timestamps <- list(recent_timestamp(current_timestamp)) do
+      impl =
+        for timestamp <- timestamps, reduce: Impl.new() do
+          impl -> Impl.record_heartbeat(impl, timestamp)
+        end
+
+      timestamps == Impl.list_heartbeat_timestamps(impl)
+    end
+  end
+
+  property "list_heartbeat_intervals/1 returns the time since the previous heartbeat" do
+    current_timestamp = DateTime.utc_now()
+
+    forall intervals <- non_empty(list(integer())) do
+      timestamps =
+        intervals
+        |> Enum.reduce([current_timestamp], fn interval, [last_timestamp | _] = timestamps ->
+          timestamp = DateTime.add(last_timestamp, interval)
+
+          [timestamp | timestamps]
+        end)
+        |> Enum.reverse()
+
+      impl =
+        for timestamp <- timestamps, reduce: Impl.new() do
+          impl -> Impl.record_heartbeat(impl, timestamp)
+        end
+
+      intervals == Impl.list_heartbeat_intervals(impl)
+    end
+  end
+
+  property "list_heartbeat_intervals/1 returns non negative values when only calling record_heartbeat/1" do
+    forall [
+      heartbeat_count <- integer(2, :inf),
+      time_unit <- oneof([:second, :millisecond, :microsecond, :nanosecond])
+    ] do
+      impl = Impl.new() |> record_heartbeat_multiple_times(heartbeat_count)
+
+      impl |> Impl.list_heartbeat_intervals(time_unit) |> Enum.all?(&(&1 >= 0))
+    end
+  end
+
+  test "list_heartbeat_intervals/1 returns an empty array when heartbeat_count has been called less than twice" do
+    for heartbeat_count <- 0..1 do
+      impl = Impl.new() |> record_heartbeat_multiple_times(heartbeat_count)
+
+      assert Impl.list_heartbeat_intervals(impl) == []
+    end
+  end
+
+  @spec record_heartbeat_multiple_times(Impl.t(), non_neg_integer) :: Impl.t()
+  defp record_heartbeat_multiple_times(impl, times) when is_integer(times) and times > 0 do
+    impl |> Impl.record_heartbeat() |> record_heartbeat_multiple_times(times - 1)
+  end
+
+  defp record_heartbeat_multiple_times(impl, 0), do: impl
+
+  defp recent_timestamp(%DateTime{} = base_timestamp) do
+    let seconds_after <- integer() do
+      DateTime.add(base_timestamp, seconds_after)
+    end
+  end
+end
diff --git a/fe_test_helpers/test/fe_test_helpers/heartbeat_tracker_test.exs b/fe_test_helpers/test/fe_test_helpers/heartbeat_tracker_test.exs
@@ -0,0 +1,46 @@
+defmodule FETestHelpers.HeartbeatTrackerTest do
+  use ExUnit.Case, async: true
+  use PropCheck
+
+  alias FETestHelpers.HeartbeatTracker
+
+  property "record_heartbeat/1 stores the heartbeat" do
+    forall [heartbeat_count <- non_neg_integer()] do
+      {:ok, tracker} = HeartbeatTracker.start_link([])
+
+      record_heartbeat_multiple_times(tracker, heartbeat_count)
+
+      actual_heartbeat_count =
+        tracker
+        |> HeartbeatTracker.list_heartbeat_timestamps()
+        |> length()
+
+      actual_heartbeat_count == heartbeat_count
+    end
+  end
+
+  property "list_heartbeat_intervals/1 returns non negative values when only calling record_heartbeat/1" do
+    forall [
+      heartbeat_count <- integer(2, :inf),
+      time_unit <- oneof([:second, :millisecond, :microsecond, :nanosecond])
+    ] do
+      {:ok, tracker} = HeartbeatTracker.start_link([])
+
+      record_heartbeat_multiple_times(tracker, heartbeat_count)
+
+      intervals = HeartbeatTracker.list_heartbeat_intervals(tracker, time_unit)
+
+      intervals_all_non_negative? = Enum.all?(intervals, &(&1 >= 0))
+      correct_interval_count? = length(intervals) == heartbeat_count - 1
+
+      intervals_all_non_negative? && correct_interval_count?
+    end
+  end
+
+  defp record_heartbeat_multiple_times(tracker, times) when is_integer(times) and times > 0 do
+    :ok = HeartbeatTracker.record_heartbeat(tracker)
+    record_heartbeat_multiple_times(tracker, times - 1)
+  end
+
+  defp record_heartbeat_multiple_times(_tracker, 0), do: :ok
+end
diff --git a/fe_test_helpers/test/test_helper.exs b/fe_test_helpers/test/test_helper.exs
@@ -0,0 +1 @@
+ExUnit.start()

Original file line number	Diff line number	Diff line change
`@@ -0,0 +1,3 @@`
	`1`	`+# Used for ignoring dialyzer errors`
	`2`	`+# See: https://github.com/jeremyjh/dialyxir/tree/fd13c1cef28cde1b563236405e1441ada867b314#elixir-term-format`
	`3`	`+[]`
-Original file line number
+Diff line change
@@ @@ -0,0 +1,4 @@ @@
 +# Used by "mix format"
 +[
 +  inputs: ["{mix,.formatter}.exs", "{config,lib,test}/**/*.{ex,exs}"]
 +]
Original file line number	Diff line number	Diff line change
`@@ -0,0 +1,3 @@`
	`1`	`+# FETestHelpers`
	`2`	`+`
	`3`	`+Test helpers for use with FreezerEye.`