-
Notifications
You must be signed in to change notification settings - Fork 0
/
Copy pathFindPJSIP.cmake
291 lines (270 loc) · 11.2 KB
/
FindPJSIP.cmake
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
# Use this module by invoking find_package with the form:
# find_package(PJSIP
# [version] [EXACT] # Minimum or EXACT version e.g. 1.9
# [REQUIRED] # Fail with error if PJSIP is not found
# )
# This module finds headers and requested component libraries OR a CMake
# package configuration file provided by a "PJSIP CMake" build. For the
# latter case skip to the "PJSIP CMake" section below. For the former
# case results are reported in variables:
# PJSIP_FOUND - True if headers and requested libraries were found
# PJSIP_INCLUDE_DIRS - PJSIP include directories
# PJSIP_LIBRARY_DIRS - Link directories for PJSIP libraries
# PJSIP_LIBRARIES - PJSIP component libraries to be linked
# PJSIP_VERSION - PJSIP version
#
# This module reads hints about search locations from variables:
# PJSIP_ROOT - Preferred installation prefix
# (or PJSIPROOT)
#
# You can set additional messages output with `set (PJSIP_DEBUG ON)`
#
#=============================================================================
# Copyright 2014 halex2005 <[email protected]>
#
# Distributed under Apache v2.0 License (the "License");
# see accompanying file LICENSE for details.
#
# This software is distributed WITHOUT ANY WARRANTY; without even the
# implied warranty of MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.
# See the License for more information.
#=============================================================================
# (To distribute this file outside of CMakeHelpers, substitute the full
# License text for the above reference.)
#=============================================================================
#-------------------------------------------------------------------------------
#
# Setup environment
#
#-------------------------------------------------------------------------------
# If PJSIP_DIR is not set, look for PJSIPROOT and PJSIP_ROOT
# as alternatives, since these are more conventional for PJSIP.
if ("$ENV{PJSIP_DIR}" STREQUAL "")
if (NOT "$ENV{PJSIP_ROOT}" STREQUAL "")
set(ENV{PJSIP_DIR} $ENV{PJSIP_ROOT})
elseif (NOT "$ENV{PJSIPROOT}" STREQUAL "")
set(ENV{PJSIP_DIR} $ENV{PJSIPROOT})
endif()
endif()
mark_as_advanced(PJSIP_DIR)
set(PJSIP_ROOT_DIR $ENV{PJSIP_DIR})
if (NOT DEFINED PJSIP_REGENERATE_PKGCONFIG)
set (PJSIP_REGENERATE_PKGCONFIG OFF)
endif()
if (WIN32)
if (NOT DEFINED PJSIP_USE_BUILD_FROM_SOURCE)
set (PJSIP_USE_BUILD_FROM_SOURCE ON)
endif()
if (NOT DEFINED PJSIP_USE_PKGCONFIG)
set (PJSIP_USE_PKGCONFIG OFF)
endif()
if (NOT DEFINED PJSIP_USE_STATIC_RUNTIME)
set (PJSIP_USE_STATIC_RUNTIME OFF)
endif()
add_definitions(-DPJ_WIN32=1)
endif()
if (UNIX)
if (NOT DEFINED PJSIP_USE_PKGCONFIG)
set (PJSIP_USE_PKGCONFIG ON)
endif()
if (NOT DEFINED PJSIP_USE_BUILD_FROM_SOURCE)
set (PJSIP_USE_BUILD_FROM_SOURCE OFF)
endif()
endif()
#-------------------------------------------------------------------------------
#
# Get version
#
#-------------------------------------------------------------------------------
if(PJSIP_USE_BUILD_FROM_SOURCE)
# try to get actual version from PJSIP source directory
if (EXISTS ${PJSIP_ROOT_DIR}/version.mak)
file(STRINGS "${PJSIP_ROOT_DIR}/version.mak" PJSIP_VERSION_STRINGS)
FOREACH(i IN LISTS PJSIP_VERSION_STRINGS)
string(REGEX REPLACE "export PJ_VERSION_MAJOR.*:=.*([0-9]+)" "\\1" _PJSIP_TEMP_ "${i}")
if (NOT "${_PJSIP_TEMP_}" STREQUAL "${i}")
set (PJSIP_VERSION_MAJOR ${_PJSIP_TEMP_})
endif()
string(REGEX REPLACE "export PJ_VERSION_MINOR.*:=.*([0-9]+)" "\\1" _PJSIP_TEMP_ "${i}")
if (NOT "${_PJSIP_TEMP_}" STREQUAL "${i}")
set (PJSIP_VERSION_MINOR ${_PJSIP_TEMP_})
endif()
string(REGEX REPLACE "export PJ_VERSION_REV.*:=.*([0-9]+)" "\\1" _PJSIP_TEMP_ "${i}")
if (NOT "${_PJSIP_TEMP_}" STREQUAL "${i}")
set (PJSIP_VERSION_REV ${_PJSIP_TEMP_})
endif()
ENDFOREACH()
set (PJSIP_VERSION_SHORT "${PJSIP_VERSION_MAJOR}.${PJSIP_VERSION_MINOR}")
set (PJSIP_VERSION "${PJSIP_VERSION_SHORT}.${PJSIP_VERSION_REV}")
if (PJSIP_DEBUG)
message(STATUS "found version ${PJSIP_VERSION} from ${PJSIP_ROOT_DIR}/version.mak")
endif()
else()
set(PJSIP_VERSION "0.0.0")
if (PJSIP_DEBUG)
message(STATUS "there is no file ${PJSIP_ROOT_DIR}/version.mak, version set to ${PJSIP_VERSION}")
endif()
endif()
if (PJSIP_FIND_VERSION_EXACT)
if (NOT ${PJSIP_VERSION} VERSION_EQUAL ${PJSIP_FIND_VERSION})
message(SEND_ERROR "Required exact version ${PJSIP_FIND_VERSION} not found (found version ${PJSIP_VERSION})")
return()
endif()
else()
if(PJSIP_FIND_VERSION)
if (${PJSIP_VERSION} VERSION_LESS ${PJSIP_FIND_VERSION})
message(SEND_ERROR "Required version ${PJSIP_FIND_VERSION} or greater not found (found version ${PJSIP_VERSION})")
return()
endif()
else()
# Any version is acceptable.
endif()
endif()
if (PJSIP_USE_STATIC_RUNTIME)
set(PJSIP_CRT_LINKAGE Static)
else()
set(PJSIP_CRT_LINKAGE Dynamic)
endif()
endif()
#-------------------------------------------------------------------------------
#
# Discover PJSIP
#
#-------------------------------------------------------------------------------
if (PJSIP_USE_PKGCONFIG)
if (PJSIP_DEBUG)
message(STATUS "using PkgConfig to discover pjsip")
endif()
if (NOT $ENV{PKG_CONFIG_PATH} STREQUAL "" AND IS_DIRECTORY $ENV{PKG_CONFIG_PATH})
# environment variable PKG_CONFIG_PATH exists and it is directory
string(REPLACE "\\" "/" PJSIP_ROOT_DIR_FOR_PKGCONFIG ${PJSIP_ROOT_DIR})
if (NOT EXISTS "$ENV{PKG_CONFIG_PATH}/libpjproject.pc" OR PJSIP_REGENERATE_PKGCONFIG)
message (STATUS "generate $ENV{PKG_CONFIG_PATH}/libpjproject.pc")
configure_file(${CMAKE_CURRENT_LIST_DIR}/libpjproject.pc.in "$ENV{PKG_CONFIG_PATH}/libpjproject.pc" @ONLY)
else()
message (STATUS "found $ENV{PKG_CONFIG_PATH}/libpjproject.pc, no regenerate")
endif()
else()
message (STATUS "there is no PKG_CONFIG_PATH environment variable, no libpjproject.pc file generated")
endif()
find_package(PkgConfig REQUIRED)
if (NOT PKG_CONFIG_FOUND)
message(SEND_ERROR "PkgConfig not found")
return()
endif()
if (PJSIP_FIND_VERSION)
if (PJSIP_FIND_VERSION_EXACT)
pkg_check_modules(PJSIP libpjproject=${PJSIP_FIND_VERSION} REQUIRED)
else()
pkg_check_modules(PJSIP libpjproject>=${PJSIP_FIND_VERSION} REQUIRED)
endif()
else()
pkg_check_modules(PJSIP libpjproject REQUIRED)
endif()
elseif(PJSIP_USE_BUILD_FROM_SOURCE)
if (PJSIP_DEBUG)
message(STATUS "not using PkgConfig to discover pjsip")
endif()
if( CMAKE_SIZEOF_VOID_P EQUAL 8 )
set(PJSIP_TargetCPU "x86_64")
add_definitions(-DPJ_M_X86_64)
else()
set(PJSIP_TargetCPU "i386")
add_definitions(-DPJ_M_I386)
endif()
find_path(PJSIP_PJLIB_INCLUDE_DIR NAMES "pjlib.h" PATHS "${PJSIP_ROOT_DIR}/pjlib/include")
find_path(PJSIP_PJLIB_UTIL_INCLUDE_DIR NAMES "pjlib-util.h" PATHS "${PJSIP_ROOT_DIR}/pjlib-util/include")
find_path(PJSIP_PJMEDIA_INCLUDE_DIR NAMES "pjmedia.h" PATHS "${PJSIP_ROOT_DIR}/pjmedia/include")
find_path(PJSIP_PJNATH_INCLUDE_DIR NAMES "pjnath.h" PATHS "${PJSIP_ROOT_DIR}/pjnath/include")
find_path(PJSIP_PJSIP_INCLUDE_DIR NAMES "pjsip.h" PATHS "${PJSIP_ROOT_DIR}/pjsip/include")
set (PJSIP_INCLUDE_DIR
${PJSIP_PJLIB_INCLUDE_DIR}
${PJSIP_PJLIB_UTIL_INCLUDE_DIR}
${PJSIP_PJMEDIA_INCLUDE_DIR}
${PJSIP_PJNATH_INCLUDE_DIR}
${PJSIP_PJSIP_INCLUDE_DIR}
)
if (WIN32)
set (PJSIP_LIBRARY_DIR "${PJSIP_ROOT_DIR}/lib")
if (PJSIP_USE_STATIC_RUNTIME)
set (PJSIP_LIBRARIES "libpjproject-\$(Platform)-\$(PlatformToolset)-\$(Configuration)-Static.lib")
else()
set (PJSIP_LIBRARIES "libpjproject-\$(Platform)-\$(PlatformToolset)-\$(Configuration)-Dynamic.lib")
endif()
set (PJSIP_STATIC_LIBRARIES ${PJSIP_LIBRARIES} Ws2_32.lib)
elseif(UNIX)
set (PJSIP_LIBRARY_DIR /usr/lib/${PJSIP_TargetCPU}-unknown-linux-gnu)
set (PJSIP_LIBRARIES
pjsua2-${PJSIP_TargetCPU}-unknown-linux-gnu
pjsua-${PJSIP_TargetCPU}-unknown-linux-gnu
pjsip-ua-${PJSIP_TargetCPU}-unknown-linux-gnu
pjsip-simple-${PJSIP_TargetCPU}-unknown-linux-gnu
pjsip-${PJSIP_TargetCPU}-unknown-linux-gnu
pjmedia-codec-${PJSIP_TargetCPU}-unknown-linux-gnu
pjmedia-${PJSIP_TargetCPU}-unknown-linux-gnu
pjmedia-videodev-${PJSIP_TargetCPU}-unknown-linux-gnu
pjnath-${PJSIP_TargetCPU}-unknown-linux-gnu
pjlib-util-${PJSIP_TargetCPU}-unknown-linux-gnu
srtp-${PJSIP_TargetCPU}-unknown-linux-gnu
resample-${PJSIP_TargetCPU}-unknown-linux-gnu
gsmcodec-${PJSIP_TargetCPU}-unknown-linux-gnu
speex-${PJSIP_TargetCPU}-unknown-linux-gnu
ilbcodec-${PJSIP_TargetCPU}-unknown-linux-gnu
g7221codec-${PJSIP_TargetCPU}-unknown-linux-gnu
portaudio-${PJSIP_TargetCPU}-unknown-linux-gnu
pj-${PJSIP_TargetCPU}-unknown-linux-gnu
)
set (PJSIP_STATIC_LIBRARIES
${PJSIP_LIBRARIES}
stdc++
m
rt
pthread
asound
SDL2
avformat
avcodec
swscale
avutil
v4l2
crypto
ssl
opencore-amrnb
opencore-amrwb
opencore-amrwbenc
)
endif()
set (PJSIP_INCLUDE_DIRS ${PJSIP_INCLUDE_DIR})
set (PJSIP_LIBRARY_DIRS ${PJSIP_LIBRARY_DIR})
if ("${PJSIP_INCLUDE_DIRS}" MATCHES "NOTFOUND" OR "${PJSIP_LIBRARY_DIRS}" MATCHES "NOTFOUND")
set(PJSIP_FOUND 0)
else()
set (PJSIP_FOUND 1)
endif()
endif()
if (PJSIP_DEBUG)
message(STATUS "PJSIP_ROOT_DIR = ${PJSIP_ROOT_DIR}")
message(STATUS "PJSIP_FOUND = ${PJSIP_FOUND}")
message(STATUS "PJSIP_INCLUDE_DIRS = ${PJSIP_INCLUDE_DIRS}")
message(STATUS "PJSIP_LIBRARY_DIRS = ${PJSIP_LIBRARY_DIRS}")
message(STATUS "PJSIP_LIBRARIES = ${PJSIP_LIBRARIES}")
message(STATUS "PJSIP_VERSION = ${PJSIP_VERSION}")
endif()
if(PJSIP_FOUND)
else()
if(PJSIP_FIND_REQUIRED)
message(SEND_ERROR "Unable to find the requested PJSIP libraries.\n${PJSIP_ERROR_REASON}")
else()
if(NOT PJSIP_FIND_QUIETLY)
# we opt not to automatically output PJSIP_ERROR_REASON here as
# it could be quite lengthy and somewhat imposing in its requests
# Since PJSIP is not always a required dependency we'll leave this
# up to the end-user.
if(PJSIP_DEBUG OR PJSIP_DETAILED_FAILURE_MSG)
message(STATUS "Could NOT find PJSIP\n${PJSIP_ERROR_REASON}")
else()
message(STATUS "Could NOT find PJSIP")
endif()
endif()
endif()
endif()