❄️ Nix (nix-darwin) installation with custom config directory

[minusfive]

Just dipping my toes into this whole Nix rabbit hole, so bare with me...

Per #1734 the only way to move the location of your config file/directory is by populating the MJConfigFile key in the hammerspoon plist (defaults write org.hammerspoon.Hammerspoon MJConfigFile "~/.config/hammerspoon/init.lua").

So here's my flake.nix (with irrelevant pieces removed) to install Homebrew, Hammerspoon, and configure the custom config directory:

# dotfiles/flake.nix

{
  description = "My macOS configuration";

  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixpkgs-unstable";
    nix-darwin.url = "github:LnL7/nix-darwin";
    nix-darwin.inputs.nixpkgs.follows = "nixpkgs";

    # https://github.com/zhaofengli/nix-homebrew
    nix-homebrew.url = "github:zhaofengli-wip/nix-homebrew";
  };

  outputs = {
    self,
    nix-darwin,
    nixpkgs,
    nix-homebrew,
  } @ inputs: let
    configuration = {pkgs, ...}: {
      # List packages installed in system profile. To search by name, run:
      # $ nix-env -qaP | grep wget
      environment.systemPackages = with pkgs; [
        nixfmt-rfc-style
        nixd
        alejandra
      ];

      # Necessary for using flakes on this system.
      nix.settings.experimental-features = "nix-command flakes";

      # Set Git commit hash for darwin-version.
      system.configurationRevision = self.rev or self.dirtyRev or null;

      # Used for backwards compatibility, please read the changelog before changing.
      # $ darwin-rebuild changelog
      system.stateVersion = 5;

      # The platform the configuration will be used on.
      nixpkgs.hostPlatform = "aarch64-darwin";

      # System Settings
      system.defaults = {
        CustomUserPreferences = {
          "org.hammerspoon.Hammerspoon" = {
            MJConfigFile = "~/.config/hammerspoon/init.lua";
          };
        };
      };

      # Homebrew
      homebrew = {
        enable = true;

        onActivation = {
          autoUpdate = true;
          cleanup = "zap";
          upgrade = true;
          extraFlags = [
            "--verbose"
          ];
        };

        casks = [
          "hammerspoon" # macOS automation
        ];
      };
    };
  in {
    # Build darwin flake using:
    # $ darwin-rebuild build --flake .#macos
    darwinConfigurations."macos" = nix-darwin.lib.darwinSystem {
      modules = [
        configuration
        nix-homebrew.darwinModules.nix-homebrew
        {
          # Homebrew
          nix-homebrew = {
            enable = true;
            user = <YOUR_USER>;
            autoMigrate = true;
          };
        }
      ];
    };
  };
}

Tested and works like a charm. Back into the rabbit hole 🐇.