build.gradle

import io.gitlab.arturbosch.detekt.Detekt
import org.jetbrains.kotlin.gradle.tasks.KotlinCompile

buildscript {
  apply from: "gradle/dependencies.gradle"

  repositories {
    mavenCentral()
    gradlePluginPortal()
    google()
  }

  dependencies {
    classpath libs.android.gradlePlugin
    classpath libs.kotlin.gradlePlugin
    classpath libs.mavenPublishGradlePlugin
    classpath libs.dokka.gradlePlugin
    classpath libs.detekt.gradlePlugin
    classpath libs.gradleVersions.gradlePlugin
    classpath libs.kotlin.x.binaryCompatibility.gradlePlugin
  }
}

apply plugin: libs.kotlin.x.binaryCompatibility.gradlePluginId

apiValidation {
  ignoredProjects += ["sample"]
}

allprojects {
  repositories {
    mavenCentral()
    google()
  }

  group GROUP
  version VERSION_NAME

  tasks.withType(Test) {
    testLogging {
      events "skipped", "failed", "passed"
    }
  }

  tasks.withType(JavaCompile) {
    sourceCompatibility JavaVersion.VERSION_1_8.toString()
    targetCompatibility JavaVersion.VERSION_1_8.toString()
  }

  tasks.withType(KotlinCompile) {
    kotlinOptions {
      jvmTarget = JavaVersion.VERSION_1_8.toString()
      freeCompilerArgs += [
          "-progressive",
          // TODO: Remove API in tests https://youtrack.jetbrains.com/issue/KT-42718
          "-Xexplicit-api=strict",
      ]
    }
  }

  pluginManager.withPlugin("com.android.library") {
    android {
      compileOptions {
        sourceCompatibility JavaVersion.VERSION_1_8
        targetCompatibility JavaVersion.VERSION_1_8
      }

      compileSdkVersion versions.androidBuild.compileSdk

      defaultConfig {
        minSdkVersion versions.androidBuild.minSdk
        targetSdkVersion versions.androidBuild.targetSdk

        vectorDrawables.useSupportLibrary true
      }

      variantFilter { variant ->
        setIgnore variant.name != "release"
      }

      libraryVariants.all { variant ->
        variant.outputs.all {
          outputFileName = "${archivesBaseName}-${version}.aar"
        }
      }

      lintOptions {
        lintConfig rootProject.file("lint.xml")

        htmlReport !isCi()
        xmlReport isCi()
        xmlOutput file("build/reports/lint/lint-results.xml")

        textReport true
        textOutput "stdout"
        explainIssues false

        checkDependencies false
        checkGeneratedSources true
        checkTestSources false
        checkReleaseBuilds false
      }
    }
  }
}

apply plugin: libs.detekt.gradlePluginId

dependencies {
  detekt libs.detekt.formatting
  detekt libs.detekt.cli
  detektPlugins libs.kurePotlin
}

tasks.withType(Detekt) {
  parallel true
  config.setFrom(rootProject.files("detekt-config.yml"))
  setSource(files(projectDir))
  exclude "**/test/**", "**/androidTest/**"
  exclude subprojects.collect { "${rootDir.toPath().relativize(it.buildDir.toPath())}/" }
  reports {
    xml {
      enabled = isCi()
      destination = file("build/reports/detekt/detekt-results.xml")
    }
    html.enabled = !isCi()
    txt.enabled = false
  }
}

apply plugin: libs.gradleVersions.gradlePluginId

dependencyUpdates {
  rejectVersionIf {
    isNonStable(it.candidate.version) && !isNonStable(it.currentVersion)
  }
}

private static def isNonStable(String version) {
  def regex = /^[0-9,.v-]+(-r)?$/
  return !(version ==~ regex)
}

private static def isCi() {
  // noinspection GroovyPointlessBoolean
  return System.getenv("CI")?.toBoolean() == true
}