actor.gd

class_name Actor
extends CharacterBody2D

enum MotionType
{
	DIRECT, LERP, MOVETO
}

@export var motion_type := MotionType.DIRECT
@export var target: PathFollow2D

@export var speed := 600.0
@export var lerp_acceleration := 10
@export var moveto_acceleration := 10000

@export var moving := false


func _physics_process(delta: float) -> void:
	if moving:
		match motion_type:
			MotionType.LERP:
				_motion_lerp(delta)
			MotionType.MOVETO:
				_motion_moveto(delta)
			_:
				_motion_no_smoothing()
	else:
		velocity = Vector2.ZERO

	move_and_slide()


func _motion_no_smoothing() -> void:
	velocity = _target_velocity()


func _motion_lerp(delta: float) -> void:
	velocity = velocity.lerp(
		_target_velocity(), lerp_acceleration * delta
	)


func _motion_moveto(delta: float) -> void:
	velocity = velocity.move_toward(
		_target_velocity(), moveto_acceleration * delta
	)

func _target_velocity() -> Vector2:
	var diff := target.global_position - global_position

	var result: Vector2
	if not diff.is_zero_approx():
		result = diff.normalized() * speed
	else:
		result = Vector2.ZERO

	return result