readpixel and drawpixel.. diferent colours

[eb4cuv]

Hi Bodmer.

from the spiffs I draw an image on the screen. Until there, everything ok.
Then, I do a pixel by pixel reading of the screen with readpixel and save it in a buffer.
Later, I retrieve the previously saved data from the buffer and draw it in screen with drawpixel.
It is expected that the result would be the same, but no ... the color is different. What am I doing wrong?

Thanks for your time.

---

uint16_t zzxx[400];

for (int a = 0; a <= 480; a++)
{
for (int i = 0; i <= 320; i++)
{
zzxx[i] = tft.readPixel(a, i);
}
}

for (int i = 0; i <= 320; i++)
tft.drawPixel(a, i, zzxx[i]);

---

[Bodmer]

Not all displays can be read successfully. Post a link to the (exactly the same) display you are using.

[Bodmer]

Here is a simple sketch to test. You should end up with a single red line 320 pixels long:

#include <SPI.h>
#include <TFT_eSPI.h>

TFT_eSPI tft = TFT_eSPI();

void setup() {
  tft.init();
}

void loop() {
  uint16_t zzxx[240];
  int a = 0;

  tft.fillScreen(TFT_RED);

  for (int x = 0; x < 240; x++)
  {
    zzxx[x] = tft.readPixel(x, a);
  }

  tft.fillScreen(TFT_BLACK);

  for (int x = 0; x < 240; x++)
  {
    tft.drawPixel(x, 10, zzxx[x]);
  }

  while (1) yield();
}

Note that in your sketch you should use < for the for loop, not <= because row/coumns 320 and 480 do not exist. Then you can minimise the array size to uint16_t zzxx[320]; since clearly the array index can only be 0-319 otherwise the processor will crash.

You can change TFT_RED in that sketch to TFT_GREEN and then TFT_BLUE to check the R,G and B colour pixels are being read, if correct then all other colours should be OK too.

[eb4cuv]

Hi,

This is the display I am using: http://www.lcdwiki.com/3.5inch_SPI_Module_ILI9488_SKU:MSP3520

This is the result: after reading the original with readpixel and repainting it with drawpixel:

the error is very evident in the monkey's left eye and in the mouse.

[Bodmer]

Did you run the sketch I posted? What are you findings?

[eb4cuv]

Yes, I ran the sketch and everything was fine. The problem is that when the original color for example is red, when he repaints it is not the same red but an orange. The same goes for other colors. In the photo the monkey and the mouse can be seen clearly.

[Bodmer]

What SPI clock rate are you using for read and write?

[eb4cuv]

// #define SPI_FREQUENCY 20000000
#define SPI_FREQUENCY 30000000
// #define SPI_FREQUENCY 40000000
// #define SPI_FREQUENCY 60000000
// #define SPI_FREQUENCY 80000000

// Optional reduced SPI frequency for reading TFT
//#define SPI_READ_FREQUENCY 16000000
#define SPI_READ_FREQUENCY 30000000
#define SPI_TOUCH_FREQUENCY 2500000

[Bodmer]

The read frequency is too high, this cause "bit smearing" where a single 1 bit becomes 2. Change it back to the default 16MHz. Note that the data sheet limit is 6.7MHz for read frequency and 20MHz for write frequency. Displays typically can be overclocked, but 16MHz is likely to be the limit for ILI9488 reads.

Here is a simple walking 1 test, to test for read errors, run it, then reduce the frequency to 16MHz and it should run without error.

#include <TFT_eSPI.h> // Hardware-specific library
#include <SPI.h>

#define TDELAY 0

TFT_eSPI tft = TFT_eSPI(); 

void setup() {
  Serial.begin(115200);

  tft.init();
  tft.fillScreen(TFT_BLACK);
}

void loop() {
  static uint32_t wr = 1;
  static uint32_t rd = 0xFFFFFFFF;

  delay(TDELAY);

  tft.drawPixel(30,30,wr);
  Serial.print(" Pixel value written = ");Serial.println(wr,HEX);
  
  rd = tft.readPixel(30,30);
                Serial.print(" Pixel value read    = ");Serial.println(rd,HEX);

  if (rd!=wr) {
    Serial.println(" ERROR                 ^^^^");
    while(1) yield();
  }

  // Walking 1 test
  wr = wr<<1;
  if (wr >= 0x10000) wr = 1;
}

[eb4cuv]

Already solved. The problem was effectively as you said in the SPI read frequency. I had to lower it to 12mhz for it to work without errors.

Again thanks for your time and for your fantastic library.