Add support for 4bits pushToSprite, pushRotated

[sduponch]

Hi,

When using 4bits colorDepth on eTFT_Sprite, the pushToSprite and pushRotate(&sprite,..) are not working.

I spent one night figuring why it was working in 8bits/16bits and not in 4bits.

• It seems that the 4bits has been disabled in code.
• Investigation leads me to an issue with the "pushImage" code in 4bits mode (

  TFT_eSPI/Extensions/Sprite.cpp

  Line 1110 in cc9787d

  else if (_bpp == 4)

  ).
• The pushed sprites has color corruptions, only the transparency color is correctly handled.
• The color picking does not look to work, returning always the same color in code display the sprite but with some corruption.

on Arduino IDE with latest library on a DOIT ESP32 Devboard and the 2" 320x240 ST7789 SPI TFT.
bitmap.zip

#include <TFT_eSPI.h>
TFT_eSPI tft = TFT_eSPI();

#include "background_swipe4bits.h";
TFT_eSprite bg = TFT_eSprite(&tft);
#include "swipe4bits.h";
TFT_eSprite swipeCard = TFT_eSprite(&tft);

int angle = 0;
void drawBackground() {
  bg.setColorDepth(4);
  bg.createSprite(320, 240);
  bg.createPalette(palette, 16);
  //bg.fillSprite(4);
  bg.pushImage(0, 0, 320, 240, (uint16_t *)background);
  
  swipeCard.setColorDepth(4);
  swipeCard.createSprite(140, 70);
  swipeCard.createPalette(palette, 16);

  //swipeCard.fillSprite(5);
  swipeCard.pushImage(0, 0, 140, 70, (uint16_t *)swipe_card);
  swipeCard.setPivot(0, 35);
 
  //swipeCard.pushToSprite(&bg, 10, 10, 5);
  bg.setPivot(170,240);
  swipeCard.pushRotated(&bg, angle, 5); // 5 is transparency color in palette
  
  bg.pushSprite(0,0);
  bg.deleteSprite();
  swipeCard.deleteSprite();
}

[Bodmer]

pushToSprite already handles copying a 4 bit sprite into another sprite. So this should work:

  bg.setColorDepth(4);
  bg.createSprite(320, 240);
  bg.createPalette(palette, 16);
  bg.pushImage(0, 0, 320, 240, (uint16_t *)background);

  swipeCard.setColorDepth(4);
  swipeCard.createSprite(140, 70);
  swipeCard.createPalette(palette, 16);
  swipeCard.pushImage(0, 0, 140, 70, (uint16_t *)swipe_card);

  swipeCard.pushToSprite(&bg, 70, 35);

  bg.pushSprite(0, 0);

  while(1) delay(1000);

pushRotated only handles 8 bit and 16 bit sprite to sprite copying. I will add to the todo list but I have little time at the moemnt to work on additions.

[sduponch]

Thank you for your quick response, on an unmodified library the pushToSpite is not displaying anything.
Only the pushSprite to the tft is working :

With a modified library to allow 4bits on pushToSprite and pushRotated, i get the folowing result :

It works good with 8bits sprites but it consume more RAM and space for the same result (color aproximated), without the possibility to play with palette color change... (for exemple changing the backgroud black color to green or red on success or failure).

There is a way to do colors changes in 8bits mode ?

Best regards,
Sebastian.

[sduponch]

I came up to a different approach and i now work in full 16bits.
Suprisingly i was able to create two 16bits Sprites of 160x240 but not one of 320x240...

So i came up with a method that consist of allocationg only a portion of the screen and redrawing everyting for each portions of the full screen and it keep my memory usage relatively low.

#include "background.h"
#include "swipe_card.h"
int angle=-30;
#include "sonic.h"
int frame=1;
void drawBackground()
{
  bool oldSwap;

  swipeCard.setColorDepth(16);
  swipeCard.createSprite(140, 70);
  oldSwap = swipeCard.getSwapBytes();
  swipeCard.setSwapBytes(!oldSwap);
  swipeCard.pushImage(0, 0, 140, 70, (uint16_t *)image_data_swipe_card, 16);
  swipeCard.setSwapBytes(oldSwap);
  swipeCard.setPivot(0, 35);
  
  sonic.setColorDepth(16);
  sonic.createSprite(40, 40);
  oldSwap = sonic.getSwapBytes();
  sonic.setSwapBytes(!oldSwap);
  sonic.pushImage(0, 0, 40, 40, ((uint16_t *)image_data_sonic)+(40*40*frame), 16);
  sonic.setSwapBytes(oldSwap);
  
  // Render the screen by quarter
  int dx=80;
  fb = (uint16_t*)fbspr.createSprite(dx, 240);
  for(int px=0; px<320; px+=dx) {
    oldSwap = fbspr.getSwapBytes();
    fbspr.setSwapBytes(!oldSwap);
    fbspr.pushImage(0-px, 0, 320, 240, (uint16_t *)image_data_background, 16);
    fbspr.setSwapBytes(oldSwap);
    sonic.pushToSprite(&fbspr, 140-px, 44, sonic.readPixel(0,0));
    label.pushToSprite(&fbspr, 60-px, 83, 5);
    fbspr.setPivot(200-px,240);
    swipeCard.pushRotated(&fbspr, angle, swipeCard.readPixel(0,0)); // only on right side
    fbspr.setTextColor(tft.color565(0xFF,0xF2,0x65), tft.color565(00,17,21), false);
    fbspr.drawString(rtc.getTime("%d/%m/%Y"), 0-px, 0, 4);
    fbspr.drawString(rtc.getTime(), 221-px, 0, 4);
    fbspr.drawString(WiFi.localIP().toString().c_str(), 0-px, 216, 4);
    //fbspr.pushSprite(0, 0, 0, 0, 160, 240);
    // push the left side to DMA
    tft.startWrite();
    tft.pushImageDMA(px, 0, dx, 240, fb);
    tft.dmaWait();
  }
  tft.endWrite();
  
  fbspr.deleteSprite();
  sonic.deleteSprite();
  swipeCard.deleteSprite();
}

void drawScreen(){
  if(frame > 31) {
    frame = 1;
  }
  frame++;
  if(angle < -75) {
    angle = -30;
  } else {
    angle = angle - 1;
  };
  drawBackground();
}

[Bodmer]

Great, glad you have a solution. 8 bit colour sprites should work too is you become memory constrained.

[sduponch]

The 8bits palette does not render well with my animated sonic sprite and the use of the DMA looks to not works with 8bits sprites, it is weird that i can not create a 16bits sprite of 320x240 but it's ok with two 160x240 stiched together... maybe a memory pagination problem idk.

This workaround give me some good result by the way :
https://youtu.be/XDU1dk9tNxk
You did a good job with your library.

Best regards,
Sébastien.