Getting rid of trailing digit

[mike-rankin]

Love this library and have a small issue that's killing me. Trying to print a sensor value that when drops from 100 to 99 will remove the trailing 0. Right now it shows 990 instead of 99. Possibly an if number less than 100, tft.drawChar(' ',x,y); but wondering if there is an easier way?

Tried this but no luck:

void loop() {

  uint16_t x = tft.width()/2;
  uint16_t y = tft.height()/2;

  // Set datum to Middle Right
  tft.setTextDatum(MC_DATUM);

  // Set the padding to the maximum width that the digits could occupy in font 4
  // This ensures small numbers obliterate large ones on the screen
  tft.setTextPadding( tft.textWidth("888", 4) );

  // Creat a random number in range 0 to 150
  int number = random(150);

  tft.setTextSize(4); 
  tft.setCursor(x, y);  
  tft.println(number);
  Serial.println(number);
  
  // Reset text padding to 0 otherwise all future rendered strings will use it!
  tft.setTextPadding(0);
  
  // Set datum to Middle Left
  tft.setTextDatum(MC_DATUM);

  delay(3000);
}  

[Bodmer]

There are a few thing that are not quite right:

1. The print stream does not support paddiing or datum setting (this is becuase the library is fed chanracters one by one, so the library does not know where to put the first character in that case)
2. The text size must be set before the textWidth function is called so the pixel width can be calculated
3. The background colour must be specified

Here is a working sketch:

#include <TFT_eSPI.h>
TFT_eSPI tft = TFT_eSPI();

void setup() {
  tft.begin();
  tft.setRotation(0);
  tft.fillScreen(TFT_BLACK);
  tft.setTextColor(TFT_GREEN, TFT_BLUE);
}

void loop() {

  uint16_t x = tft.width()/2;
  uint16_t y = tft.height()/2;

  // Set datum to Middle Centre
  tft.setTextDatum(MC_DATUM);

 // Set text size
  tft.setTextSize(4);

  // Set the padding to the maximum width that the digits could occupy in font 4 at the text size set
  // This ensures small numbers obliterate large ones on the screen
  tft.setTextPadding(tft.textWidth("888", 4) );

  // Creat a random number in range 0 to 150
  int number = random(150);

 // Draw number centred on x,y (datum was set to middle centre) in font 4
  tft.drawNumber(number, x, y, 4);

  Serial.println(number);
  
  // Reset text padding to 0 otherwise all future rendered strings will use it!
  tft.setTextPadding(0);
  
  // Set datum to Middle Left
  tft.setTextDatum(ML_DATUM);

  delay(3000);
}

[mike-rankin]

Thank you and I had so many things wrong but it works perfectly now.