How to refer a parent in module when using loop for creating resources?

[h00jraq]

So I'm trying to write something that will allow me to create topics and subscriptions in a loop and while I think I've achieved that thanks to code founded here, I'm facing some problems and I'n not sure how to resolve them. It looks like sometimes bicep fails because it try to create subscription when topics creation is not yet finished. When I re-run my pipeline, it works just fine. I guess this is the reason:

https://learn.microsoft.com/en-us/azure/azure-resource-manager/bicep/linter-rule-use-parent-property

The error I get is: The incoming request is not recognized as a namespace policy put request. ttps://aka.ms/sbResourceMgrExceptions. TrackingId:e1d2c50d-fe92-43d8-abfe-8eb2c1917a70_G5, SystemTracker:ihdev-nonprod-servicebus.servicebus.windows.net:dev-sb-topic-test/subscriptions/dev-sb-sub-test, Timestamp:2024-04-08T13:33:29 (Code: MessagingGatewayNotFoundStatusCode

I'm not sure how to avoid this error. Is there a way to create particular subscription only if corresponding topic was created? I guess I cannot simply add dependsOn[i] as I would have to change from for topic in topicsAndSubscriptions to something like for (topic, i) in topicsAndSubscriptions but maybe I'm wrong?
In general I'm trying to find a smartway of doing this os it will be easy for me to just add more topics and subscriptions and set necessary parameters depends on topic/subscription

Main.bicepparam:

using './main.bicep'

param serviceBusNamespaceName = '#{SBUS_NAMESPACE_NAME}#'
param topicsAndSubscriptions = [
  {
    name: 'dev-sb-top-failure'
    subscriptions: [
      'dev-sb-sub-failure'
    ]
  }
  {
    name: 'xrm-dev-sb-report-completion'
    subscriptions: [
      'dev-sb-sub-report-completion'
    ]
  }
  {
    name: 'dev-sb-top-completion'
    subscriptions: [
      'dev-sb-sub-completion'
    ]
  }
  {
    name: 'dev-sb-top-discharge'
    subscriptions: [
      'dev-sb-sub-discharge'
    ]
  }
]

Here is the code for main.bicep

@description('Name of the Service Bus namespace')
param serviceBusNamespaceName string

@description('Location for all resources.')
param location string = resourceGroup().location
param topicsAndSubscriptions array

resource serviceBusNamespace 'Microsoft.ServiceBus/namespaces@2022-01-01-preview' = {
  name: serviceBusNamespaceName
  location: location
  sku: {
    name: 'Premium'
  }
  properties: {}
}

resource serviceBusTopic 'Microsoft.ServiceBus/namespaces/topics@2022-10-01-preview' = [
  for topic in topicsAndSubscriptions: {
    parent: serviceBusNamespace
    name: topic.name
    properties: {}
  }
]

module subs 'modules/subscription.bicep' = [
  for topic in topicsAndSubscriptions: {
    name: '${topic.name}-subs'
    params: {
      servicebusNamespaceName: serviceBusNamespaceName
      topicName: topic.name
      subscriptions: topic.subscriptions
    }
  }
]

module file:

param servicebusNamespaceName string
param topicName string
param subscriptions array = ['asubscription', 'anotherone']

resource sub 'Microsoft.ServiceBus/namespaces/topics/subscriptions@2022-10-01-preview' = [
  for i in subscriptions: {
    name: '${servicebusNamespaceName}/${topicName}/${i}'
    properties: {}

[GABRIELNGBTUC]

I guess I cannot simply add dependsOn[i] as I would have to change from for topic in topicsAndSubscriptions to something like for (topic, i) in topicsAndSubscriptions but maybe I'm wrong?

You can and I don't see why you wouldn't do this at this point. Changing to the following is valid bicep and would fix the issue for now

@description('Name of the Service Bus namespace')
param serviceBusNamespaceName string

@description('Location for all resources.')
param location string = resourceGroup().location
param topicsAndSubscriptions array

resource serviceBusNamespace 'Microsoft.ServiceBus/namespaces@2022-01-01-preview' = {
  name: serviceBusNamespaceName
  location: location
  sku: {
    name: 'Premium'
  }
  properties: {}
}

resource serviceBusTopic 'Microsoft.ServiceBus/namespaces/topics@2022-10-01-preview' = [
  for topic in topicsAndSubscriptions: {
    parent: serviceBusNamespace
    name: topic.name
    properties: {}
  }
]

module subs 'modules/subscription.bicep' = [
  for (topic, i) in topicsAndSubscriptions: {
    name: '${topic.name}-subs'
    params: {
      servicebusNamespaceName: serviceBusNamespaceName
      topicName: topic.name
      subscriptions: topic.subscriptions
    }
    dependsOn: [
      serviceBusTopic[i]
    ]
  }
]

[ManagedUx]

Likewise, you can eliminate the explicit dependsOn by referencing the name property of the serviceBusTopic so that bicep can infer a dependency.

...

module subs 'modules/subscription.bicep' = [
  for (topic, i) in topicsAndSubscriptions: {
    name: '${topic.name}-subs'
    params: {
      servicebusNamespaceName: serviceBusNamespaceName
      topicName: serviceBusTopic[i].name
      subscriptions: topic.subscriptions
    }
  }
]

[johnlokerse]

You already got great suggestions, but I would suggest to consolidate the topics and subscriptions deployment. In the Bicep template below, you see the combined the infrastructure for topics and subscriptions into a module. By doing this, some of the dependency and loop complexity is resolved because it will be handled by the Azure Resource Manager instead.

Main bicep template:

@description('Name of the Service Bus namespace')
param serviceBusNamespaceName string

@description('Location for all resources.')
param location string = resourceGroup().location
param topicsAndSubscriptions array

resource serviceBusNamespace 'Microsoft.ServiceBus/namespaces@2022-01-01-preview' = {
  name: serviceBusNamespaceName
  location: location
  sku: {
    name: 'Premium'
  }
  properties: {}
}

module subs 'topicsAndSubscriptions.module.bicep' = [
  for topic in topicsAndSubscriptions: {
    name: '${topic.name}-subs'
    params: {
      servicebusNamespaceName: serviceBusNamespace.name
      topicName: topic.name
      subscriptions: topic.subscriptions
    }
  }
]

Topics and Subscriptions module:

param servicebusNamespaceName string
param topicName string
param subscriptions array = ['asubscription', 'anotherone']

resource serviceBusTopic 'Microsoft.ServiceBus/namespaces/topics@2022-10-01-preview' = {
  name: '${servicebusNamespaceName}/${topicName}'
  properties: {}

  resource topicSubscription 'subscriptions' = [
    for subscriptionName in subscriptions: {
      name: subscriptionName
      properties: {}
    }
  ]
}

In the Topics and Subscription module, the serviceBusTopic now has a parent/child relationship with topicSubscription. The Azure Resource Manager recognises that there are dependencies and will handle the deployment accordingly. Using the topics and subscription module you can create multiple topics including the subscriptions.

Let me know if you have questions 💪

[h00jraq]

Yes, I've actually went that way.
Was not touching Bicep for quite some time but now it is looking better haha.
Thanks for all the suggestions!