add wolfsheepcabbage examples

Author: Anniepoo

clpfdwsc.pl

@@ -0,0 +1,23 @@
+:- module(clpfdwsc, [go/1]).
+
+:-use_module(library(clpfd)).
+
+go(M) :-
+    wsc([[0,0,0,0]], M),
+    flatten(M, FM),
+    label(FM).
+
+wsc([[1,1,1,1]|R], [[1,1,1,1]|R]).
+wsc([[F,W,S,C]|R], M) :-
+    [NF, NW, NS, NC] = NM,
+    NM ins 0..1,
+    NF #\= F, % move the farmer
+    % move max one thing
+    NW #= W #/\ NS #= S  #\/
+    NS #= S #/\ NC #= C  #\/
+    NW #= W #/\ NC #= C,
+    % game rules
+    NS #= NC #==> NF #= NS,
+    NW #= NS #==> NF #= NW,
+    wsc([NM, [F,W,S,C] | R], M).
+

tabledwsc.pl

@@ -0,0 +1,45 @@
+go(Moves) :-
+   wsc(0,0,0,0, Moves).
+
+:- table wsc(_, _, _, _, lattice(shortest/3)).
+
+shortest(P1, P2, P):-
+    length(P1, L1),
+    length(P2, L2),
+    ( L1 < L2 -> P = P1 ; P = P2 ).
+
+% wsc/5, c/4, safe/3 are the same as OP's code, slightly reformatted.
+
+wsc(1,1,1,1, []).               % goal
+wsc(0,W,S,C, [lr(f) | Rest]) :- % farmer moving alone
+    c(0,W,S,C),
+    wsc(1,W,S,C, Rest).
+wsc(1,W,S,C, [rl(f) | Rest]) :-
+    c(1,W,S,C),
+    wsc(0,W,S,C, Rest).
+wsc(0,0,S,C, [lr(w) | Rest]) :- % move wolf
+    c(0,0,S,C),
+    wsc(1,1,S,C, Rest).
+wsc(1,1,S,C, [rl(w) | Rest]) :-
+    c(1,1,S,C),
+    wsc(0,0,S,C, Rest).
+wsc(0,W,0,C, [lr(s) | Rest]) :- % move sheep
+    c(0,W,0,C),
+    wsc(1,W,1,C, Rest).
+wsc(1,W,1,C, [rl(s) | Rest]) :-
+    c(1,W,1,C),
+    wsc(0,W,0,C, Rest).
+wsc(0,W,S,0, [lr(c) | Rest]) :- % move cabbage
+    c(0,W,S,0),
+    wsc(1,W,S,1, Rest).
+wsc(1,W,S,1, [rl(c) | Rest]) :-
+    c(1,W,S,1),
+    wsc(0,W,S,0, Rest).
+
+c(F,W,S,C) :-
+    safe(F,W,S),
+    safe(F,S,C).
+
+safe(A,A, _).
+safe(_,0,1).
+safe(_,1,0).

wolfsheepcabbage.pl

@@ -0,0 +1,68 @@
+:- module(wsc, [go/1]).
+
+go(Moves) :-
+   allowed(A),
+   list_to_ord_set(A, OA),
+   wsc(0,0,0,0, OA, Moves).
+
+allowed([
+    s(0,0,0,0),
+    s(0,0,0,1),
+   % s(0,0,1,1),
+    s(0,0,1,0),
+  %  s(0,1,1,0),
+ %   s(0,1,1,1),
+    s(0,1,0,1),
+    s(0,1,0,0),
+ %   s(1,1,0,0),
+    s(1,1,0,1),
+    s(1,1,1,1),
+    s(1,1,1,0),
+    s(1,0,1,0),
+    s(1,0,1,1)
+%    s(1,0,0,1),
+%    s(1,0,0,0)
+]).
+
+wsc(1,1,1,1, _, []).   % goal
+wsc(0,W,S,C,A, [lr(f) | Rest]) :-  % farmer moving alone
+   c(0,W,S,C,A,NA),
+    wsc(1,W,S,C, NA, Rest).
+wsc(1,W,S,C,A, [rl(f) | Rest]) :-
+   c(1,W,S,C,A,NA),
+    wsc(0,W,S,C, NA, Rest).
+wsc(0,0,S,C,A, [lr(w) | Rest]) :-  % move wolf
+    c(0,0,S,C,A,NA),
+    wsc(1,1,S,C, NA, Rest).
+wsc(1,1,S,C,A, [rl(w) | Rest]) :-
+   c(1,1,S,C,A,NA),
+    wsc(0,0,S,C, NA, Rest).
+wsc(0,W,0,C,A, [lr(s) | Rest]) :-  % move sheep
+   c(0,W,0,C,A,NA),
+    wsc(1,W,1,C, NA, Rest).
+wsc(1,W,1,C,A, [rl(s) | Rest]) :-
+   c(1,W,1,C,A,NA),
+    wsc(0,W,0,C, NA, Rest).
+wsc(0,W,S,0,A, [lr(c) | Rest]) :-  % move cabbage
+   c(0,W,S,0,A,NA),
+    wsc(1,W,S,1, NA, Rest).
+wsc(1,W,S,1,A, [rl(c) | Rest]) :-
+   c(1,W,S,1,A,NA),
+    wsc(0,W,S,0, NA, Rest).
+
+c(F,W,S,C,A,NA) :-
+   safe(F,W,S),
+   safe(F,S,C),
+   member(s(F,W,S,C), A),
+   ord_subtract(A, [s(F,W,S,C)], NA).
+
+safe(A,A, _).
+safe(_,0,1).
+safe(_,1,0).
+
+
+
+
+
+
+